Engineering/portuguese_ledge_nocomms.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission {
  """
  Mergulhe na agua imediatamente e ligue para casa apos uma volta.
  """

  arguments {
    MissionTimeout = 4 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 120 minute
      """
      How often to surface for commumications
      """

    DoCommsAtEndOfLap = false
      """
      Vehicle will surface for comms at end of each waypoint cycle (lap) when true.
      """

    AcousticContactTimeout = 15 minute
      """
      If the vehicle does not receive an acoustic signal for more than this
      length of time, it will surface for communications with shore.
      """

    Depth = 50 meter
      """
      Depth of flat and level flight during the mission.
      """

    Speed = 1 meter_per_second
      """
      Speed of vehicle (relative to water) during the mission.
      """

    MaxDepth = 60 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 4 kilometer
      """
      Minimum distance offshore for the entire mission.
      """

    MinAltitude = 5 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MassHold = true
      """
      Set to True in order to hold mass at default position, False to allow
      mass to run on its own.
      """

    BuoyancyHold = true
      """
      Set to True in order to hold buoyancy at neutral position, False to
      allow buoyancy to run on its own.
      """

    Repeat = 4 count
      """
      Number of times the vehicle should try to cycle through waypoints..
      """

    Lat1 = 36.695944 degree
      """
      Latitude of waypoint 1. If nan, waypoint is skipped.
      """

    Lon1 = -121.945120 degree
      """
      Longitude of waypoint 1. If nan, waypoint is skipped.
      """

    Lat2 = 36.696536 degree
      """
      Latitude of waypoint 2. If nan, waypoint is skipped.
      """

    Lon2 = -121.937544 degree
      """
      Longitude of waypoint 2. If nan, waypoint is skipped.
      """

    Lat3 = 36.693760 degree
      """
      Latitude of waypoint 3. If nan, waypoint is skipped.
      """

    Lon3 = -121.938647 degree
      """
      Longitude of waypoint 3. If nan, waypoint is skipped.
      """

    Lat4 = 36.698094 degree
      """
      Latitude of waypoint 4. If nan, waypoint is skipped.
      """

    Lon4 = -121.940450 degree
      """
      Longitude of waypoint 4. If nan, waypoint is skipped.
      """

    Lat5 = 36.695944 degree
      """
      Latitude of waypoint 5. If nan, waypoint is skipped.
      """

    Lon5 = -121.945120 degree
      """
      Longitude of waypoint 5. If nan, waypoint is skipped.
      """

    ContactLabel = 0 count
      """
      The acoustic address of the asset to be tracked
      """

    ContactDepth = NaN meter
      """
      The acoustic address of the asset to be tracked
      """

    TrackingUpdatePeriod = 60 second
      """
      How long to wait between acoustic queries
      """

    NumberOfPings = 1 count
      """
      Number of return pings to request with each acoustic query (more than 1
      will activate oneway mode)
      """

    PowerBackseat = true
      """
      Power the backseat
      """
  }

  timeout duration=MissionTimeout

  insert Insert/AbortDrift.tl {
    redefineArg AcousticTimeout = AcousticContactTimeout
  }

  behavior Estimation:Tracking {
    run in parallel

    set contactDepthSetting = ContactDepth
    set contactLabelSetting = ContactLabel
    set numberOfSamplesSetting = NumberOfPings
    set updatePeriodSetting = TrackingUpdatePeriod
  }

  insert Insert/Science.tl {
    """
    Most missions will run the science sensors. If you don't place this
    aggregate above NeedComms, science instruments get turned off on the
    last upcast and while floating on the surface.
    """

    redefineArg PeakDetectChlActive = true
  }

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert Insert/BackseatDriver.tl

  assign in sequence BackseatDriver:EnableBackseat = PowerBackseat

  insert Insert/PowerOnly.tl

  behavior Guidance:Buoyancy id="BuoyancyHold" {
    run while ( BuoyancyHold )

    set position = Control:VerticalControl.buoyancyNeutral
  }

  behavior Guidance:Pitch id="MassHold" {
    run while ( MassHold )

    set massPosition = Control:VerticalControl.massDefault
  }

  aggregate Transit {
    run in sequence

    behavior Guidance:Pitch {
      run in parallel

      set depth = Depth
    }

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = Speed
    }

    aggregate Lap {
      run in sequence repeat=Repeat

      aggregate Wpt1 {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat1
          set longitude = Lon1
        }
      }

      aggregate Wpt2 {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat2
          set longitude = Lon2
        }
      }

      aggregate Wpt3 {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat3
          set longitude = Lon3
        }
      }

      aggregate Wpt4 {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat4
          set longitude = Lon4
        }
      }

      aggregate Wpt5 {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat5
          set longitude = Lon5
        }
      }

      aggregate LapEndComms {
        run in sequence

        break if ( not ( DoCommsAtEndOfLap ) )

        # DO NOT REMOVE the syslog entry below. The MissionManager seems to ignore the value of DoCommsAtEndOfLap, does not evaluate the Break statement properly, and always calls NeedComms. Adding the syslog call somehow fixes it.
        syslog info "Completed lap. Surfacing for GPS."

        call id="Ligue_para_casa" refId="NeedComms"
      }
    }
  }
}