underIce/DefaultUnderTimeout.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission DefaultUnderTimeout {
  arguments {
    MissionTimeout = 4 hour
      """
      Maximum duration of mission
      """

    CommsInterval = 10 minute
      """
      How often to trigger uModem communications while the mission is in an
      idle state (on the dock).
      """

    HomingCommsInterval = 30 minute
      """
      How often to trigger uModem communications while the mission is actively
      homing to the dock (line capture).
      """

    TransponderCode = 2 count
      """
      Dock transponder address.
      """

    AcousticUpdatePeriod = 60 second
      """
      Time duration between acoustic queries while the mission is in an idle
      state (on the dock or surface).
      """

    HomingAcousticUpdatePeriod = 2.5 second
      """
      Time duration between acoustic queries while the mission is actively
      homing to the dock (line capture).
      """

    NumberOfPings = 1 count
      """
      Number of pings requested each time.
      """

    TrackingLowPassFilterWinSize = 1 count
      """
      Median filter bin size. Filters the contact estimated lat/lon position.
      Prefer odd number, set to 1 to disable filter.
      """

    TrackingLowPassFilterWinOverlap = true
      """
      Set True for "sliding" median filter, false for non-overlapping bins.
      """
  }

  output {
    # Mission Variables (don't change!)

    TrackingUpdatePeriod = 60 second
      """
      Mission variable (don't change). How long to wait between acoustic
      queries.
      """

    uModemCommsInterval = 10 minute
      """
      Mission variable (don't change). The mission updates the value of this
      variable to determine how often to trigger uModem communications.
      """

    Surface = -1 count
      """
      Mission variable (don't change). The mission will run in this mode to go
      to the surface after homing attempts have failed.
      """

    Docked = 0 count
      """
      Mission variable (don't change). The mission will run in this mode when
      the vehicle is docked.
      """

    Home = 1 count
      """
      Mission variable (don't change). The mission will run in this mode when
      homing to the dock.
      """

    DefaultMode = 0 count
      """
      Mission variable (don't change). The mission sets this variable to
      switch between default modes.
      """

    CaptureMode = -1 count
      """
      Mission variable (don't change). The mission sets this variable to
      reflect the termination status of the LineCapture insert.
      """

    StartComms = true
      """
      Mission variable (don't change). The mission sets this variable to reset
      the comms timer. Forces comms when true.
      """

    ElapsedSinceDefaultStarted = 0 minute
  }

  timeout duration=MissionTimeout

  # Initialize mission variables with default values

  assign in sequence DefaultMode = Docked

  assign in sequence TrackingUpdatePeriod = AcousticUpdatePeriod

  assign in sequence uModemCommsInterval = CommsInterval

  assign in sequence StartComms = true

  # Safety nets

  behavior Guidance:PitchEnvelope {
    run in parallel
  }

  # uModem communication directives

  aggregate uModemComms {
    run while (
      not ( DefaultMode == Surface )
      and (
        StartComms
        or ( elapsed ( StartComms ) > uModemCommsInterval )
      )
    )

    aggregate doComms {
      run in sequence

      syslog info "Initiating uModem comms cycle."

      # Reduce range interrogation rates to minimize interruptions to uModem comms packets

      assign in sequence TrackingUpdatePeriod = AcousticUpdatePeriod

      readDatum {
        timeout duration=P10M

        Universal:platform_communications
      }

      aggregate ResumeTracking {
        """
        Resume rapid acoustic interrogation rate if the mission is
        still actively homing to the dock.
        """

        run in sequence

        break if ( not ( DefaultMode == Home ) )

        assign in sequence TrackingUpdatePeriod = HomingAcousticUpdatePeriod
      }

      # This assignment restarts the comms timer

      assign in sequence StartComms = false
    }
  }

  # Notify directives.

  aggregate Notify {
    run in parallel

    aggregate {
      run in sequence

      aggregate {
        run in sequence repeat=48

        behavior Guidance:Wait {
          run in sequence

          set duration = 30 minute
        }

        assign in sequence ElapsedSinceDefaultStarted = elapsed ( Universal:mission_started )

        syslog important "Default Under mission has been running for "
             + ElapsedSinceDefaultStarted~minute
      }

      syslog important "Restarting logs."

      behavior Guidance:Execute {
        run in sequence

        set command = "restart logs"
      }
    }
  }

  # Add LineCapture directives.

  insert Insert/LineCapture.tl

  # Add SetNav directives.

  insert Insert/SetNavAcoustic.tl

  # Add track acoustic contact directives.

  aggregate TrackAcousticContact {
    run in parallel

    behavior Estimation:TrackAcousticContact {
      run in parallel

      set contactLabelSetting = TransponderCode
      set numberOfSamplesSetting = NumberOfPings
      set updatePeriodSetting = TrackingUpdatePeriod
      set numFixesLowPassSetting = TrackingLowPassFilterWinSize
      set lowPassOverlapSetting = TrackingLowPassFilterWinOverlap
    }
  }

  # Default mission sequence.

  behavior Guidance:Wait {
    """
    Wait a moment to see if the scheduler starts a new mission before
    starting to actually run Default.
    """

    run in sequence

    set duration = 13 second
  }

  aggregate Default {
    run in sequence

    aggregate Docked {
      """
      Keep the vehicle in an idle state while on the dock, transition
      to Home mode if detached.
      """

      run while ( DefaultMode == Docked )

      aggregate run {
        run in sequence

        syslog info "Running Docked. DefaultMode:" + DefaultMode~count

        aggregate initialize {
          run in sequence

          assign in sequence uModemCommsInterval = CommsInterval

          assign in sequence TrackingUpdatePeriod = AcousticUpdatePeriod

          assign in sequence StartComms = true
        }

        behavior Dock:Docked {
          run in sequence
        }

        assign in sequence DefaultMode = Home
      }
    }

    aggregate Home {
      """
      Execute the homing sequence.
      """

      run while ( DefaultMode == Home )

      aggregate run {
        run in sequence

        syslog info "Running Home sequence. DefaultMode:" + DefaultMode~count

        aggregate initialize {
          run in sequence

          assign in sequence uModemCommsInterval = HomingCommsInterval

          assign in sequence TrackingUpdatePeriod = HomingAcousticUpdatePeriod

          assign in sequence CaptureMode = Surface
        }

        # Execute the LineCapture sequence.

        call refId="LineCapture"

        assign in sequence CaptureMode = LineCapture:GuidanceMode

        aggregate CheckCaptureSuccess {
          run in sequence

          break if ( not ( CaptureMode == Docked ) )

          assign in sequence DefaultMode = Docked
        }

        assign in sequence DefaultMode = Surface
      }
    }

    aggregate Surface {
      run while ( DefaultMode == Surface )

      aggregate run {
        run in sequence

        syslog info "Running Surface sequence. DefaultMode:" + DefaultMode~count

        aggregate initialize {
          run in sequence

          assign in sequence TrackingUpdatePeriod = AcousticUpdatePeriod
        }

        behavior Guidance:GoToSurface {
          run in parallel
        }

        aggregate SurfaceComms {
          run in sequence repeat=288

          readDatum id="Read_GPS" {
            timeout duration=P5M

            Universal:time_fix
          }

          readDatum id="Read_Iridium_uModem" {
            timeout duration=P2H {
              behavior Guidance:Execute {
                run in sequence

                set command = "Burn on"
              }

              syslog critical "Dropped weight due to communications timeout."
            }

            Universal:platform_communications
          }

          behavior Guidance:Wait {
            run in sequence

            set duration = 5 minute
          }
        }
      }
    }
  }
}