underIce/profile_stationUnder.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission profile_stationUnder {
  """
  This mission yoyos in a circle around a specified location. Designed for
  under ice.
  """

  arguments {
    # Mission-wide settings

    MissionTimeout = 2 hour
      """
      Maximum duration of mission
      """

    DetachTimeout = 20 minute
      """
      Maximum time to spend getting off the dock
      """

    # You probably need to change these.

    Lat = 44.847 degree
      """
      The latitude of the center of the circle.
      """

    Lon = -67.577535 degree
      """
      The longitude of the center of the circle.
      """

    Radius = 50 meter
      """
      Radius to circle at
      """

    # You probably do not need to change these.

    YoYoMinDepth = 2.5 meter
      """
      Minimum depth while performing the YoYo behavior.
      """

    YoYoMaxDepth = 5 meter
      """
      Maximum depth while performing the YoYo behavior.
      """

    YoYoMinAltitude = 4 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    YoYoPitch = 15 degree
      """
      Pitch (plus and minus) for yo-yo behavior.
      """

    Speed = 1 meter_per_second
      """
      Vehicle speed.
      """

    # You are even less likely to need to change these.

    CircleMaxError = 1 meter
      """
      If this distance away from the circle, drive straight towards (or away
      from the center). Otherwise, try to reduce distance from the ideal
      circle.
      """

    CircleTurnToPort = false
      """
      If true, vehicle turns to the left around the center point. If false,
      vehicle turns to the right.
      """

    KwpHeading = 0.010 radian_per_meter
      """
      Used to relax waypoint cross-track error constant that is adjusted for
      docking. (You can override this setting by passing an argument.)
      """

    MinAltitude = 2 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 8 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 10 meter
      """
      Minimum offshore distance for the entire mission.
      """

    MicromodemCommsInterval = 5 minute
      """
      How often to trigger Umodem communications
      """

    TransponderCode = 2 count
      """
      Transponder Address.
      """

    TrackingUpdatePeriod = 2.5 second
      """
      How long to wait between acoustic queries.
      """

    NumberOfPings = 1 count
      """
      Number of pings requested each time.
      """
  }

  # Missions should almost always start with a timeout

  timeout duration=MissionTimeout

  insert Insert/Science.tl {
    """
    Most missions will run the science sensors.
    """

    redefineArg PeakDetectChlActive = true
  }

  insert id="MicromodemComms" Insert/MicromodemComms.tl {
    redefineArg CommsInterval = MicromodemCommsInterval
  }

  # Missions should almost always start with standard safety envelopes; most missions should not expose the parameters of these envelopes.

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  # Many missions will keep mass position and buoyancy volume fixed at defaults.

  aggregate Detach {
    run in sequence

    timeout duration=DetachTimeout {
      syslog important "Timed out trying to detach from dock. Stopping mission."

      behavior Guidance:Execute {
        run in sequence

        set command = "stop"
      }
    }

    syslog important "Detaching from dock."

    # Turn on tracking so we get some ranges to see how far we are from the dock

    behavior Estimation:TrackAcousticContact {
      run in parallel

      set contactLabelSetting = TransponderCode
      set numberOfSamplesSetting = NumberOfPings
      set updatePeriodSetting = TrackingUpdatePeriod
    }

    # Time to leave the dock!

    behavior Dock:Undock {
      run in sequence
    }
  }

  aggregate ProfileStation {
    run in sequence

    behavior Guidance:Pitch {
      run in parallel

      set massPosition = Control:VerticalControl.massDefault
    }

    behavior Guidance:Buoyancy {
      run in parallel

      set position = Control:VerticalControl.buoyancyNeutral
    }

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = Speed
    }

    behavior Guidance:DepthEnvelope {
      """
      Another depth envelope for the YoYo behavior. This envelope
      should fall within the limits of the standard safety envelopes
      in Insert/StandardEnvelopes.tl in order to avoid commanding
      high pitch angles for depth-terminated YoYos.
      """

      run in parallel

      set minDepth = YoYoMinDepth
      set maxDepth = YoYoMaxDepth
      set pitch = YoYoPitch
    }

    behavior Guidance:AltitudeEnvelope {
      """
      Another altitude envelope for the YoYo behavior. This envelope
      should fall within the limits of the standard safety envelopes
      in Insert/StandardEnvelopes.tl in order to avoid commanding
      high pitch angles for bottom-terminated YoYos.
      """

      run in parallel

      set minAltitude = YoYoMinAltitude
      set pitch = YoYoPitch
    }

    behavior Guidance:YoYo {
      run in parallel

      set pitch = YoYoPitch
    }

    aggregate CircleWrapper {
      run in sequence repeat=4096

      assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

      behavior Guidance:Circle {
        run in sequence

        set latitude = Lat
        set longitude = Lon
        set radius = Radius
        set maxError = CircleMaxError
        set turnToPort = CircleTurnToPort
      }
    }
  }
}