Science/sci2_peak_layer_yoyo.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

#! TethysL version initially based on automated translation from original Science/sci2.xml
#! and then (syntactically) simplified with use of array/macro extensions in TethysL.

mission sci2_peak_layer_yoyo {
  """
  Vehicle yo-yo's to the specified waypoints, with science turned on.
  """

  arguments {
    MissionTimeout = 2 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 60 minute
      """
      How often to surface for communications
      """

    Repeat = 1 count
      """
      Number of times the vehicle should try to cycle through waypoints..
      """

    Lat[1..7] = NaN degree
      """
      Latitude of waypoint {$}. If nan, waypoint is skipped.
      """

    Lon[1..7] = NaN degree
      """
      Longitude of waypoint {$}. If nan, waypoint is skipped.
      """

    Speed = 1 meter_per_second
      """
      Speed while performing the YoYo behavior.
      """

    YoYoMinDepth[1..7] = 2 meter
      """
      Minimum depth while performing the YoYo behavior.
      """

    YoYoMaxDepth[1..7] = 20 meter
      """
      Maximum depth while performing the YoYo behavior.
      """

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    SurfaceDiveSpeed = NaN meter_per_second
      """
      Vehicle speed to get off of surface, same as speed if skipped
      """

    SurfaceThreshold = Control:VerticalControl.surfaceThreshold
      """
      Depth at which to return to normal speed, skipped if SurfaceDiveSpeed NaN
      """

    YoYoLightTerminate = false
      """
      Set true to terminate dive once PAR value falls below threshold.
      """

    YoYoLightTerminateThreshold = 0.1 micromole_per_second_per_square_meter
      """
      Threshold of PAR output at which pitch command will flip positive if vehicle is pitched down.
      """

    EdgeDetectChl = true
      """
      Whether to enable chl edge detection on each yo-yo profile
      """

    EdgeDetectPlanktivoreLMavgROI = false
      """
      Whether to enable PlanktivoreLMavgROI edge detection on each yo-yo profile
      """

    EdgeDetectPlanktivoreHMavgROI = false
      """
      Whether to enable PlanktivoreHMavgROI edge detection on each yo-yo profile
      """

    EdgeDetectPlanktivoreDiatoms = false
      """
      Whether to enable PlanktivoreDiatoms edge detection on each yo-yo profile
      """

    EdgeDetectPlanktivoreDinoflagellates = false
      """
      Whether to enable PlanktivoreDinoflagellates edge detection on each yo-yo profile
      """

    ChlThreshTrigger = false
      """
      Whether to enable chl threshold triggering
      """

    ChlLowerThreshold = NaN microgram_per_liter
      """
      Used only when ChlThreshTrigger is true. Triggered when peak chl values on NumProfilesThreshold consecutive yo-yo profiles fall in [ChllowerThreshold ChlUpperThreshold]. ChllowerThreshold is ignored if NaN.
      """

    ChlUpperThreshold = NaN microgram_per_liter
      """
      Used only when ChlThreshTrigger is true. Triggered when peak chl values on NumProfilesThreshold consecutive yo-yo profiles fall in [ChllowerThreshold ChlUpperThreshold]. ChlUpperThreshold is ignored if NaN.
      """

    ChlPeakThreshold = 2 microgram_per_liter
      """
      In vertical-dimension edge detection, threshold for qualifying as a peak.
      """

    PlanktivoreLMavgROIPeakThreshold = 0 count_per_second
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    PlanktivoreHMavgROIPeakThreshold = 0 count_per_second
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    PlanktivoreDiatomsPeakThreshold = 0 count_per_milliliter
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    PlanktivoreDinoflagellatesPeakThreshold = 0 count_per_milliliter
      """
      In vertical-dimension edge detection, threshold for qualifying as an peak.
      """

    NumLayers = 1 count
      """
      Expected number of high-signal layers.
      """

    VerticalOffPeakFractionAscent = 50 percent
      """
      When the filtered signal falls below this fraction of the peak when vehicle is on ascent, edge is detected.
      """

    VerticalOffPeakFractionDescent = 50 percent
      """
      When the filtered signal falls below this fraction of the peak when vehicle is on Descent, edge is detected.
      """

    NumProfilesThreshold = 5 count
      """
      Used only when ChlThreshTrigger is true. Triggered when peak chl values on NumProfilesThreshold consecutive yo-yo profiles fall in [ChllowerThreshold ChlUpperThreshold]. ChlUpperThreshold is ignored if NaN.
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position
      """

    MinAltitude = 5 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    IntervalRestartLogs = 24 hour
  }

  timeout duration=MissionTimeout

  insert Insert/Science.tl {
    """
    Most missions will run the science sensors. If you don't place this
    aggregate above NeedComms, science instruments get turned off on the
    last upcast and while floating on the surface.
    """

    redefineArg EdgeDetectChlActive = EdgeDetectChl
    redefineArg EdgeDetectPlanktivoreLMavgROIActive = EdgeDetectPlanktivoreLMavgROI
    redefineArg EdgeDetectPlanktivoreHMavgROIActive = EdgeDetectPlanktivoreHMavgROI
    redefineArg EdgeDetectPlanktivoreDiatomsActive = EdgeDetectPlanktivoreDiatoms
    redefineArg EdgeDetectPlanktivoreDinoflagellatesActive = EdgeDetectPlanktivoreDinoflagellates
    redefineArg ShallowBound = YoYoMinDepth[1]
    redefineArg DeepBound = YoYoMaxDepth[1]
    redefineArg ChlThreshTriggerActive = ChlThreshTrigger
    redefineArg ChlLowerThresh = ChlLowerThreshold
    redefineArg ChlUpperThresh = ChlUpperThreshold
    redefineArg NumProfilesThresh = NumProfilesThreshold
    redefineArg OffPeakFractionVerticalAscent = VerticalOffPeakFractionAscent
    redefineArg OffPeakFractionVerticalDescent = VerticalOffPeakFractionDescent
    redefineArg ChlPeakThresh = ChlPeakThreshold
    redefineArg PlanktivoreLMavgROIPeakThresh = PlanktivoreLMavgROIPeakThreshold
    redefineArg PlanktivoreHMavgROIPeakThresh = PlanktivoreHMavgROIPeakThreshold
    redefineArg PlanktivoreDiatomsPeakThresh = PlanktivoreDiatomsPeakThreshold
    redefineArg PlanktivoreDinoflagellatesPeakThresh = PlanktivoreDinoflagellatesPeakThreshold
    redefineArg NumberOfLayers = NumLayers
  }

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert Insert/BackseatDriver.tl

  insert Insert/PowerOnly.tl

  call id="StartingMission" priorityHere=false refId="NeedComms"

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  behavior Guidance:Buoyancy {
    run in parallel

    set position = BuoyancyNeutral
  }

  aggregate SetSpeed {
    run in parallel

    aggregate SurfaceDive {
      run while (
        not isNaN ( SurfaceDiveSpeed )
        and Universal:depth <= SurfaceThreshold
      )

      aggregate SurfaceSpeed {
        run in parallel

        behavior Guidance:SetSpeed {
          run in parallel

          set speed = SurfaceDiveSpeed
        }
      }
    }

    aggregate ProfileSpeed {
      run while (
        isNaN ( SurfaceDiveSpeed )
        or Universal:depth > Control:VerticalControl.surfaceThreshold
      )

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = Speed
      }
    }
  }

  behavior Guidance:DepthEnvelope {
    """
    Another depth envelope for the YoYo behavior. This envelope should
    fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for depth-terminated YoYos.
    """

    run in parallel

    set downPitch = YoYoDownPitch
    set upPitch = YoYoUpPitch
  }

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude
  }

  # Automatically restart logs

  aggregate CycleLogs {
    run in parallel

    aggregate {
      run in sequence

      behavior Guidance:Wait {
        run in sequence

        set duration = IntervalRestartLogs
      }

      syslog important "Restarting logs."

      behavior Guidance:Execute {
        run in sequence

        set command = "restart logs"
      }
    }
  }

  aggregate YoYoFlip {
    """
    If light value falls below a threshold as we're pointed down, pitch the vehicle back up to terminate the yo.
    """

    run when (
      Science:PAR_Licor.loadAtStartup
      and ( YoYoLightTerminate )
      and ( Science:PAR_Licor.downwelling_photosynthetic_photon_flux_in_sea_water < YoYoLightTerminateThreshold )
      and ( Universal:platform_pitch_angle < 1 degree )
    )

    behavior Guidance:Pitch {
      run in parallel

      set pitch = YoYoUpPitch
    }
  }

  aggregate StopIfTriggered {
    """
    If peak chlorophyll values on NumProfilesThresh consecutive yo-yo profiles fall in [ChlLowerThreshold ChlUpperThreshold], stop mission.
    """

    run when ( Science:TriggeredOnChl )

    behavior Guidance:Execute {
      run in sequence

      set command = "stop"
    }
  }

  aggregate Lap {
    run in sequence repeat=Repeat

    macro $i = 1..7 {
      aggregate Wpt$i {
        run in sequence

        syslog important "Setting minDepth, maxDepth = " + YoYoMinDepth[$i]~meter + ","
             + YoYoMaxDepth[$i]~meter

        assign in sequence Science:ShallowBound = YoYoMinDepth[$i]

        assign in sequence Science:DeepBound = YoYoMaxDepth[$i]

        behavior Guidance:DepthEnvelope {
          run in parallel

          set minDepth = YoYoMinDepth[$i]
          set maxDepth = YoYoMaxDepth[$i]
        }

        behavior Guidance:Pitch {
          run while ( Science:GoDown )

          set pitch = YoYoDownPitch
        }

        behavior Guidance:Pitch {
          run while ( not ( Science:GoDown ) )

          set pitch = YoYoUpPitch
        }

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat[$i]
          set longitude = Lon[$i]
        }
      }
    }
  }
}