Science/sci2_circle_hotspot.tl

# -   Copyright (c) 2024 MBARI
# -   MBARI Proprietary Information. Confidential. All Rights Reserved
# -   Unauthorized copying or distribution of this file via any medium is strictly
# -   prohibited.
# -
# -   WARNING - This file contains information whose export is restricted by the
# -   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
# -   amended. Violations of these export laws are subject to severe civil and/or
# -   criminal penalties.
mission sci2_circle_hotspot {
  arguments {
    # Almost every mission should start with an overall timeout and a NeedCommsTime. Drift Missions will have an acoustic timeout instead of a NeedCommsTime.

    # You probably need to change these.

    MissionTimeout = 1 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 30 minute
      """
      On yo-yo transit to waypoint or yoyo-circling at the hotspot, how often to surface for commumications.
      """

    Speed = 1.0 meter_per_second
      """
      Vehicle speed when transiting or yoyo-circling at the hotspot.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    RudderAngleYoyoCircle = 5 degree

    YoYoMinDepth = 2 meter
      """
      Minimum depth while performing the YoYo behavior.
      """

    YoYoMaxDepth = 20 meter
      """
      Maximum depth while performing the YoYo behavior.
      """

    CircleYoYoHalfThickness = 5 meter
      """
      Used only in yoyo-circle. If NaN, then CircleYoYoMinDepth is set to YoYoMinDepth; CircleYoYoMaxDepth is set to YoYoMaxDepth.
      """

    CircleYoYoShallowLimit = 2 meter
      """
      Used only in yoyo-circle.
      """

    CircleYoYoDeepLimit = NaN meter
      """
      Used only in yoyo-circle.
      """

    MarginValidLegDeep = 5 meter
      """
      Flip-to-ascent depth needs to be deeper than YoYoMaxDepth-MarginValidLegDeep to be considered a valid leg for peak reporting. Typically no need to change.
      """

    Lat[1..10] = NaN degree
      """
      Latitude of waypoint {$}. If NaN, skipped.
      """

    Lon[1..10] = NaN degree
      """
      Longitude of waypoint {$}. If NaN, skipped.
      """

    # debug
    #     </Description><Units:degree/><Value>36.803</Value></DefineArg>
    #     </Description><Units:degree/><Value>-121.83</Value></DefineArg>
    #     </Description><Units:degree/><Value>36.81</Value></DefineArg>
    #     </Description><Units:degree/><Value>-121.825</Value></DefineArg>

    ModemIDDestination = 0 enum
      """
      ID of destination modem to send acoustic messages to.
      """

    NumProfilesAvgPeakDepth = 1 count
      """
      Number of yoyo profiles for averaging the max-per-profile peak depths.
      """

    SendMessageTransitOrNot = true
      """
      Whether to report this vehicle's maneuver mode (0 = spiral, 1 = transit) to the other LRAUV.
      """

    MsgTransitOrNotPeriod = 10 minute
      """
      Time interval of sending transit-or-not message to the other LRAUV.
      """

    PeakPerYoYo = true
      """
      Based on peak per yo-yo profile (if true) or values of successive data points (if false).
      """

    TimeWindowForHighSignal = 10 minute
      """
      Used only when PeakPerYoYo is false. Time window for counting high signals.
      """

    PeakDetectChl = false
      """
      Whether to enable peak chl detection on each yo-yo profile
      """

    SendPeakDepthAvgProfilesChl = false
      """
      Whether to report profiles-averaged max-per-profile depth of chlorophyll: _.peakdepth.
      """

    ThreshChl = NaN microgram_per_liter
      """
      Threshold for qualifying as a hotspot.
      """

    PeakDetectPlanktivoreLMavgROI = false
      """
      Whether to enable peak PlanktivoreLMavgROI detection on each yo-yo profile
      """

    SendPeakDepthAvgProfilesPlanktivoreLMavgROI = false
      """
      Whether to report profiles-averaged max-per-profile depth of PlanktivoreLMavgROI: _.peakdepth.
      """

    ThreshPlanktivoreLMavgROI = 10 count_per_second
      """
      Threshold for qualifying as a hotspot.
      """

    ThreshHighSignalCounts = 1 count
      """
      When in transit, if CountsHighSignal exceeds this threshold, exit transit to enter yoyo-circle.
      """

    ThreshLowSignalCounts = 1 count
      """
      When in yoyo-circle, if CountsLowSignal exceeds this threshold, exit yoyo-circle to run the transit.
      """

    ListenToTerminateMissionMsg = false
      """
      Whether to listen to the _.terminateMission acoustic message.
      """

    # You probably do not need to change these.

    IntervalRestartLogs = 24 hour

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    MinAltitude = 7 meter
      """
      Minimum altitude for the entire mission.
      """

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    LowPassWindowLengthVertical = 20 count
      """
      Low-pass window length (based on depth sensor sampling interval 0.4
      second) for low-pass filtering.
      """

    MaxNumLaps = 20 count
      """
      Maximum number of laps.
      """
  }

  output {
    PeakDepthAvgOverProfiles = 0 meter
      """
      The peak signal depth averaged over NumProfilesAvgPeakDepth of profiles.
      """

    CircleYoYoMinDepth = NaN meter

    CircleYoYoMaxDepth = NaN meter

    InTransit = true
      """
      Initialized to true
      """

    InYoyoCircle = false
      """
      Initialized to false
      """

    CountsHighSignal = 0 count

    CountsLowSignal = 0 count

    WaypointReached[1..10] = false
      """
      Initialized to false
      """

    ElapsedSinceLastMsgTransitOrNot = 0 hour
  }

  # Missions should almost always start with a timeout and a NeedComms aggregate. Drift missions will not use NeedComms.

  timeout duration=MissionTimeout

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime

  # Missions should almost always start with standard safety envelopes

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  # Power the Backseat payload.

  insert Insert/BackseatDriver.tl

  insert Insert/PowerOnly.tl

  insert Insert/TerminateMissionByMsg.tl

  assign in sequence TerminateMissionByMsg:ListenToMsgTerminateMission = ListenToTerminateMissionMsg

  insert id="Science" Insert/Science.tl {
    redefineArg PeakDetectChlActive = PeakDetectChl
    redefineArg PeakDepthAvgProfilesChlActive = SendPeakDepthAvgProfilesChl
    redefineArg PeakDetectPlanktivoreLMavgROIActive = PeakDetectPlanktivoreLMavgROI
    redefineArg PeakDepthAvgProfilesPlanktivoreLMavgROIActive = SendPeakDepthAvgProfilesPlanktivoreLMavgROI
    redefineArg PlanktivoreLMavgROIThreshTriggerActive = not ( PeakPerYoYo )
    redefineArg ShallowLimit = CircleYoYoShallowLimit
    redefineArg TimeWindowHighSignal = TimeWindowForHighSignal
    redefineArg ChlThresh = ThreshChl
    redefineArg PlanktivoreLMavgROIThresh = ThreshPlanktivoreLMavgROI
    redefineArg PlanktivoreLMavgROIThreshCount = ThreshHighSignalCounts
    redefineArg LowPassWindowLength = LowPassWindowLengthVertical
    redefineArg FilterWidthHorizontal = NumProfilesAvgPeakDepth
    redefineArg ShallowBound = YoYoMinDepth
    redefineArg DeepBound = YoYoMaxDepth
    redefineArg DeepThreshValidLeg = YoYoMaxDepth - MarginValidLegDeep
  }

  aggregate SendSignalOfPeakDepthChl {
    run when (
      ( SendPeakDepthAvgProfilesChl
        and (
          not ( isNaN ( Science:PeakChlDepthAvgProfiles ) )
          and (
            ( Science:PeakChlDepthAvgProfiles > PeakDepthAvgOverProfiles )
            or ( Science:PeakChlDepthAvgProfiles < PeakDepthAvgOverProfiles )
          )
        )
      )
    )

    assign in sequence PeakDepthAvgOverProfiles = Science:PeakChlDepthAvgProfiles

    aggregate PeakDepthSignalChl {
      run in sequence

      break if ( Science:PeakChlAvgProfiles < ThreshChl )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDDestination
        set destName = "_.peakdepth"
        set value = Science:PeakChlDepthAvgProfiles
        set unit = "meter"
      }

      syslog info "Set _.peakdepth to " + Science:PeakChlDepthAvgProfiles~meter
    }

    aggregate PeakSignalChl {
      run in sequence

      break if ( Science:PeakChlAvgProfiles < ThreshChl )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDDestination
        set destName = "_.peakChl"
        set value = Science:PeakChlAvgProfiles
        set unit = "microgram_per_liter"
      }

      syslog info "Set _.peakChl to " + Science:PeakChlAvgProfiles~microgram_per_liter
    }
  }

  aggregate SendSignalOfPeakDepthPlanktivoreLMavgROI {
    run when (
      ( SendPeakDepthAvgProfilesPlanktivoreLMavgROI
        and (
          not ( isNaN ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles ) )
          and (
            ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles > PeakDepthAvgOverProfiles )
            or ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles < PeakDepthAvgOverProfiles )
          )
        )
      )
    )

    assign in sequence PeakDepthAvgOverProfiles = Science:PeakPlanktivoreLMavgROIDepthAvgProfiles

    aggregate PeakDepthSignalPlanktivoreLMavgROI {
      run in sequence

      break if (
        Science:PeakPlanktivoreLMavgROIAvgProfiles < ThreshPlanktivoreLMavgROI
      )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDDestination
        set destName = "_.peakdepth"
        set value = Science:PeakPlanktivoreLMavgROIDepthAvgProfiles
        set unit = "meter"
      }

      syslog info "Set _.peakdepth to " + Science:PeakPlanktivoreLMavgROIDepthAvgProfiles~meter
    }

    aggregate PeakSignalPlanktivoreLMavgROI {
      run in sequence

      break if (
        Science:PeakPlanktivoreLMavgROIAvgProfiles < ThreshPlanktivoreLMavgROI
      )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemIDDestination
        set destName = "_.peakPlanktivoreLM"
        set value = Science:PeakPlanktivoreLMavgROIAvgProfiles
        set unit = "count_per_second"
      }

      syslog info "Set _.peakPlanktivoreLM to "
           + Science:PeakPlanktivoreLMavgROIAvgProfiles~count_per_second
    }
  }

  aggregate IncrementCounterHighSignal {
    run when (
      ( SendPeakDepthAvgProfilesChl
        and (
          ( Science:PeakChlDepthAvgProfiles > PeakDepthAvgOverProfiles )
          or ( Science:PeakChlDepthAvgProfiles < PeakDepthAvgOverProfiles )
        )
        and (
          not ( isNaN ( Science:PeakChlAvgProfiles ) )
          and ( Science:PeakChlAvgProfiles >= ThreshChl )
        )
      )
      or (
        SendPeakDepthAvgProfilesPlanktivoreLMavgROI
        and (
          ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles > PeakDepthAvgOverProfiles )
          or ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles < PeakDepthAvgOverProfiles )
        )
        and (
          not ( isNaN ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles ) )
          and ( Science:PeakPlanktivoreLMavgROIAvgProfiles >= ThreshPlanktivoreLMavgROI )
        )
      )
    )

    assign in sequence CountsHighSignal = CountsHighSignal + 1 count

    syslog info "CountsHighSignal = " + CountsHighSignal~count
  }

  aggregate ResetCounterHighSignal {
    run when (
      ( CountsHighSignal >= 1 count )
      and (
        ( SendPeakDepthAvgProfilesChl
          and (
            ( Science:PeakChlDepthAvgProfiles > PeakDepthAvgOverProfiles )
            or ( Science:PeakChlDepthAvgProfiles < PeakDepthAvgOverProfiles )
          )
          and (
            isNaN ( Science:PeakChlAvgProfiles )
            or ( Science:PeakChlAvgProfiles < ThreshChl )
          )
        )
        or (
          SendPeakDepthAvgProfilesPlanktivoreLMavgROI
          and (
            ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles > PeakDepthAvgOverProfiles )
            or ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles < PeakDepthAvgOverProfiles )
          )
          and (
            isNaN ( Science:PeakPlanktivoreLMavgROIAvgProfiles )
            or ( Science:PeakPlanktivoreLMavgROIAvgProfiles < ThreshPlanktivoreLMavgROI )
          )
        )
      )
    )

    assign in sequence CountsHighSignal = 0 count

    syslog info "CountsHighSignal = " + CountsHighSignal~count
  }

  aggregate IncrementCounterLowSignal {
    run when (
      ( SendPeakDepthAvgProfilesChl
        and (
          ( Science:PeakChlDepthAvgProfiles > PeakDepthAvgOverProfiles )
          or ( Science:PeakChlDepthAvgProfiles < PeakDepthAvgOverProfiles )
        )
        and (
          isNaN ( Science:PeakChlAvgProfiles )
          or ( Science:PeakChlAvgProfiles < ThreshChl )
        )
      )
      or (
        SendPeakDepthAvgProfilesPlanktivoreLMavgROI
        and (
          ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles > PeakDepthAvgOverProfiles )
          or ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles < PeakDepthAvgOverProfiles )
        )
        and (
          isNaN ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles )
          or ( Science:PeakPlanktivoreLMavgROIAvgProfiles < ThreshPlanktivoreLMavgROI )
        )
      )
    )

    assign in sequence CountsLowSignal = CountsLowSignal + 1 count

    syslog info "CountsLowSignal = " + CountsLowSignal~count
  }

  aggregate ResetCounterLowSignal {
    run when (
      ( CountsLowSignal >= 1 count )
      and (
        ( SendPeakDepthAvgProfilesChl
          and (
            ( Science:PeakChlDepthAvgProfiles > PeakDepthAvgOverProfiles )
            or ( Science:PeakChlDepthAvgProfiles < PeakDepthAvgOverProfiles )
          )
          and (
            not ( isNaN ( Science:PeakChlAvgProfiles ) )
            and ( Science:PeakChlAvgProfiles >= ThreshChl )
          )
        )
        or (
          SendPeakDepthAvgProfilesPlanktivoreLMavgROI
          and (
            ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles > PeakDepthAvgOverProfiles )
            or ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles < PeakDepthAvgOverProfiles )
          )
          and (
            not ( isNaN ( Science:PeakPlanktivoreLMavgROIDepthAvgProfiles ) )
            and ( Science:PeakPlanktivoreLMavgROIAvgProfiles >= ThreshPlanktivoreLMavgROI )
          )
        )
      )
    )

    assign in sequence CountsLowSignal = 0 count

    syslog info "CountsLowSignal = " + CountsLowSignal~count
  }

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = Control:VerticalControl.massDefault
  }

  behavior Guidance:DepthEnvelope {
    run in parallel

    set minDepth = YoYoMinDepth
    set maxDepth = YoYoMaxDepth
    set downPitch = YoYoDownPitch
    set upPitch = YoYoUpPitch
  }

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude
  }

  aggregate SendTransitOrNotMessage {
    run when ( called )

    behavior Sensor:SendDirect {
      run in sequence

      set destType = "modem"
      set destId = ModemIDDestination
      set destName = "_.transitOrNot"
      set value = InTransit
      set unit = "bool"
    }

    syslog important "Set _.transitOrNot to " + InTransit~bool + "."
  }

  # Automatically restart logs

  aggregate CycleLogs {
    run in parallel

    aggregate {
      run in sequence

      behavior Guidance:Wait {
        run in sequence

        set duration = IntervalRestartLogs
      }

      syslog important "Restarting logs."

      behavior Guidance:Execute {
        run in sequence

        set command = "restart logs"
      }
    }
  }

  aggregate MissionStart {
    run in sequence

    call id="MissionStartComms" priorityHere=false refId="NeedComms"
  }

  macro $i = 1..10 {
    aggregate SetWaypointReached$i {
      run in sequence

      break if (
        not ( isNaN ( Lat[$i] ) )
        and not ( isNaN ( Lon[$i] ) )
      )

      assign in sequence WaypointReached[$i] = true
    }
  }

  aggregate Lap {
    run in sequence repeat=MaxNumLaps

    aggregate ClearWaypointReached {
      run when (
        WaypointReached[1]
        and WaypointReached[2]
        and WaypointReached[3]
        and WaypointReached[4]
        and WaypointReached[5]
        and WaypointReached[6]
        and WaypointReached[7]
        and WaypointReached[8]
        and WaypointReached[9]
        and WaypointReached[10]
      )

      assign in sequence WaypointReached[1] = false
    }

    aggregate Wpt1 {
      run in sequence

      break if (
        isNaN ( Lat[1] )
        or ( isNaN ( Lon[1] ) )
        or ( WaypointReached[1] )
        or (
          InYoyoCircle
          and PeakPerYoYo
          and ( CountsLowSignal < ThreshLowSignalCounts )
        )
        or (
          InTransit
          and PeakPerYoYo
          and ( CountsHighSignal >= ThreshHighSignalCounts )
        )
        or (
          not ( PeakPerYoYo )
          and Science:ThresholdMet
        )
      )

      assign in sequence InTransit = true

      assign in sequence InYoyoCircle = false

      syslog important "Transit."

      behavior Guidance:Buoyancy {
        run in parallel

        set position = Control:VerticalControl.buoyancyNeutral
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = Speed
      }

      behavior Guidance:DepthEnvelope {
        run in parallel

        set minDepth = YoYoMinDepth
        set maxDepth = YoYoMaxDepth
        set downPitch = YoYoDownPitch
        set upPitch = YoYoUpPitch
      }

      behavior Guidance:YoYo {
        run in parallel

        set downPitch = YoYoDownPitch
        set upPitch = YoYoUpPitch
      }

      aggregate Transit {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat[1]
          set longitude = Lon[1]
        }
      }

      aggregate ClearNextWaypointReached {
        run in sequence

        break if (
          isNaN ( Lat[2] )
          or ( isNaN ( Lon[2] ) )
        )

        assign in sequence WaypointReached[2] = false
      }

      assign in sequence WaypointReached[1] = true
    }

    macro $k = 2..9 {
      aggregate Wpt$k {
        run in sequence

        break if (
          isNaN ( Lat[$k] )
          or ( isNaN ( Lon[$k] ) )
          or ( WaypointReached[$k] )
          or ( not ( WaypointReached[$k - 1] ) )
          or (
            InYoyoCircle
            and PeakPerYoYo
            and ( CountsLowSignal < ThreshLowSignalCounts )
          )
          or (
            InTransit
            and PeakPerYoYo
            and ( CountsHighSignal >= ThreshHighSignalCounts )
          )
          or (
            not ( PeakPerYoYo )
            and Science:ThresholdMet
          )
        )

        assign in sequence InTransit = true

        assign in sequence InYoyoCircle = false

        syslog important "Transit."

        behavior Guidance:Buoyancy {
          run in parallel

          set position = Control:VerticalControl.buoyancyNeutral
        }

        behavior Guidance:SetSpeed {
          run in parallel

          set speed = Speed
        }

        behavior Guidance:DepthEnvelope {
          run in parallel

          set minDepth = YoYoMinDepth
          set maxDepth = YoYoMaxDepth
          set downPitch = YoYoDownPitch
          set upPitch = YoYoUpPitch
        }

        behavior Guidance:YoYo {
          run in parallel

          set downPitch = YoYoDownPitch
          set upPitch = YoYoUpPitch
        }

        aggregate Transit {
          run in sequence

          behavior Guidance:Waypoint {
            run in sequence

            set latitude = Lat[$k]
            set longitude = Lon[$k]
          }
        }

        aggregate ClearNextWaypointReached {
          run in sequence

          break if (
            isNaN ( Lat[$k + 1] )
            or ( isNaN ( Lon[$k + 1] ) )
          )

          assign in sequence WaypointReached[$k + 1] = false
        }

        assign in sequence WaypointReached[$k] = true
      }
    }

    aggregate YoyoCircleHotspot {
      run in sequence

      break if (
        ( InYoyoCircle
          and PeakPerYoYo
          and ( CountsLowSignal >= ThreshLowSignalCounts )
        )
        or (
          InTransit
          and PeakPerYoYo
          and ( CountsHighSignal < ThreshHighSignalCounts )
        )
        or (
          not ( PeakPerYoYo )
          and not ( Science:ThresholdMet )
        )
      )

      assign in sequence InTransit = false

      assign in sequence InYoyoCircle = true

      syslog important "Yoyo-circle."

      assign in sequence CircleYoYoMinDepth = YoYoMinDepth
      assign in sequence CircleYoYoMaxDepth = YoYoMaxDepth

      aggregate ChangeCircleYoYoDepthsPeakPerYoYo {
        run in sequence

        break if (
          not ( PeakPerYoYo )
          or isNaN ( CircleYoYoHalfThickness )
        )

        assign in sequence CircleYoYoMinDepth = PeakDepthAvgOverProfiles - CircleYoYoHalfThickness
        assign in sequence CircleYoYoMaxDepth = PeakDepthAvgOverProfiles + CircleYoYoHalfThickness
      }

      aggregate ChangeCircleYoYoDepthsNotPeakPerYoYo {
        run in sequence

        break if ( PeakPerYoYo or isNaN ( CircleYoYoHalfThickness ))

        assign in sequence CircleYoYoMinDepth = Science:HighSignalDepth - CircleYoYoHalfThickness
        assign in sequence CircleYoYoMaxDepth = Science:HighSignalDepth + CircleYoYoHalfThickness
      }

      aggregate ClampedToCircleYoYoShallowLimit {
        run in sequence

        break if (
          CircleYoYoMinDepth > CircleYoYoShallowLimit
          or ( isNaN ( CircleYoYoShallowLimit ) )
        )

        assign in sequence CircleYoYoMinDepth = CircleYoYoShallowLimit
      }

      aggregate ClampedToCircleYoYoDeepLimit {
        run in sequence

        break if (
          CircleYoYoMaxDepth < CircleYoYoDeepLimit
          or ( isNaN ( CircleYoYoDeepLimit ) )
        )

        assign in sequence CircleYoYoMaxDepth = CircleYoYoDeepLimit
      }

      behavior Guidance:Buoyancy {
        run in parallel

        set position = Control:VerticalControl.buoyancyNeutral
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = Speed
      }

      behavior Guidance:DepthEnvelope {
        run in parallel

        set minDepth = CircleYoYoMinDepth
        set maxDepth = CircleYoYoMaxDepth
        set downPitch = YoYoDownPitch
        set upPitch = YoYoUpPitch
      }

      behavior Guidance:YoYo {
        run in parallel

        set downPitch = YoYoDownPitch
        set upPitch = YoYoUpPitch
      }

      behavior Guidance:Point {
        run in parallel

        set rudderAngle = RudderAngleYoyoCircle
      }

      behavior Guidance:Wait {
        run in sequence

        set duration = MissionTimeout
      }
    }

    aggregate SendMsgTransitOrNot {
      run when (
        elapsed ( ElapsedSinceLastMsgTransitOrNot ) > MsgTransitOrNotPeriod
      )

      break if ( not ( SendMessageTransitOrNot ) )

      call id="SendTransitOrNotMsg" priorityHere=false refId="SendTransitOrNotMessage"

      assign in sequence ElapsedSinceLastMsgTransitOrNot = 0 hour
    }
  }
}