#! /bin/csh
# getm1.log - C Shell script to download data from M2 can under test
#	     and extract the data with logging
#
set oasis = /oasis
set can = m1
set tncaddr = "2000M1 v mbari-2"
set logfile = "dlinfo.log"

cd $oasis/raw
set noclobber
set noglob
set datafilebase = `date +%Y%j`
set failmail = "headley@mbari.org,zorba@mbari.org,w3ab@mbari.org"

set i = 0
set datafile = $can.$datafilebase.00
while ( -e $datafile )
	@ i++
	set datafile = $can.$datafilebase.`printf "%02d" $i`
end

set starttime = `date +"%x %H:%M:%S"`

$oasis/bin/getoasis -a "$tncaddr" -c $can >& $datafile
set rtnsts = $status

set endtime = `date +"%x %H:%M:%S"`

set filesize = `ls -l $datafile|sed -f $oasis/bin/fs.sed`
unset noclobber
echo "$datafile,$starttime,$endtime,$filesize,$rtnsts" >> $logfile
set noclobber

echo -n $rtnsts "  " >> filelist
ls -l $datafile >> filelist

if ( $rtnsts ) then
	/bin/mailx -s "Failed OASIS Download" $failmail << !
Download failure of file $datafile
Return code was $rtnsts
	0 = Success
	1 = Argument error (bad command line arguments)
	2 = Couldn't acquire TNC port (hung download or port in use)
	3 = Couldn't connect to OASIS (it's not listening)
	4 = Download error (something broke after it connected)
	5 = Abort error (somebody killed the download)
`date` *** message from get$can.log ***
!
endif

set errorfile = $oasis/$can/error/$datafile

if ( (-e $datafile) && !(-z $datafile) ) then
	$oasis/bin/extract -r -n -y1 $datafile >& $errorfile
endif

if ( -z $errorfile ) \
	rm -f $errorfile