.SUBCKT HUF75542P3  2 1 3      
*Nom Temp=25 deg C       
*15 Feb 00
Ca 12 8 4.4e-9
Cb 15 14 4.2e-9
Cin 6 8 2.5e-9

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 87.2
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 2.60e-9
Ldrain 2 5 1e-9
Lsource 3 7 1.1e-9

RLgate 1 9 26
RLdrain 2 5 10
RLsource 3 7 11

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD    

Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 5.5e-3
Rgate 9 20 1.0
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 3.3e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*230),2.5))}

.MODEL DbodyMOD D (IS=2.5E-12 N=1 XTI=5.5 RS=2.85e-3 TRS1=2E-3  TRS2=1E-6
+ CJO=3.2e-9 TT=5.5e-8 M=0.6)
.MODEL DbreakMOD D (RS=2.9e-1 TRS1=1E-3 TRS2=1E-6)
.MODEL DplcapMOD D (CJO=3.4e-9 IS=1e-30 M=0.8 N=10)

.MODEL MmedMOD NMOS (VTO=3.06 KP=4.8 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1)
.MODEL MstroMOD NMOS (VTO=3.5 KP=80 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MweakMOD NMOS (VTO=2.67 kp=0.08 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=10 RS=0.1) 

.MODEL RbreakMOD RES (TC1=1.3E-3 TC2=-9E-7)
.MODEL RdrainMOD RES (TC1=1.1e-2 TC2=2.5e-5)
.MODEL RSLCMOD RES (TC1=4.5e-3 TC2=1.0e-5)
.MODEL RsourceMOD RES (TC1=0 TC2=0)
.MODEL RvthresMOD RES (TC1=-2.5e-3 TC2=-1.1e-5)
.MODEL RvtempMOD RES (TC1=-2.75e-3 TC2=0)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-6.0 VOFF=-4.5)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-4.5 VOFF=-6.0)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-0.5 VOFF=0.5)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0.5 VOFF=-0.5)

.ENDS

*Thermal Model Subcircuit
*TA75542
.SUBCKT T75542 Junction Ambient

CTHERM1 Junction c2 4.1E-3	   
CTHERM2 c2 c3 5.5E-3
CTHERM3 c3 c4 8.6E-3
CTHERM4 c4 c5 1.5E-2
CTHERM5 c5 c6 1.6E-2
CTHERM6 c6 Ambient 6.5e-2

RTHERM1 Junction c2 2e-4
RTHERM2 c2 c3 3.5e-3
RTHERM3 c3 c4 2.5e-2
RTHERM4 c4 c5 9e-2
RTHERM5 c5 c6 1.6e-1
RTHERM6 c6 Ambient 2.3e-1

.ENDS