Science/smear_yoyo_sampling.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission Smear_yoyo_sampling {
  arguments {
    # Almost every mission should start with an overall timeout and a NeedCommsTime. Drift Missions will have an acoustic timeout instead of a NeedCommsTime.

    # You probably need to change these.

    NumSamplers = 1 count
      """
      Total number of ESP cartridges (Maximum 60) or CANON samplers. Set to 0
      to disable sampling.
      """

    # debug
    #     </Description><Units:count/><Value>3</Value></DefineArg>

    StartIndex = 1 count
      """
      Start index in ESP settings. If re-running mission, can skip settings of
      already-completed samples. Default is 1 (no skipping).
      """

    # debug
    #     </Description><Units:count/><Value>2</Value></DefineArg>

    CANONSamplerRotateOnly = 0 bool

    MissionTimeout = 2 hour
      """
      Maximum duration of mission
      """

    SurfaceCommsEndOfEachSample = true
      """
      Whether to go to surface for comms at completion of each sample
      (initialized to False.)
      """

    # debug
    #     </Description><False/></DefineArg>

    NeedCommsTimeInTransit = 30 minute
      """
      On the way transiting to the sampling location, how often to surface for
      commumications
      """

    BeingInterrogatedTimeout = 21 hour
      """
      If the vehicle does not receive an acoustic signal for more than this
      length of time, it will surface for communications. Set longer than
      MissionTimeout to effectively disable.
      """

    TrackAcousticTarget = false
      """
      Whether to track an acoustic target.
      """

    # debug
    #     </Description><True/></DefineArg>

    AcousticTargetContactLabel = 0 count
      """
      The acoustic address of the asset to be tracked
      """

    AcousticTargetDepth = NaN meter
      """
      Depth of acoustic target if known and fixed (or nearly fixed). For
      example, if the acoustic target is a Wave Glider, set it to zero. This
      will improve 2D projected position estimates in the Earth reference
      frame. Defaults to NaN.
      """

    AcousticTargetContactTimeout = 15 minute
      """
      Only use a sufficiently fresh handshake to update the tracking center.
      """

    MaxWaitNoFiring = 2 hour
      """
      If no firing after more than MaxWaitNoFiring, terminate mission.
      """

    # debug
    #     </Description><Units:hour/><Value>0.05</Value></DefineArg>

    SpeedTransit = 1.0 meter_per_second
      """
      Vehicle speed when transiting to the sampling location.
      """

    SpeedSampling = 1.0 meter_per_second
      """
      Vehicle speed when sampling on cylinder yoyo.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    TransitYoYoMinDepth = 10 meter
      """
      Minimum yoyo depth while transiting to the sampling location.
      """

    TransitYoYoMaxDepth = 20 meter
      """
      Maximum yoyo depth while transiting to the sampling location.
      """

    TransitCaptureRadius = 100 meter
      """
      Waypoint capture radius for transiting to the sampling location.
      """

    CylinderRadius = 20 meter
      """
      Radius of cylinder centered at the sampling location.
      """

    MaxCirclesOnCylinder = 1000 count
      """
      Maximum number of circles on cylinder.
      """

    TransitLatitude = NaN degree
      """
      The latitude of the sampling location. If NaN, will skip transit.
      """

    # debug
    #     </Description><Units:degree/><Value>36.80</Value></DefineArg>

    TransitLongitude = NaN degree
      """
      The longitude of the sampling location. If NaN, will skip transit.
      """

    # debug
    #     </Description><Units:degree/><Value>-121.82</Value></DefineArg>

    CenterLatitude = NaN degree
      """
      The latitude of the center of the circle. Fill this in to specify a
      start position, it will be overwritten once the vehicle receives an
      acoustic signal from the contact.
      """

    # debug
    #     </Description><Units:degree/><Value>36.80</Value></DefineArg>

    CenterLongitude = NaN degree
      """
      The longitude of the center of the circle. Fill this in to specify a
      start position, it will be overwritten once the vehicle receives an
      acoustic signal from the contact.
      """

    # debug
    #     </Description><Units:degree/><Value>-121.82</Value></DefineArg>

    CartridgeTypeCommon = -6 count
      """
      Value common to all samples unless set diffently: cartridge type.
      """

    CartridgeType[1..60] = -6 count
      """
      Sample {$}. Cartridge type.
      """

    ShallowBoundSmearCommon = NaN meter
      """
      Value common to all samples unless set diffently: shallow depth bound
      for smear sampling.
      """

    # debug
    #     </Description><Units:meter/><Value>5.0</Value></DefineArg>

    ShallowBoundSmear[1..60] = NaN meter
      """
      Shallow depth bound for smear sampling. Sample {$}.
      """

    DeepBoundSmearCommon = NaN meter
      """
      Value common to all samples unless set diffently: deep depth bound for
      smear sampling.
      """

    # debug
    #     </Description><Units:meter/><Value>15.0</Value></DefineArg>

    DeepBoundSmear[1..60] = NaN meter
      """
      Deep depth bound for smear sampling. Sample {$}.
      """

    WaitCommon = 5.0 minute
      """
      Value common to all samples unless set diffently: Wait time before
      firing.
      """

    Wait[1..60] = NaN minute
      """
      Wait time before firing. Sample {$}.
      """

    # Use caution when changing these.

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    MinAltitude = 7 meter
      """
      Minimum altitude for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    # You probably do not need to change these.

    UseCANONSampler = Science:CANONSampler.loadAtStartup
      """
      Whether to use CANON Sampler to sample.
      """

    UseESP = Science:ESPComponent.loadAtStartup
      """
      Whether to use ESP to sample.
      """

    CANONSamplerTriggerTimeout = 1 minute
      """
      How long to wait for a CANON Sampler sample to start.
      """

    CANONSamplerTimeout = Science:CANONSampler.sampleTimeout
      """
      How long to wait for a CANON Sampler sample to complete.
      """

    TrackingUpdatePeriod = 15 second
      """
      How long to wait between acoustic queries
      """

    NumberOfPings = 1 count
      """
      Number of return pings to request with each acoustic query (more than 1
      will activate oneway mode)
      """

    NumberOfFixesLowPass = 4 count
      """
      Number of fixes to average to produce smoothed lat/lon/dep output
      (initialized to 4).
      """

    NumberOfStartingFixesToIgnore = 8 count
      """
      Number of fixes to ignore at the start of mission (as the vehicle just
      leaves surface, contact's location estimate especailly bearing can be
      erroneous. Initialized to 8, corresponding to 2 minutes if query
      interval TrackingUpdatePeriod = 15 s.
      """

    CylinderCircleMaxError = 100 meter
      """
      If this distance away from the circle, drive straight towards (or away
      from the center). Otherwise, try to reduce distance from the ideal
      circle.
      """

    CylinderCircleTurnToPort = false
      """
      If true, vehicle turns to the left around the center point. If false,
      vehicle turns to the right.
      """

    KwpHeading = 0.010 radian_per_meter
      """
      Used to relax waypoint cross-track error constant that is adjusted for
      docking. (You can override this setting by passing an argument.)
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position
      """

    # Internal variables that you should not change

    NeedCommsTimeVeryLong = 100 hour
      """
      How often to surface for commumications during sampling. Huge number to
      disable needcomms.
      """
  }

  output {
    ShallowBoundSmearIndividual = NaN meter
      """
      YoYoMinDepth individual.
      """

    DeepBoundSmearIndividual = NaN meter
      """
      YoYoMaxDepth individual.
      """

    WaitIndividual = NaN minute
      """
      Wait individual.
      """

    CartridgeTypeIndividual = NaN count
      """
      Cartridge type individual.
      """

    CartridgeTypeSet = -6 count
      """
      Cartridge type. Initialized to -6.
      """

    ElapsedSinceStartOrLastSample = 0 hour
      """
      The mission sets this variable to reset the ESP sample timer.
      """

    ElapsedSinceLastCenterUpdate = 0 hour
      """
      The mission sets this variable to reset the center update timer.
      """

    ElapsedTime = 0 hour
      """
      Only for syslog.
      """

    ContactLatitudeLowpass = NaN degree
      """
      Low-pass filtered latitude of contact (initialized to NaN).
      """

    ContactLongitudeLowpass = NaN degree
      """
      Low-pass filtered longitude of contact (initialized to NaN).
      """

    YoYoMinDepth = 1.5 meter
      """
      Minimum depth while performing the YoYo behavior. Program will overwrite
      for each sampler, e.g., ShallowBoundSmear1.
      """

    YoYoMaxDepth = 20 meter
      """
      Maximum depth while performing the YoYo behavior. Program will overwrite
      for each sampler, e.g., DeepBoundSmear1
      """

    WaitDuration = 5.0 minute
      """
      Wait time before firing a sample. Program will set for each sampler,
      e.g., Wait1.
      """

    CommsEndOfSampleCompleted = false
      """
      End-of-sample comms completed. Initialized to False.
      """

    StoppedForNoFiringForTooLong = false
      """
      Mission stopped because of no firing for too long. Initialized to false.
      """

    DepthLogged = 0.0 meter

    TempLogged = 0.0 celsius

    ChlLogged = 0.0 microgram_per_liter

    MissionStartCommsCompleted = false
      """
      MissionStartComms is completed (initialized to false).
      """

    TransitCompleted = false
      """
      Transit is completed (initialized to False).
      """

    FlagSamplingOngoing = false
      """
      Flag of water sampling in process (initialized to false).
      """

    SampleCompleted = false
      """
      Sampling completed. Initialized to false.
      """

    SampleOptionsSet = false
      """
      Sample options (DepDiffFromPeakChl, ReportAtSurface, ReacquirePeak)
      already set. Initialized to false.
      """

    CntSamples = 1 count
      """
      Count of water samples (initilized to 1).
      """
  }

  # Missions should almost always start with a timeout and a NeedComms aggregate. Drift missions will not use NeedComms.

  timeout duration=MissionTimeout

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTimeVeryLong

  # Missions should almost always start with standard safety envelopes

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  behavior Sample:AbortSample {
    run in parallel
  }

  insert Insert/AbortDrift.tl {
    redefineArg AcousticTimeout = BeingInterrogatedTimeout
  }

  # Many missions will keep mass position fixed at the default.

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  insert Insert/Science.tl

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude
  }

  aggregate TrackingAcousticTarget {
    run while ( TrackAcousticTarget )

    behavior Estimation:Tracking {
      run in parallel

      set contactLabelSetting = AcousticTargetContactLabel
      set numberOfSamplesSetting = NumberOfPings
      set updatePeriodSetting = TrackingUpdatePeriod
      set numFixesLowPassSetting = NumberOfFixesLowPass
      set numStartingFixesToIgnoreSetting = NumberOfStartingFixesToIgnore
      set contactDepthSetting = AcousticTargetDepth
    }
  }

  aggregate TriggerSampling {
    run when ( called )

    aggregate TriggerESP {
      run in sequence

      break if ( not ( UseESP ) )

      assign in sequence DepthLogged = Universal:depth

      assign in sequence TempLogged = Universal:sea_water_temperature

      assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

      syslog important "Trigger ESP sampling. DepthLogged, TempLogged, ChlLogged = "
           + DepthLogged~meter + ", " + TempLogged~celsius + ", " + ChlLogged~microgram_per_liter + "."

      behavior Science:ESPCartridgeSelect {
        run in sequence

        timeout duration=P1M

        set cartridgeType = CartridgeTypeSet
      }

      readDatum {
        Science:ESPComponent.sampling
      }

      syslog important "Wait for ESP sampling to complete."

      readDatum {
        Science:ESPComponent.sample_number
      }
    }

    aggregate TriggerCANON {
      run in sequence

      break if ( not ( UseCANONSampler ) )

      assign in sequence DepthLogged = Universal:depth

      assign in sequence TempLogged = Universal:sea_water_temperature

      assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

      syslog important "Trigger CANON sampling. DepthLogged, TempLogged, ChlLogged = "
           + DepthLogged~meter + ", " + TempLogged~celsius + ", " + ChlLogged~microgram_per_liter + "."

      assign in parallel Science:CANONSampler.sampleTimeout = CANONSamplerTimeout

      assign in parallel Science:CANONSampler.rotateOnly = CANONSamplerRotateOnly

      readDatum id="TriggerCANONSampler" {
        timeout duration=CANONSamplerTriggerTimeout {
          syslog important "Timed out triggering CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sampling
      }

      readDatum {
        timeout duration=CANONSamplerTimeout {
          syslog important "Timed out sampling with CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sample_number
      }
    }
  }

  aggregate InsertWait {
    run when ( called )

    syslog important "Wait " + WaitDuration~minute + " before firing sample."

    behavior Guidance:Wait {
      run in sequence

      set duration = WaitDuration
    }
  }

  aggregate SetSampleOptions {
    run when ( called )

    aggregate SettingCartridgeTypeIndividual {
      run in sequence

      break if (
        isNaN ( CartridgeTypeIndividual )
        or ( not ( UseESP ) )
      )

      assign in sequence CartridgeTypeSet = CartridgeTypeIndividual
    }

    aggregate SettingCartridgeTypeCommon {
      run in sequence

      break if (
        not ( isNaN ( CartridgeTypeIndividual ) )
        or ( not ( UseESP ) )
      )

      assign in sequence CartridgeTypeSet = CartridgeTypeCommon
    }

    aggregate SettingYoYoMinDepthIndividual {
      run in sequence

      break if ( isNaN ( ShallowBoundSmearIndividual ) )

      assign in sequence YoYoMinDepth = ShallowBoundSmearIndividual
    }

    aggregate SettingYoYoMinDepthCommon {
      run in sequence

      break if (
        not ( isNaN ( ShallowBoundSmearIndividual ) )
      )

      assign in sequence YoYoMinDepth = ShallowBoundSmearCommon
    }

    aggregate SettingYoYoMaxDepthIndividual {
      run in sequence

      break if ( isNaN ( DeepBoundSmearIndividual ) )

      assign in sequence YoYoMaxDepth = DeepBoundSmearIndividual
    }

    aggregate SettingYoYoMaxDepthCommon {
      run in sequence

      break if (
        not ( isNaN ( DeepBoundSmearIndividual ) )
      )

      assign in sequence YoYoMaxDepth = DeepBoundSmearCommon
    }

    aggregate SettingWaitIndividual {
      run in sequence

      break if ( isNaN ( WaitIndividual ) )

      assign in sequence WaitDuration = WaitIndividual
    }

    aggregate SettingWaitCommon {
      run in sequence

      break if ( not ( isNaN ( WaitIndividual ) ) )

      assign in sequence WaitDuration = WaitCommon
    }

    syslog important "Set CartridgeType (if ESP), YoYoMinDepth, YoYoMaxDepth, WaitDuration to "
         + CartridgeTypeSet~count + ", " + YoYoMinDepth~meter + ", " + YoYoMaxDepth~meter + ", "
         + WaitDuration~minute + "."
  }

  aggregate MissionStart {
    run in sequence

    call id="MissionStartComms" refId="NeedComms"

    assign in sequence ElapsedSinceStartOrLastSample = 0 hour

    assign in sequence MissionStartCommsCompleted = true
  }

  aggregate TransitToSamplingLocation {
    run in sequence

    break if (
      isNaN ( TransitLatitude )
      or ( isNaN ( TransitLongitude ) )
    )

    assign in sequence NeedComms:DiveInterval = NeedCommsTimeInTransit

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = SpeedTransit
    }

    behavior Guidance:DepthEnvelope {
      run in parallel

      set minDepth = TransitYoYoMinDepth
      set maxDepth = TransitYoYoMaxDepth
      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:YoYo {
      run in parallel

      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:Buoyancy {
      run in parallel

      set position = BuoyancyNeutral
    }

    behavior Guidance:Waypoint {
      run in sequence

      set latitude = TransitLatitude
      set longitude = TransitLongitude
      set captureRadius = TransitCaptureRadius
    }

    assign in sequence NeedComms:DiveInterval = NeedCommsTimeVeryLong

    assign in sequence ElapsedSinceStartOrLastSample = 0 hour

    assign in sequence TransitCompleted = true
  }

  aggregate NoTransit {
    run in sequence

    break if (
      not (
        isNaN ( TransitLatitude )
        or ( isNaN ( TransitLongitude ) )
      )
    )

    assign in sequence TransitCompleted = true
  }

  aggregate InitializeWithGPSlatlon {
    run when (
      isNaN ( CenterLatitude )
      or ( isNaN ( CenterLongitude ) )
    )

    assign in sequence CenterLatitude = Universal:latitude_fix

    assign in sequence CenterLongitude = Universal:longitude_fix

    syslog important "Initialize CenterLatitude and CenterLongitude to GPS fix: "
         + CenterLatitude~degree + ", " + CenterLongitude~degree + "."
  }

  aggregate UpdateCenter {
    run when (
      elapsed ( Estimation:Tracking.range_to_contact ) < AcousticTargetContactTimeout
    )

    assign in sequence ContactLatitudeLowpass = Estimation:Tracking.contact_latitude_lowpass

    assign in sequence ContactLongitudeLowpass = Estimation:Tracking.contact_longitude_lowpass

    # debug
    #   <Syslog Severity="Important">Overwrite or update. CenterLatitude, CenterLongitude, contact_latitude, contact_longitude, contact_latitude_lowpass, contact_longitude_lowpass = <Arg Name="CenterLatitude"/><Units:degree/>, <Arg Name="CenterLongitude"/><Units:degree/>, <Estimation:Tracking.contact_latitude/><Units:degree/>, <Estimation:Tracking.contact_longitude/><Units:degree/>, <Estimation:Tracking.contact_latitude_lowpass/><Units:degree/>, <Estimation:Tracking.contact_longitude_lowpass/><Units:degree/></Syslog>

    aggregate UpdateWithContactLowpassLatLon {
      run when (
        not ( isNaN ( ContactLatitudeLowpass ) )
        and ( not ( isNaN ( ContactLongitudeLowpass ) ) )
        and ( elapsed ( ElapsedSinceLastCenterUpdate ) >= TrackingUpdatePeriod )
      )

      assign in sequence CenterLatitude = ContactLatitudeLowpass

      assign in sequence CenterLongitude = ContactLongitudeLowpass

      assign in sequence ElapsedTime = elapsed ( ElapsedSinceLastCenterUpdate )

      syslog info "Updating. Elapsed time since last center update, CenterLatitude, CenterLongitude = "
           + ElapsedTime~second + ", " + CenterLatitude~degree + ", " + CenterLongitude~degree

      assign in sequence ElapsedSinceLastCenterUpdate = 0 hour
    }
  }

  aggregate Cylinder {
    run in sequence

    break if ( CntSamples == ( NumSamplers + 1 count ) )

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = SpeedSampling
    }

    behavior Guidance:DepthEnvelope {
      run in parallel

      set minDepth = YoYoMinDepth
      set maxDepth = YoYoMaxDepth
      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:YoYo {
      run in parallel

      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:Buoyancy {
      run in parallel

      set position = BuoyancyNeutral
    }

    aggregate CylinderYoYo {
      run in sequence

      syslog important "Yoyo profile on a cylinder around location " + CenterLatitude~degree + ","
           + CenterLongitude~degree + ", at radius = " + CylinderRadius~meter + "."

      aggregate CylinderWrapper {
        run in sequence repeat=MaxCirclesOnCylinder

        assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

        behavior Guidance:Circle {
          run in sequence

          set latitude = CenterLatitude
          set longitude = CenterLongitude
          set radius = CylinderRadius
          set maxError = CylinderCircleMaxError
          set turnToPort = CylinderCircleTurnToPort
        }
      }
    }
  }

  aggregate TakeSamples {
    run in parallel

    break if ( CntSamples == ( NumSamplers + 1 count ) )

    aggregate NoFiringForTooLong {
      run when (
        TransitCompleted
        and ( elapsed ( ElapsedSinceStartOrLastSample ) > MaxWaitNoFiring )
        and ( not ( FlagSamplingOngoing ) )
        and ( not ( StoppedForNoFiringForTooLong ) )
      )

      assign in sequence ElapsedTime = elapsed ( ElapsedSinceStartOrLastSample )

      syslog important "No firing for too long. Stopping mission. Elapsed time since start or last sample, MaxWaitNoFiring, CntSamples = "
           + ElapsedTime~minute + ", " + MaxWaitNoFiring~minute + ", " + CntSamples~count

      behavior Guidance:Execute {
        run in sequence

        set command = "stop"
      }

      assign in sequence StoppedForNoFiringForTooLong = true
    }

    macro $k = 1..60 {
      aggregate SetOptionsOfSample$k {
        run when (
          not ( SampleOptionsSet )
          and ( CntSamples + StartIndex - 1 count == $k count )
          and ( CntSamples <= NumSamplers )
          and ( not ( FlagSamplingOngoing ) )
        )

        assign in sequence CartridgeTypeIndividual = CartridgeType[$k]

        assign in sequence ShallowBoundSmearIndividual = ShallowBoundSmear[$k]

        assign in sequence DeepBoundSmearIndividual = DeepBoundSmear[$k]

        assign in sequence WaitIndividual = Wait[$k]

        call id="SetOptionsForSample$k" refId="SetSampleOptions"

        assign in sequence SampleOptionsSet = true
      }
    }

    aggregate FiringNoCommsEndOfSample {
      run when (
        Universal:depth >= YoYoMinDepth
        and ( Universal:depth <= YoYoMaxDepth )
        and MissionStartCommsCompleted
        and TransitCompleted
        and ( not ( FlagSamplingOngoing ) )
        and ( CntSamples <= NumSamplers )
        and SampleOptionsSet
        and ( not ( SampleCompleted ) )
        and ( not ( SurfaceCommsEndOfEachSample ) )
      )

      assign in sequence CommsEndOfSampleCompleted = false

      assign in sequence FlagSamplingOngoing = true

      syslog important "Taking sample No." + CntSamples~count + "."

      assign in sequence ElapsedSinceStartOrLastSample = 0 hour

      call id="WaitBeforeFiring" refId="InsertWait"

      call id="Sampling" refId="TriggerSampling"

      syslog important "Sample No." + CntSamples~count + " completed."

      assign in sequence SampleCompleted = true

      assign in sequence ElapsedSinceStartOrLastSample = 0 hour

      assign in sequence FlagSamplingOngoing = false
    }

    aggregate FiringCommsEndOfSample {
      run when (
        Universal:depth >= YoYoMinDepth
        and ( Universal:depth <= YoYoMaxDepth )
        and MissionStartCommsCompleted
        and TransitCompleted
        and ( not ( FlagSamplingOngoing ) )
        and ( CntSamples <= NumSamplers )
        and SampleOptionsSet
        and ( not ( SampleCompleted ) )
        and SurfaceCommsEndOfEachSample
      )

      assign in sequence CommsEndOfSampleCompleted = false

      assign in sequence FlagSamplingOngoing = true

      syslog important "Taking sample No." + CntSamples~count + "."

      assign in sequence ElapsedSinceStartOrLastSample = 0 hour

      call id="WaitBeforeFiring" refId="InsertWait"

      call id="Sampling" refId="TriggerSampling"

      syslog important "Sample No." + CntSamples~count + " completed."

      call id="CommsSampling" refId="NeedComms"

      assign in sequence CommsEndOfSampleCompleted = true

      assign in sequence SampleCompleted = true

      assign in sequence ElapsedSinceStartOrLastSample = 0 hour

      assign in sequence FlagSamplingOngoing = false
    }

    aggregate IncrementSampleCounter {
      run when (
        SampleCompleted
        and (
          not ( SurfaceCommsEndOfEachSample )
          or (
            SurfaceCommsEndOfEachSample
            and CommsEndOfSampleCompleted
          )
        )
      )

      assign in sequence CntSamples = CntSamples + 1 count

      assign in sequence SampleOptionsSet = false

      assign in sequence SampleCompleted = false
    }
  }
}