Give names to the columns of SES data.

dateTime=1;
darkRefIntTime=2;
darkRef690=3;
darkRef590=4;
measureRefIntTime=5;
measureRef690=6;
measureRef590=7;
luminIntTime=8;
lumin690=9;
lumin590=10;
fluorIntTime=11;
fluor690=12;
fluor590=13;
phosIntTime=14;
phos690=15;
phos590=16;

Import data from Pulse 60, which was sampled every 12 hours.

fluorP60Data=Drop[Import["/Volumes/PBC/SES/Pulse\ 60/dep-2012.06.10-02-SES-STATION_M-1/fluorometer.csv"],1];

fluorP60Data[[1;;10]]

fluorP60Data[[-1]]

startp60={2012,6,11,12,10}

endp60={2012,11,10,0,10}

Import data from Pulse 61, which was sampled every 3 hours.

fluorP61Data=Drop[Import["/Volumes/PBC/SES/Pulse\ 61/dep-2012.11.17-01-Pulse-61/fluorometer.csv"],1];

fluorP61Data[[1;;10]]

fluorP61Data[[-1]]

{"2013-04-16T23:17:50.98",1000,0,0,1000,302,588,1000,0,0,1000,368,627,1000,0,0}

The start time for Pulse 61 is the fourth sample, since we’ll be summing the first four samples together.

startp61={2012,11,18,11,17}

endp61={2013,4,16,23,17}

Import data from Pulse 62, which was sampled every 4 hours.

fluorP62Data=Drop[Import["/Volumes/PBC/SES/Pulse\ 62/dep-2013.06.19-01-Pulse-62/fluorometer.csv"],1];

fluorP62Data[[1;;10]]

fluorP62Data[[-1]]

The start time for Pulse 62 is the third sample, since we’ll be summing the first three samples together.

startp62={2013,6,20,12,25}

endp62={2014,2,5,18,43}

Create the datasets needed for the plots.

f690p60=Clip[Flatten[fluorP60Data[[All,{fluor690}]]-fluorP60Data[[All,{measureRef690}]]],{0,1000}];

f590p60=Clip[Flatten[fluorP60Data[[All,{fluor590}]]-fluorP60Data[[All,{measureRef590}]]],{0,1000}];

f690p61=Clip[Flatten[fluorP61Data[[All,{fluor690}]]-fluorP61Data[[All,{measureRef690}]]],{0,1000}];

f590p61=Clip[Flatten[fluorP61Data[[All,{fluor590}]]-fluorP61Data[[All,{measureRef590}]]],{0,1000}];

f690p62=Clip[Flatten[fluorP62Data[[All,{fluor690}]]-fluorP62Data[[All,{measureRef690}]]],{0,1000}];

f590p62=Clip[Flatten[fluorP62Data[[All,{fluor590}]]-fluorP62Data[[All,{measureRef590}]]],{0,1000}];

sample=f690p61[[1;;12]]

Define a function which will lower the sample rate of data by adding samples together to combine them.

sumsample[data_List,factor_Integer]:=Total[Partition[data,factor],{2}]

sumsample[sample,4]

Lower the sample rate of the Pulse 61 data by a factor of 4, so it matches the rate of the Pulse 60 data.

f690p61sum=sumsample[f690p61,4];

{Length[f690p61],Length[f690p61sum]}

DateListPlot[f690p61sum,{startp61,endp61},{PlotRange->All,Joined->True,PlotLabel->"SES 690 nm Fluorescence on Pulse 61",FrameLabel->{"Date","Fluorescence (counts)"}}]

Compare the original and sumsampled data.

DateListPlot[{f690p61,f690p61sum},{startp61,endp61},{PlotRange->All,Joined->True,PlotLabel->"SES 690 nm Fluorescence on Pulse 61",FrameLabel->{"Date","Fluorescence (counts)"}}]

f590p61sum=sumsample[f590p61,4];

DateListPlot[f590p61sum,{startp61,endp61},{PlotRange->All,Joined->True,PlotLabel->"SES 590 nm Fluorescence on Pulse 61",FrameLabel->{"Date","Fluorescence (counts)"}}]

DateListPlot[{f690p61sum,f590p61sum},{startp61,endp61},{PlotRange->All,Joined->True,PlotLabel->"SES Fluorescence on Pulse 61",FrameLabel->{"Date","Fluorescence (counts)"}}]

Lower the sample rate of the Pulse 62 data by a factor of 3, so it matches the rate of the Pulse 60 data.

f690p62sum=sumsample[f690p62,3];

f590p62sum=sumsample[f590p62,3];

DateListPlot[{f690p62sum,f590p62sum},{startp62,endp62},{PlotRange->All,Joined->True,PlotLabel->"SES Fluorescence on Pulse 62",FrameLabel->{"Date","Fluorescence (counts)"}}]

Combine all three plots into a single plot with gaps where there are no data.

plot1=DateListPlot[{f590p60,f690p60},{startp60,endp60},ImagePadding->60,BaseStyle->{FontWeight->"Normal",FontSize->14},Frame->{False,True,False,False},FrameLabel->{{"Fluorescence (PM counts)",""},{"Date",Text[Style["SES Fluorescence on Pulse 60, 61, and 62",18]]}},Joined->True,PlotStyle->{Orange,Red},PlotLegends->Placed[{"590 nm","690 nm"},{0.5,0.8}],PlotRange->{{{2012,6,4,12,10},{2014,2,12,18,43}},{-30,1030}},DateTicksFormat->{"MonthNameShort"," '","YearShort"},ImageSize->Large]

plot2=DateListPlot[{f590p61sum,f690p61sum},{startp61,endp61},ImagePadding->60,BaseStyle->{FontWeight->"Normal",FontSize->14},Frame->{True,False,True,False},FrameLabel->{{{"",""},{"",""}},{"Date",Text[Style["SES Fluorescence on Pulse 60, 61, and 62",18]]}},Joined->True,PlotStyle->{Orange,Red},PlotRange->{{{2012,6,4,12,10},{2014,2,12,18,43}},{-30,1030}},DateTicksFormat->{"MonthNameShort"," '","YearShort"},ImageSize->Large]

plot3=DateListPlot[{f590p62sum,f690p62sum},{startp62,endp62},ImagePadding->60,BaseStyle->{FontWeight->"Normal",FontSize->14},Frame->{False,False,False,True},FrameLabel->{{"",""},{"Date",Text[Style["SES Fluorescence on Pulse 60, 61, and 62",18]]}},Joined->True,PlotStyle->{Orange,Red},PlotRange->{{{2012,6,4,12,10},{2014,2,12,18,43}},{-30,1030}},DateTicksFormat->{"MonthNameShort"," '","YearShort"},ImageSize->Large]

P606162Fluor=Overlay[{plot1,plot2,plot3}]

Export["P606162Fluor.pdf",P606162Fluor]