Skip to content

Science/sci2_noyo_optim.tl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
mission sci2_noyo_optim {
  """
  Vehicle transits to the specified waypoints at the commanded depth
  (flat-and-level, no yoyos) with science, Optim camera, and multiray
  lights on.
  """

  arguments {
    MissionTimeout = 2 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 60 minute
      """
      How often to surface for commumications
      """

    Depth = 35 meter
      """
      Depth of flat and level flight during the mission.
      """

    Repeat = 1 count
      """
      Number of times the vehicle should try to cycle through waypoints.
      """

    Lat[1..8] = NaN degree
      """
      Latitude of waypoint {$}. If nan, waypoint is skipped.
      """

    Lon[1..8] = NaN degree
      """
      Longitude of waypoint {$}. If nan, waypoint is skipped.
      """

    FastSpeed = 1 meter_per_second
      """
      Speed while transiting to waypoint.
      """

    ApproachDepth = 30 meter
      """
      Depth for initial descent form the surface.
      """

    ApproachSpeed = 0.7 meter_per_second
      """
      Speed while descending to target depth.
      """

    ApproachDepthRate = 0.05 meter_per_second
      """
      Descent depth rate (Positive depth rate means going down).
      """

    ApproachPitchLimit = 20 degree
      """
      Max vehicle pitch (+/-) when decending from the surface.
      """

    ApproachDepthTimeout = 15 minute
      """
      Maximum time duration for the vehicle to reach the target depth
      """

    ApproachSettleTimePreDive = 1 minute
      """
      Time duration for the vehicle to pump down the VBS *BEFORE* leaving the
      surface.
      """

    ApproachSettleTimePostDive = 3 minute
      """
      Time duration for the vehicle to settle *AFTER* reaching the target
      depth.
      """

    kpDepth = 0.07 radian_per_meter
      """
      Dive loop proportional gain (applied only while the vehicle is
      descending to target depth).
      """

    SlowSpeed = 0.25 meter_per_second
      """
      Set this to something other than Nan if slow speed filming with a
      wide depth deadband is desired.
      """

    DepthDeviationSlow = 3 meter
      """
      Allowable +/- deviation from depth during slow flight. Needs a SlowSpeed
      to be set.
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position during the mission. Defaults to
      buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy.
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position.
      """

    MinAltitude = 2 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    LightMode = 2 count
      """
      Mode for MultiRay lights at depth. 0 is off, 1 is red, 2 is white
      """

    BrightnessWhite = 100 none_int
      """
      White MultiRay LED brightness, 0-100
      """

    BrightnessRed = 100 none_int
      """
      Red MultiRay LED brightness, 0-100
      """

    BackseatWait = 30 second
      """
      How long to wait for the backseat to power up before attempting to power the Optim
      """

    InitialSampleTime = 1 second
      """
      PowerOnly sample time for initial record. Will go back to continuous after startup.
      """
  }

  output {
    DiveMode = 0 count
      """
      Mission variable (don't change). The mission sets this variable to
      switch between dive modes. Initialized to DoingComms.
      """

    DoingComms = 0 count
      """
      Mission variable (don't change). The mission will run in this to mode
      when doing surface comms.
      """

    InitialDive = 1 count
      """
      Mission variable (don't change). The mission will run in this mode after
      surface comms are done to dive the vehicle to the approach depth.
      """

    SettleAtDepth = 2 count
      """
      Mission variable (don't change). The mission will run in this mode to
      settle the vehicle at the target depth.
      """

    MaintainDepth = 3 count
      """
      Mission variable (don't change). The mission will run in this mode to
      maintain the vehicle at the target depth.
      """

    RecordingEnabled = false
      """
      Mission variable (don't change). Reflects intended recording state.
      """

    LightsEnabled = false
      """
      Mission variable (dont' chage). Reflects intended light state.
      """
  }

  # Mission timeout

  timeout duration=MissionTimeout

  # Science!

  insert Insert/Science.tl {
    """
    Run the science sensors.
    """
  }

  # Safety nets and surfacing behaviors

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = MissionTimeout

  assign in sequence NeedComms:WaitForPitchUp = 0 minute

  insert Insert/BackseatDriver.tl
  assign in parallel BackseatDriver:EnableBackseat = true

  behavior Guidance:Buoyancy {
    run in parallel

    set position = BuoyancyNeutral
  }

  # Power lights and camera when recording enabled
  readData strategy="MinError" {
    while ( RecordingEnabled )

    Sensor:PowerOnly.sampleLoad1
  }

  readData strategy="MinError" {
    while ( LightsEnabled )

    Sensor:MultiRay.lightModeLog
  }

  aggregate OptimStartup {
    run in sequence

    syslog info "Waiting " + BackseatWait~s + " for backseat to start up..."

    behavior Guidance:Wait {
      run in sequence

      set duration = BackseatWait
    }

    # Power-cycle Optim with some rather specific timing requirements to start up
    aggregate UseMission {
      run in sequence

      assign in parallel Sensor:PowerOnly.sampleTime1 = InitialSampleTime

      assign in sequence RecordingEnabled = true

      syslog info "Disabling Optim recording after " + InitialSampleTime~s
      assign in sequence RecordingEnabled = false

      behavior Guidance:Wait {
        run in sequence

        set duration = InitialSampleTime
      }

      assign in sequence RecordingEnabled = true
      syslog info "Powering up Optim to try to tide over gap to handoff..."
    }

    assign in sequence RecordingEnabled = true
    assign in sequence LightsEnabled = true
    assign in sequence Sensor:MultiRay.lightModeCommand = LightMode

    syslog important "Enabling backseat, camera, and multiray"

    aggregate setRed {
      run in sequence

      break if ( LightMode != 1 count )

      assign in sequence Sensor:MultiRay.brightnessRed = BrightnessRed
      syslog info "Setting multiray red brightness to" + BrightnessRed~count
    }

    aggregate setWhite {
      run in sequence

      break if ( LightMode != 2 count )

      assign in sequence Sensor:MultiRay.brightnessWhite = BrightnessWhite
      syslog info "Setting muliray white brightness to" + BrightnessWhite~count
    }
  }

  aggregate SurfaceComms {
    run when (
      called
      or ( elapsed ( Universal:time_fix ) > NeedCommsTime )
    )

    assign in sequence DiveMode = DoingComms

    call refId="NeedComms"

    assign in sequence DiveMode = InitialDive
  }

  aggregate DiveCmd {
    """
    Called when the vehicle should be underwater. Arbitrates between 4
    dive modes: 1) descend from the surface to initial depth. 2) settle
    at target depth using the VB. 3) cruise at target depth and go slow
    while within depth deviation bounds if a slow speed is set.
    """

    run when ( called )

    aggregate InitialDive {
      """
      Descend from the surface to target depth, limit pitch and
      depth-rate.
      """

      run while ( DiveMode == InitialDive )

      aggregate dive {
        run in sequence

        assign in parallel Control:VerticalControl.pitchLimit = ApproachPitchLimit

        assign in parallel Control:VerticalControl.kpDepth = kpDepth

        behavior Guidance:Mass {
          run in parallel

          set position = MassDefault
        }

        # behavior Guidance:Buoyancy {
        #   run in parallel

        #   set position = BuoyancyNeutral
        # }

        syslog info "Waiting for "
             + ApproachSettleTimePreDive~minute + "while pumping down to neutral."

        behavior Guidance:Wait {
          """
          Take a few moments to ensure the VBS reaches neutral.
          """

          run in sequence

          set duration = ApproachSettleTimePreDive
        }

        syslog "Moving to " + ApproachDepth~meter

        aggregate ApproachDepth {
          run in sequence

          behavior Guidance:SetSpeed {
            run in parallel

            set speed = ApproachSpeed
          }

          behavior Guidance:Pitch {
            run in sequence

            timeout duration=ApproachDepthTimeout {
              syslog important "Timed out while trying to reach target depth at current depth of "
                   + Universal:depth~meter

              behavior Guidance:Execute {
                run in sequence

                set command = "stop"
              }
            }

            set depth = ApproachDepth
            set depthRate = ApproachDepthRate
          }
        }

        assign in sequence DiveMode = SettleAtDepth
      }
    }

    aggregate SettleAtDepth {
      """
      Take a few more moments here to make sure the vehicle is settled
      at the target depth.
      """

      run while ( DiveMode == SettleAtDepth )

      aggregate dive {
        run in sequence

        syslog info "Reached " + Universal:depth~meter + ", settling for "
             + ApproachSettleTimePostDive~minute

        behavior Guidance:Pitch {
          run in parallel

          set depth = Depth
        }

        behavior Guidance:Wait {
          run in sequence

          set duration = ApproachSettleTimePostDive
        }

        assign in sequence DiveMode = MaintainDepth
      }
    }

    aggregate MaintainDepth {
      """
      Cruise at the target depth.
      """

      run while (
        DiveMode == MaintainDepth
        and ( Universal:depth > ( Depth + DepthDeviationSlow ) )
        or ( Universal:depth < ( Depth - DepthDeviationSlow ) )
      )

      aggregate dive {
        run in parallel

        aggregate ThrusterDive {
          run while ( FastSpeed > 0.0 meter_per_second )

          behavior Guidance:Mass {
            run in parallel

            set position = MassDefault
          }

          # behavior Guidance:Buoyancy {
          #   run in parallel

          #   set position = BuoyancyNeutral
          # }

          behavior Guidance:SetSpeed {
            run in parallel

            set speed = FastSpeed
          }
        }

        behavior Guidance:Pitch {
          run in parallel

          set depth = Depth
        }
      }
    }

    aggregate MaintainDepthSlow {
      """
      Cruise slow at the target depth.
      """

      run while (
        ( not isNaN ( SlowSpeed ) )
        and ( DiveMode == MaintainDepth )
        and ( Universal:depth <= ( Depth + DepthDeviationSlow ) )
        and ( Universal:depth >= ( Depth - DepthDeviationSlow ) )
      )

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = SlowSpeed
      }

      # Let's make sure the vertical control depth deadband doesn't interfere with our mission
      # level version of the deadband. And we'll add an extra 3m so we don't trigger any
      # faults inside vertical control when attempting to regain the commanded depth.
      assign in parallel Control:VerticalControl.depthDeadband = ( DepthDeviationSlow + 3 m )

      behavior Guidance:Buoyancy {
        run in parallel

        set position = NaN cc
      }

      behavior Guidance:Pitch {
        run in parallel

        set depth = Depth
      }
    }
  }

  # Start mission sequence

  call id="StartingMission" refId="SurfaceComms"

  aggregate Lap {
    run in sequence repeat=Repeat

    aggregate Dive {
      run while ( not ( DiveMode == DoingComms ) )

      call refId="DiveCmd"
    }

    aggregate Wpt1 {
      run in sequence

      behavior Guidance:Waypoint {
        run in sequence

        set latitude = Lat[1]
        set longitude = Lon[1]
      }
    }

    macro $i = 2..7 {
      aggregate Wpt$i {
        run in sequence

        behavior Guidance:Waypoint {
          run in sequence

          set latitude = Lat[$i]
          set longitude = Lon[$i]
        }
      }
    }
  }
}