Skip to content

Science/mbts_sci2.tl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission mbts_sci2 {
  """
  This mission is basically Science/sci2 with 5 pre-established waypoints
  in the order: C1 - M1 - M2 - M1 - C1, but also with ability to (re)start
  the mission at any point just adjusting the `leg` parameter as needed.
  """

  # Almost every mission should start with an overall timeout and a NeedCommsTime.

  arguments {
    MissionTimeout = 48 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 60 minute
      """
      How often to surface for communications
      """

    # You probably need to change these.

    leg = 1 count
      """
      Denotes Which leg to start at. By default, this is 1 meaning the
      complete sequence: C1 - M1 - M2 - M1 - C1. Valid values are 1–5, with
      the following effect: 1: C1 - M1 - M2 - M1 - C1; 2: M1 - M2 - M1 - C1;
      3: M2 - M1 - C1; 4: M1 - C1; 5: C1.
      """

    # You probably do not need to change these.

    Lat[1..5] = [36.797 degree, 36.75 degree, 36.691 degree, 36.75 degree, 36.797 degree]
      """
      Do not need to change this (used internally). Latitude of waypoint {$}.
      """

    Lon[1..5] = [-121.847 degree, -122.022 degree, -122.376 degree, -122.022 degree, -121.847 degree]
      """
      Do not need to change this (used internally). Longitude of waypoint {$}.
      """

    Speed = 1 meter_per_second
      """
      Speed while performing the YoYo behavior.
      """

    PowerBackseat = false
      """
      Turns on the backseat payload.
      """

    YoYoMinDepth = 2 meter
      """
      Minimum depth while performing the YoYo behavior.
      """

    YoYoMaxDepth[1..5] = [40 meter, 100 meter, 200 meter, 200 meter, 100 meter]
      """
      Maximum depth #{$} while performing the YoYo behavior.
      """

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    # You are even less likely to need to change these.

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position
      """

    MinAltitude = 5 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 205 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """
  }

  # Missions should almost always start with a timeout

  timeout duration=MissionTimeout

  insert Insert/Science.tl {
    """
    Most missions will run the science sensors. If you don't place this
    aggregate above NeedComms, science instruments get turned off on the
    last upcast and while floating on the surface.
    """

    redefineArg PeakDetectChlActive = true
  }

  insert Insert/BackseatDriver.tl
  assign in sequence BackseatDriver:EnableBackseat = PowerBackseat

  # Most missions should use the NeedComms aggregate.

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime
  # Missions should almost always start with standard safety envelopes;
  # most missions should not expose the parameters of these envelopes.

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude
  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth
  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore
  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth
  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  # Automatically cycle logs every 24 hours

  aggregate Logs {
    run in parallel

    aggregate {
      run in sequence

      behavior Guidance:Wait {
        run in sequence

        set duration = 24 hour
      }

      syslog important "Restarting logs."

      behavior Guidance:Execute {
        run in sequence

        set command = "restart logs"
      }
    }
  }

  call id="StartingMission" refId="NeedComms"

  # Many missions will keep mass position and buoyancy volume fixed at defaults.

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  behavior Guidance:Buoyancy {
    run in parallel

    set position = BuoyancyNeutral
  }

  behavior Guidance:SetSpeed {
    run in parallel

    set speed = Speed
  }

  behavior Guidance:DepthEnvelope {
    """
    Another depth envelope for the YoYo behavior. This envelope should
    fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for depth-terminated YoYos.
    """

    run in parallel

    set minDepth = YoYoMinDepth

    # <Setting><Guidance:DepthEnvelope.maxDepth/><Arg Name="YoYoMaxDepth1"/></Setting>


    set downPitch = YoYoDownPitch

    set upPitch = YoYoUpPitch
  }

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude
  }

  behavior Guidance:YoYo {
    run in parallel

    set downPitch = YoYoDownPitch

    set upPitch = YoYoUpPitch
  }

  aggregate SetWaypointsPerLegParameter {
    """
    The Leg2, ..., Leg5 aggregates below adjust the corresponding
    previous Lat and Lon variables according to the `leg` parameter.
    """

    run in sequence

    #! The `$k - 1` expression constructs below supported since TethysL 2.3.5.

    macro $k = 2..5 {
      aggregate Leg$k {
        run in sequence

        break if ( leg <= $( $k - 1 ) count )

        assign in sequence Lat[$k - 1] = NaN degree
        assign in sequence Lon[$k - 1] = NaN degree
      }
    }
  }

  aggregate Lap {
    run in sequence

    syslog important "Starting Lap"
    syslog important "Lat1 = " + Lat[1]~degree + " Lon1 = " + Lon[1]~degree
    syslog important "Lat2 = " + Lat[2]~degree + " Lon2 = " + Lon[2]~degree
    syslog important "Lat3 = " + Lat[3]~degree + " Lon3 = " + Lon[3]~degree
    syslog important "Lat4 = " + Lat[4]~degree + " Lon4 = " + Lon[4]~degree
    syslog important "Lat5 = " + Lat[5]~degree + " Lon5 = " + Lon[5]~degree

    # The following aggregates dispatch the Guidance:Waypoint behavior as usual
    # (similarly as with sci2 but up to 5 waypoints here):

    macro $i = 1..5 {
      aggregate Wpt$i {
        run in sequence

        syslog important "Setting YoYoMaxDepth = " + YoYoMaxDepth[$i]~meter

        behavior Guidance:DepthEnvelope {
          run in parallel

          set maxDepth = YoYoMaxDepth[$i]
        }

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat[$i]
          set longitude = Lon[$i]
        }
      }
    }
  }
}