*
*Zetex ZXMN2F34FH Spice Model v1.0 Last Revised 31/07/08
*
.SUBCKT ZXMN2F34FH 3 4 5
*------connections-------D-G-S
M1 6 20 8 8 Nmod
RG 4 2 7
RD 3 6 Rmod1 0.025
RS 8 5 Rmod1 0.0033 
RL 3 5 100E6
D1 5 3 Dmod1
I1 8 21 1
V1 22 21 1
RT 22 8 Rmod2 1
Et 2 20 21 8 1
Egs2 13 8 2 8 1
Eds1 14 8 3 8 1
C1 2 8 200E-12
C2 2 3  40E-12
C3 15 14 270E-12 
C4 16 8 230E-12
S1 2 15 14 13 SMOD1
S2 13 15 14 13 SMOD2
S3 16 13 13 8 SMOD3
S4 16 2 13 8 SMOD4
.MODEL SMOD1 VSWITCH RON=.001 ROFF=100 VON=0.5 VOFF=1.5
.MODEL SMOD2 VSWITCH RON=.001 ROFF=100 VON=1.5 VOFF=0.5
.MODEL SMOD3 VSWITCH RON=.001 ROFF=100  VON=-2 VOFF=-3
.MODEL SMOD4 VSWITCH RON=.001 ROFF=100  VON=-3 VOFF=-2
.MODEL Nmod NMOS (LEVEL=3  VTO=1.574 KP=16  NFS=1.33E12 KAPPA=500 TOX=30E-9  NSUB=1E16 IS=1E-15 N=10)
.MODEL Dmod1 D (IS=8.7E-14 RS=0.026 CJO=320E-12 VJ=0.55 M=0.45 TT=1e-9 TRS1=1e-4  BV=22)
.MODEL Rmod1 RES (TC1=3.1e-3 TC2=0.6E-5)
.MODEL Rmod2 RES (TC1=-1.9e-3 TC2=-6E-6)
.ENDS ZXMN2F34FH
*
*$
*
*                (c)  2008 Diodes Incorporated
*
*   The copyright in these models  and  the designs embodied belong
*   to Diodes Incorporated (" Diodes ").  They  are  supplied
*   free of charge by Diodes for the purpose of research and design
*   and may be used or copied intact  (including this notice)  for
*   that purpose only.  All other rights are reserved. The models
*   are believed accurate but  no condition  or warranty  as to their
*   merchantability or fitness for purpose is given and no liability
*   in respect of any use is accepted by Diodes Incorporated, its distributors
*   or agents.
*
*   Diodes Incorporated, 1566 N. Dallas Parkway, Suite 850, Dallas, TX 75248, USA