Skip to content

Engineering/OnDock.tl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
mission {
  """
  Wait on dock, communicating when possible
  """

  arguments {
    DockedTime = 8 hour
      """
      Time to stay on dock. Mission timeout will be five minutes longer.
      """

    DetachedTimeout = Dock:Docked.detachTimeout
      """
      Time duration limit for determining if the vehicle is detached from the
      dock.
      """

    RangeTimeout = Dock:Docked.rangeTimeout
      """
      Maximum allowed time without acoustic range.
      """

    TrackingUpdatePeriod = 2 minute
      """
      How long to wait between acoustic queries.
      """

    NumberOfPings = 1 count
      """
      Number of pings requested each time.
      """

    TransponderCode = Dock:Dock.transponderCode
      """
      Transponder Address.
      """

    MaxDepth = BIT:CBIT.stopDepth
      """
      Maximum depth while docked.
      """

    MinAltitude = 5 meter
      """
      Minimum altitude
      """

    MinOffshore = 2 km
      """
      Minimum offshore
      """

    StayOnDock = false
      """
      If true, don't detach from dock at end of mission
      """

    IfconfigInterval = 30 minute
      """
      How long to wait between ifconfig runs
      """

    # Mission variables (do not change)
    MissionTimeout = DockedTime
      """
      Mission timeout (local variable, do not change)
      """
  }

  timeout duration=MissionTimeout

  insert Insert/StandardEnvelopes.tl
  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude
  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth
  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore
  # End docking 5 minutes before end of mission to allow clean undock
  assign in sequence MissionTimeout = DockedTime + 5 minute

  insert Insert/BackseatDriver.tl

  # Send data when connection exists
  readData {
    while (
      Sensor:DataOverHttps.connectionStatus == true
    )

    Universal:platform_communications
  }

  behavior Estimation:TrackAcousticContact {
    run in parallel

    set contactLabelSetting = TransponderCode
    set numberOfSamplesSetting = NumberOfPings
    set updatePeriodSetting = TrackingUpdatePeriod
  }

  aggregate restartDHCP {
    run when ( called )

    syslog important "Restarting DHCP..."

    behavior Guidance:Execute {
      run in sequence

      set command = "! /mnt/mmc/LRAUV/Tools/dhcp.sh"
    }
  }

  syslog important "Restarting logs"

  behavior Guidance:Execute {
    run in sequence

    set command = "restart logs"
  }

  # Kick DHCP again, in case it took us a while to close the arm in Docked
  call refId="restartDHCP"

  aggregate PeriodicCheck {
    run in parallel

    aggregate CheckIP {
      run in sequence

      behavior Guidance:Execute {
        run in sequence

        set command = "! ifconfig"
      }

      behavior Guidance:Wait {
        run in sequence

        set duration = IfconfigInterval
      }
    }
  }

  behavior Dock:Docked {
    run in sequence

    timeout duration=DockedTime

    set detachTimeout = DetachedTimeout
    set rangeTimeout = RangeTimeout
  }

  # Undock cleanly, instead of relying on DefaultWithUndock to come next
  aggregate Detach {
    run in sequence

    break if ( StayOnDock == true )

    syslog important "Mission ending, breaking off. Range: "
         + Estimation:TrackAcousticContact.range_to_contact~meter + "."

    behavior Dock:Undock {
      run in sequence
    }

    # Get our 10.89 IP back once we're on the surface
    call refId="restartDHCP"
  }
}