Engineering/altitudeServo.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission altitudeServo {
  """
  The vehicle will transit to an initial waypoint, then navigate to
  waypoints while maintaining altitude. During the altitude following
  phase of the mission, the vehicle descends from the surface to a
  commanded depth using a spiral dive (e.g., after NeedComms).
  """

  arguments {
    MissionTimeout = 2 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 60 minute
      """
      How often to surface for commumications
      """

    TransitLat = NaN degree
      """
      Latitude of tranist waypoint. Transit is skipped if set to NaN.
      """

    TransitLon = NaN degree
      """
      Longitude of tranist waypoint. Transit is skipped if set to NaN.
      """

    TransitDepth = 10 meter
      """
      Depth of flat and level flight during the transit part of the mission.
      """

    ApproachDepthRate = 0.05 meter_per_second
      """
      Descent depth rate (Positive depth rate means going down).
      """

    Repeat = 1 count
      """
      Number of times the vehicle should try to cycle through waypoints.
      """

    Lat1 = NaN degree
      """
      Latitude of waypoint 1. If nan, waypoint is skipped.
      """

    Lon1 = NaN degree
      """
      Longitude of waypoint 1. If nan, waypoint is skipped.
      """

    Lat2 = NaN degree
      """
      Latitude of waypoint 2. If nan, waypoint is skipped.
      """

    Lon2 = NaN degree
      """
      Longitude of waypoint 2. If nan, waypoint is skipped.
      """

    Lat3 = NaN degree
      """
      Latitude of waypoint 3. If nan, waypoint is skipped.
      """

    Lon3 = NaN degree
      """
      Longitude of waypoint 3. If nan, waypoint is skipped.
      """

    HoldAltitude = 7 meter
      """
      Desired vehicle altitude to maintain.
      """

    InvalidAltitudeTimeout = NaN minute
      """
      The mission will abort if no valid altitude readings are received within
      this specified time duration. Set this variable to NaN to disable this
      timeout functionality.
      """

    AltitudeIIRFilterDecay = 0.0 none
      """
      AltitudeServo single-pole IIR filter decay value.
      Low-pass filters the AltitudeServo depth command.
      The Decay value should be btween 0 to 1, set to 0 disable filtering.
      """

    InitDepth = 30 meter
      """
      Initial depth. The vehicle will spiral dive to this depth when leaving
      the surface. Necessary if no altitude reading is available form the
      surface (e.g., when the bottom is out of DVL range).
      """

    InitDepthTimeout = 30 minute
      """
      Maximum time duration for the vehicle to reach the initial depth. The
      vehicle will switch over to altitude following after the timeout is
      expired.
      """

    Speed = 1 meter_per_second
      """
      Thruster speed for the entier mission.
      """

    DepthDeadband = 0.0 meter

    MinAltitude = 5 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 205 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """
  }

  output {
    DoingComms = false
      """
      Mission variable (don't change). The mission sets this to true *before*
      the vehicle surfaces for comms.
      """

    StartFromSurface = true
      """
      Mission variable (don't change). The mission sets this to true *after*
      the vehicle surfaces for comms.
      """
  }

  # Mission timeout

  timeout duration=MissionTimeout

  # Safety nets and surfacing behaviors

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = MissionTimeout

  assign in sequence NeedComms:WaitForPitchUp = 0 minute

  insert Insert/BackseatDriver.tl

  insert Insert/PowerOnly.tl

  aggregate SurfaceComms {
    run when (
      called
      or ( elapsed ( Universal:time_fix ) > NeedCommsTime )
    )

    assign in sequence DoingComms = true

    call refId="NeedComms"

    assign in sequence DoingComms = false

    assign in sequence StartFromSurface = true
  }

  # Set default mass and VBS positions

  behavior Guidance:Mass {
    run in parallel

    set position = Control:VerticalControl.massDefault
  }

  behavior Guidance:Buoyancy {
    run in parallel

    set position = Control:VerticalControl.buoyancyNeutral
  }

  # Callable aggregates (priority matters, so these are done below important safety directives like StandardEnvelopes).

  aggregate DiveCmd {
    run when ( called )

    aggregate SpiralDive {
      """
      Spiral down from the surface to initial depth. Necessary when no
      altitude reading is available form the surface.
      """

      run while (
        StartFromSurface
        and ( not ( DoingComms ) )
      )

      aggregate dive {
        run in sequence

        behavior Guidance:SetSpeed {
          run in parallel

          set speed = Speed
        }

        behavior Guidance:Point {
          run in parallel

          set rudderAngle = 13 degree
        }

        behavior Guidance:Pitch {
          run in sequence

          timeout duration=InitDepthTimeout {
            syslog important "Timed out at current depth of " + Universal:depth~meter
                 + ". Switching to altitude servo."

            assign in sequence StartFromSurface = false
          }

          set depth = InitDepth
          set depthRate = ApproachDepthRate
        }

        assign in sequence StartFromSurface = false
      }
    }

    aggregate AltitudeServo {
      """
      Follow commanded altitude.
      """

      run while (
        not ( StartFromSurface )
        and ( not ( DoingComms ) )
      )

      aggregate dive {
        run in parallel

        assign in parallel Control:VerticalControl.depthDeadband = DepthDeadband

        behavior Guidance:SetSpeed {
          run in parallel

          set speed = Speed
        }

        behavior Guidance:AltitudeServo {
          run in parallel

          set targetAltitude = HoldAltitude
          set invalidAltitudeTimeout = InvalidAltitudeTimeout
          set iirFilterDecay = AltitudeIIRFilterDecay
        }
      }
    }
  }

  # Mission

  call id="StartingMission" refId="SurfaceComms"

  # Fire up science sensors

  insert Insert/Science.tl

  # Run

  aggregate Transit {
    """
    Transit flat and level to the starting waypoint at a fixed depth
    (skipped when transit Lat/Lon are set to NaN).
    """

    run in sequence

    break if (
      isNaN ( TransitLat )
      or ( isNaN ( TransitLon ) )
    )

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = Speed
    }

    behavior Guidance:Pitch {
      run in parallel

      set depth = TransitDepth
    }

    behavior Guidance:Waypoint id="TransitWpt" {
      run in sequence

      set latitude = TransitLat
      set longitude = TransitLon
    }

    call refId="SurfaceComms"
  }

  aggregate Lap {
    run in sequence repeat=Repeat

    aggregate Dive {
      run while ( not ( DoingComms ) )

      call refId="DiveCmd"
    }

    aggregate Wpt1 {
      run in sequence

      behavior Guidance:Waypoint {
        run in sequence

        set latitude = Lat1
        set longitude = Lon1
      }
    }

    aggregate Wpt2 {
      run in sequence

      behavior Guidance:Waypoint {
        run in sequence

        set latitude = Lat2
        set longitude = Lon2
      }
    }

    aggregate Wpt3 {
      run in sequence

      behavior Guidance:Waypoint {
        run in sequence

        set latitude = Lat3
        set longitude = Lon3
      }
    }

    call id="PhoneHome" refId="SurfaceComms"
  }
}