*
*Zetex ZXM61P03F Spice Model v1.0 Last Revised 23/2/04
*
.SUBCKT ZXM61P03F 3 4 5
*----connections----D G S
*
M1 6 20 8 8 MOSMOD
M2 6 20 8 8 MOSMODS
RG 4 2 8
RIN 2 8 200E6
RD 3 6 RDSMOD 0.12
RS 8 5 RDSMOD 0.09 
RL 3 5 35E6
C1 2 8 162E-12
C3 15 14 210E-12 
C4 16 8 230E-12
D1 3 5 DMOD1
D2 3 17 DMOD2
S1 2 15 13 14 SMOD1a
S2 13 15 13 14 SMOD1b
S3 16 13 8 13 SMOD2a
S4 16 2 8 13 SMOD2b
Egs1 2 17 2 8 1
Egs2 13 8 2 8 1
Eds1 14 8 3 8 1
Egt1 2 20 21 8 1
Vgt1 8 22 1
Igt1 8 21 1
Rgt 21 22 RMOD2 1
.MODEL MOSMOD PMOS VTO=-2.1 IS=1E-15 KP=1.4 CBD=102E-12 PB=1 LAMBDA=4.9E-3
.MODEL MOSMODS PMOS VTO=-1.7 IS=1E-15 KP=0.018 PB=1
.MODEL DMOD1 D IS=6E-13 RS=0.1 N=1.01 BV=36 TT=1e-8
.MODEL DMOD2 D CJO=86e-12 IS=1e-30 N=10
.MODEL SMOD1a VSWITCH RON=1e-2 ROFF=1e4  VON=-1.75 VOFF=2.75
.MODEL SMOD1b VSWITCH RON=1e-2 ROFF=1e4  VON=2.75 VOFF=-1.75
.MODEL SMOD2a VSWITCH RON=1e-2 ROFF=1e4  VON=-1.5 VOFF=-3.5
.MODEL SMOD2b VSWITCH RON=1e-2 ROFF=1e4  VON=-3.5 VOFF=-1.5
.MODEL RDSMOD RES (TC1=3E-3 TC2=1.5E-5)
.MODEL RMOD2 RES (TC1=2.2E-3 TC2=3E-6)
.ENDS ZXM61P03F
*
*$
*
*                (c)  2005 Zetex Semiconductors plc
*
*   The copyright in these models  and  the designs embodied belong
*   to Zetex Semiconductors plc (" Zetex ").  They  are  supplied
*   free of charge by Zetex for the purpose of research and design
*   and may be used or copied intact  (including this notice)  for
*   that purpose only.  All other rights are reserved. The models
*   are believed accurate but  no condition  or warranty  as to their
*   merchantability or fitness for purpose is given and no liability
*   in respect of any use is accepted by Zetex PLC, its distributors
*   or agents.
*
*   Zetex Semiconductors plc, Zetex Technology Park, Chadderton,
*   Oldham, United Kingdom, OL9 9LL