Science/track_sample.tl

# -   Copyright (c) 2024 MBARI
# -   MBARI Proprietary Information. Confidential. All Rights Reserved
# -   Unauthorized copying or distribution of this file via any medium is strictly
# -   prohibited.
# -
# -   WARNING - This file contains information whose export is restricted by the
# -   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
# -   amended. Violations of these export laws are subject to severe civil and/or
# -   criminal penalties.
mission TrackAndSample {
  arguments {
    # Almost every mission should start with an overall timeout and a NeedCommsTime. Drift Missions will have an acoustic timeout instead of a NeedCommsTime.

    # You probably need to change these.

    NumSamplers = 1 count
      """
      Total number of ESP cartridges (Maximum 60) or CANON samplers. Set to 0
      to disable sampling.
      """

    MissionTimeout = 20 hour
      """
      Maximum duration of mission
      """

    AcousticTrackingTimeout = 240 hour
      """
      If the vehicle does not receive an acoustic signal for more than this
      length of time, it will surface for communications. Set longer than
      MissionTimeout to effectively disable.
      """

    NeedCommsTimeTransit = 60 minute
      """
      On yo-yo transects, how often to surface for commumications
      """

    NeedCommsTimeInPatchTracking = 300 minute
      """
      Maximum time between surfacings for communications during patch
      tracking. This is checked only when the vehicle is back to the patch center.
      """

    NeedCommsTimeMarginPatchTracking = 60 minute
      """
      In case vehicle does not surface on periodic rounds of InLeg or
      CrossLeg, vehicle will be forced to surface at
      NeedCommsTimePatchTracking+NeedCommsTimeMarginPatchTracking.
      """

    WaitTimeAfterBouncing = 5 minute
      """
      During tracking, after the vehicle bounces off the boundary (defined by
      minimum distance to shore or polygon sides), wait this long before
      re-checking the distance.
      """

    MaxWaitTimeNoFiring = 2 hour
      """
      If no firing after more than MaxWaitNoFiring, terminate mission.
      """

    MaxWaitTimeNotAchievingDepth = 0.5 hour
      """
      Maximum wait time the vehicle cannot reach the targeted depth.
      """

    LatPatchTrackingStart = NaN degree
      """
      Latitude of patch tracking start location. If nan, transit is skipped.
      """

    # debug
    #     </Description><Units:degree/><Value>36.810</Value></DefineArg>

    LonPatchTrackingStart = NaN degree
      """
      Longitude of patch tracking start location. If nan, transit is skipped.
      """

    # debug
    #     </Description><Units:degree/><Value>-121.855</Value></DefineArg>

    SendSampleStatusData = true
      """
      Whether to senddata to acoustic modem.
      """

    # debug
    #     </Description><False/></DefineArg>

    SendSampleDataToMultipleModems = false
      """
      Whether to senddata to more than one modem.
      """

    # debug
    #     </Description><True/></DefineArg>

    ModemID1 = 1 enum
      """
      Modem ID1. Initialized to 1.
      """

    ModemID2 = 4 enum
      """
      Modem ID2. Initialized to 4.
      """

    ChlPeakDetect = true
      """
      Whether to sample at peak-chl
      """

    SalinityPeakDetect = true
      """
      Whether to sample at peak-salinity
      """

    OilPeakDetect = false
      """
      Whether to sample at peak-oil
      """

    PlanktivoreLMavgROIPeakDetect = false
      """
      Whether to sample at peak-PlanktivoreLMavgROI
      """

    # debug
    #     </Description><True/></DefineArg>

    DurationOfInitialDive = 1.0 minute
      """
      On the first dive for looking for the chl max, run at SpeedInitialDive
      for this duration (e.g., 1 m/s spiral to dive fast).
      """

    SpeedTransit = 1.0 meter_per_second
      """
      Vehicle speed when transiting.
      """

    SpeedOfInitialDive = 1.0 meter_per_second
      """
      Vehicle speed during initial dive (for looking for the chl max). 0.0 for
      drift mode (prop off); 1.0 for spiral mode (prop on). Initialized to 1
      m/s.
      """

    SpeedOfSampling = 1.0 meter_per_second
      """
      Vehicle speed during sampling: 0.0 for drift mode (prop off); 1.0 for
      donut mode (prop on). Initialized to 1 m/s.
      """

    # debug
    #     </Description><Units:meter_per_second/><Value>0</Value></DefineArg>

    RudderAngleInInitialDive = 9 degree
      """
      Rudder angle in initial spiral-down to leave surface. Initialized to 9
      degrees.
      """

    RudderAngleInDonutSampling = 13 degree
      """
      Rudder angle during donut sampling.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    MinWaterDepth = 10 meter
      """
      Minimum water depth for the entire mission.
      """

    MinAltitude = 7 meter
      """
      Minimum altitude for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    MarginOfMinOffshore = 100 meter
      """
      If closer than MinOffshore+MarginMinOffshore, turn back from shore.
      """

    MinDistanceFromPolygonSides = 200 meter
      """
      If a operational safety polygon is specified and the vehicle is closer
      than this minimum distance to the polygon sides, turn back.
      """

    ShallowBoundChl = 4.5 meter
      """
      Shallow depth bound for chl-peak detection.
      """

    DeepBoundChl = 17 meter
      """
      Deep depth bound for chl-peak detection.
      """

    BeginThresholdChl = 1.0 microgram_per_liter
      """
      If non-NaN, sets threshold for starting horizontal patch detection
      """

    TriggerThresholdChl = 2.5 microgram_per_liter
      """
      If non-NaN, sets threshold for triggering sampling. Chl value of 2.5
      mug/L corresponds to HS2 fluorescence reading of 0.001 on Dorado.
      """

    BeginThresholdSalt = 33.0 psu
      """
      If non-NaN, sets salinity threshold for starting horizontal patch
      detection
      """

    BeginThresholdOil = 0.2 kilogram_per_cubic_meter
      """
      If non-NaN, sets oil threshold for starting horizontal patch detection
      """

    BeginThresholdPlanktivoreLMavgROI = 50 count_per_second
      """
      If non-NaN, sets Planktivore LMavgROI threshold for starting horizontal patch
      detection
      """

    WpBearingInit = 90 degree
      """
      Bearing being followed in the current leg. Set this to initialize start
      direction of patch tracking.
      """

    # debug
    #     </Description><Units:degree/><Value>270</Value></DefineArg>

    FractionOffPeak = 90 percent
      """
      When filtered horizontal value is this fraction of the peak, consider it
      outside the patch.
      """

    # debug
    #     </Description><Units:percent/><Value>75</Value></DefineArg>

    CountRoundsCrossLegSurfacing = 5 count
      """
      One round = one count of outleg. In TrackPatchYoyo.tl, when CntRounds (initialized to 1) counts to 5 and the ensuing CrossLeg is finished, the vehicle has completed 2 full 4-direction sweeps and is back to the patch center. When CntRounds counts to CountRoundsCrossLegSurfacing and the ensuing CrossLeg is finished (back to the patch center), the vehicle surfaces.
      """

    MaxRepeatsPatchTracking = 2 count
      """
      The maximum number of repeats of calling TrackPatchYoyo.tl (for the case of NeedCommsTimeInPatchTracking is reached but CountRoundsBetweenCrossLegSurfacing is not reached).
      """

    WpMaxDistance = 1000 meter
      """
      Maximum length of each tracking leg
      """

    WpMaxDuration = 4000 second
      """
      Maximum duration of each tracking leg
      """

    SignalDetectionTimeout = 30 minute
      """
      Look for signal for this long. If none found within this timeout, switch
      to the next leg.
      """

    YoYoMinDepthPatchTracking = 4.5 meter
      """
      Minimum depth while performing the YoYo behavior.
      """

    YoYoMaxDepthPatchTracking = 27 meter
      """
      Maximum depth while performing the YoYo behavior.
      """

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    WaitTimeDepUndulationCommon = 1.0 minute
      """
      Value common to all samples unless set differently: Wait duration for
      the depth undulation to damp down.
      """

    CartridgeTypeCommon = -6 count
      """
      Cartridge type value common to all samples unless set differently. Initialized to -6.
      """

    # Cartridge type for individual cartridges:

    CartType[1..60] = NaN count
      """
      Cartridge {$}.
      """

    # Wait duration for the depth undulation to damp down. Sample 1's is longer than that of the other samples.

    WaitDepUndulation[1..60] = {
      1..1 : 5.0 minute,
      2..60 : 1.0 minute
    }
      """
      Sample {$}.
      """

    # Use caution when changing these.

    AscentRate = -0.04 meter_per_second
      """
      Go-up depth rate (Negative depth rate means going up).
      """

    DescentRate = 0.2 meter_per_second
      """
      Go-down depth rate (Positive depth rate means going down).
      """

    # You probably do not need to change these.

    IntervalRestartLogs = 24 hour

    UseCANONSampler = Science:CANONSampler.loadAtStartup
      """
      Whether to use CANON Sampler to sample.
      """

    UseESP = Science:ESPComponent.loadAtStartup
      """
      Whether to use ESP to sample.
      """

    CANONSamplerTriggerTimeout = 1 minute
      """
      How long to wait for a CANON Sampler sample to start.
      """

    CANONSamplerTimeout = Science:CANONSampler.sampleTimeout
      """
      How long to wait for a CANON Sampler sample to complete.
      """

    RiseFromTurningDepth = 2.5 meter
      """
      Peak chl on a profile is registered at the beginning of the next yoyo
      profile. In this mission, the peak chl on the descending profile is
      saved when the vehicle has turned onto the next yoyo profile (ascending
      profile) and is at least "RiseFromDeepTurningPoint" away from the
      turning depth.
      """

    DepthChangeThreshAttitudeFlip = 2.0 meter
      """
      Depth change threshold for determining vehicle attitude flip.
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    SurfacePitch = 20 degree
      """
      Pitch to maintain while ascending
      """

    SurfaceDepthRate = NaN meter_per_second
      """
      Depth rate to maintain while ascending. Set to NaN if using pitch
      """

    Turn = 90 degree
      """
      Amount to turn at each leg
      """

    NumberOfProfilesSlidingwindow = 100 count
      """
      Length of horizontal sliding window. Picks the highest yoyo-wise chl
      peak (after low-pass filtering by a filter of length
      FilterWidthHorizontal) within this window. Ignore older highs because
      ocean is changing.
      """

    LengthOfLPWindow = 20 count
      """
      Low-pass window length (based on depth sensor sampling interval 0.4
      second) for low-pass filtering.
      """

    LengthOfMedianFilter = 5 count
      """
      Median filter length (only for chlorophyll fluorescence which tends to
      have spikes). The median-filtered signal enters the succeeding low-pass
      filter. If set to 1, then no median filtering, i.e., the raw
      fluorescence signal directly enters the low-pass filter.
      """

    # debug
    #     </Description><Units:count/><Value>1</Value></DefineArg>

    WidthOfFilterHorizontal = 4 count
      """
      Width of boxcar filter used in horizontal patch detection
      """

    GainProportional = 1 none
      """
      Proportional gain for temperature holding control loop.
      """

    # debug
    #     </Description><Units:none/><Value>2</Value></DefineArg>

    GainIntegral = 0 none
      """
      Integral gain for temperature holding control loop.
      """

    # debug
    #     </Description><Units:none/><Value>0.75</Value></DefineArg>

    GainDerivative = 0 none
      """
      Derivative gain for temperature holding control loop.
      """

    VariationPerMeter = 0.2 reciprocal_meter
      """
      Expected temperature change per meter.
      """

    # debug
    #     </Description><Units:reciprocal_meter/><Value>0.25</Value></DefineArg>
    #     </Description><Units:reciprocal_meter/><Value>0.01</Value></DefineArg>

    BuoyDiveAccel = 0.0025 meter_per_second_squared
      """
      In buoyancy-only mode, maxBuoyDiveAccel needs to be set at least an
      order of magnitude higher than that in Control.cfg.
      """

    BuoyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position
      """
  }

  output {
    # Internal variables that you should not change

    Reverse = 180 degree
      """
      Change in bearing which reverses vehicle direction
      """

    TwoPi = 360 degree
      """
      Applied to stop run-up of angles
      """

    PatchDetectOn = false
      """
      Mission sets this to true when the patch has been crossed. Initialized
      to False.
      """

    WpDone = true
      """
      Mission sets this to true when the cross-patch waypoint has been
      reached. Initialized to True.
      """

    FlagTurnBack = false
      """
      Flag of turning back from shore. Initialized to False.
      """

    CrossLegToPatchCenterCompleted = false
      """
      Initialized to False.
      """

    CrossLegSearchForPeakStarted = false
      """
      Initialized to False.
      """

    ElapsedSinceStartOrLastSample = 0 hour
      """
      The mission sets this variable to reset the sample timer.
      """

    ElapsedTime = 0 hour
      """
      Only for syslog.
      """

    StoppedForBeingOutsideOfPolygon = false
      """
      Mission stopped because the vehicle is outside of the polygon.
      Initialized to False.
      """

    StoppedForNaNPatchPeak = false
      """
      Mission stopped because of no firing for too long. Initialized to false.
      """

    ElapsedSinceStartOrLastDistCheck = 0 hour
      """
      The mission sets this variable to reset the timer for checking distance
      to shore and polygon sides.
      """

    PatchPeakChl = NaN microgram_per_liter

    PatchPeakDepth = NaN meter

    PatchPeakLatitude = NaN degree

    PatchPeakLongitude = NaN degree

    PatchPeakDistance = 0 meter
  }

  # Missions should almost always start with a timeout and a NeedComms aggregate. Drift missions will not use NeedComms.

  timeout duration=MissionTimeout

  # Missions should almost always start with standard safety envelopes

  behavior Sample:AbortSample {
    run in parallel
  }

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert Insert/AbortDrift.tl {
    redefineArg AcousticTimeout = AcousticTrackingTimeout
  }

  insert Insert/SampleAtDepth.tl {
    redefineArg MaxWaitNotReachingDepth = MaxWaitTimeNotAchievingDepth
  }

  #  insert id="TrackPatchYoyo" Insert/TrackPatchYoyo.tl

  insert id="SampleAtPeakDepOrTemp" Insert/SampleAtPeakDepOrTemp.tl {
    redefineArg SampleAtPeakChl = ChlPeakDetect
    redefineArg LPWindowLength = LengthOfLPWindow
    redefineArg MedianFilterLength = LengthOfMedianFilter
    redefineArg Shallowbnd = ShallowBoundChl
    redefineArg Deepbnd = DeepBoundChl
    redefineArg DepChangeThreshAttitudeFlip = DepthChangeThreshAttitudeFlip
    redefineArg MaxWaitNoFiring = MaxWaitTimeNoFiring
    redefineArg MaxWaitNotAchievingDepth = MaxWaitTimeNotAchievingDepth
    redefineArg SendSampleStatusAndData = SendSampleStatusData
    redefineArg SendDataToMultipleModems = SendSampleDataToMultipleModems
    redefineArg modemId1 = ModemID1
    redefineArg modemId2 = ModemID2
    redefineArg InitialDiveDuration = DurationOfInitialDive
    redefineArg SpeedInitialDive = SpeedOfInitialDive
    redefineArg SpeedSampling = SpeedOfSampling
    redefineArg RudderAngleInitialDive = RudderAngleInInitialDive
    redefineArg RudderAngleDonutSampling = RudderAngleInDonutSampling
    redefineArg TriggerThreshChl = TriggerThresholdChl
    redefineArg CartridgeCommon = CartridgeTypeCommon
    redefineArg WaitDepUndulationCommon = WaitTimeDepUndulationCommon
    redefineArg UpRate = AscentRate
    redefineArg DownRate = DescentRate
    redefineArg RiseFromTurningDep = RiseFromTurningDepth
  }

  insert id="NeedComms" Insert/NeedComms.tl

  behavior Guidance:WaterDepthEnvelope {
    run in parallel

    set minWaterDepth = MinWaterDepth
  }

  assign in parallel Control:VerticalControl.maxBuoyDiveAccel = BuoyDiveAccel

  # Many missions will keep mass position fixed at the default. This mission allows the buoyancy volume to change to track the chlorophyll peak while drifting.

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude
  }

  # Automatically restart logs

  aggregate CycleLogs {
    run in parallel

    aggregate {
      run in sequence

      behavior Guidance:Wait {
        run in sequence

        set duration = IntervalRestartLogs
      }

      syslog important "Restarting logs."

      behavior Guidance:Execute {
        run in sequence

        set command = "restart logs"
      }
    }
  }

  aggregate SurfacingBeforeSampling {
    run when ( called )

    aggregate Surfacing {
      run in sequence

      behavior Guidance:Buoyancy {
        run in parallel

        set position = Control:VerticalControl.buoyancyNeutral
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = SpeedTransit
      }

      behavior Guidance:GoToSurface {
        run in sequence

        set pitch = SurfacePitch
        set depthRate = SurfaceDepthRate
        set speed = SpeedTransit
      }
    }
  }

  aggregate TransitToPatchTrackingStartLocation {
    run in sequence

    break if (
      isNaN ( LatPatchTrackingStart )
      or ( isNaN ( LonPatchTrackingStart ) )
    )

    assign in sequence NeedComms:DiveInterval = NeedCommsTimeTransit

    behavior Guidance:DepthEnvelope {
      run in parallel

      set minDepth = YoYoMinDepthPatchTracking
      set maxDepth = YoYoMaxDepthPatchTracking
      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:AltitudeEnvelope {
      """
      Another altitude envelope for the YoYo behavior. This envelope
      should fall within the limits of the standard safety envelopes
      in Insert/StandardEnvelopes.tl in order to avoid commanding high
      pitch angles for bottom-terminated YoYos.
      """

      run in parallel

      set minAltitude = YoYoMinAltitude
    }

    behavior Guidance:YoYo {
      run in parallel

      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:Waypoint {
      run in sequence

      set latitude = LatPatchTrackingStart
      set longitude = LonPatchTrackingStart
    }
  }

  aggregate TrackPatch {
    run in sequence

    insert id="TrackPatchYoyo" Insert/TrackPatchYoyo.tl

    assign in sequence TrackPatchYoyo:BuoyancyNeutral = BuoyNeutral
    assign in sequence TrackPatchYoyo:Speed = SpeedTransit
    assign in sequence TrackPatchYoyo:PeakDetectChl = ChlPeakDetect
    assign in sequence TrackPatchYoyo:PeakDetectSalinity = SalinityPeakDetect
    assign in sequence TrackPatchYoyo:PeakDetectOil = OilPeakDetect
    assign in sequence TrackPatchYoyo:PeakDetectPlanktivoreLMavgROI = PlanktivoreLMavgROIPeakDetect
    assign in sequence TrackPatchYoyo:LengthLPWindow = LengthOfLPWindow
    assign in sequence TrackPatchYoyo:LengthMedianFilter = LengthOfMedianFilter
    assign in sequence TrackPatchYoyo:PeakShallowBnd = ShallowBoundChl
    assign in sequence TrackPatchYoyo:PeakDeepBnd = DeepBoundChl
    assign in sequence TrackPatchYoyo:DepChangeThresholdAttitudeFlip = DepthChangeThreshAttitudeFlip
    assign in sequence TrackPatchYoyo:MinOffshore = MinOffshore
    assign in sequence TrackPatchYoyo:MarginMinOffshore = MarginOfMinOffshore
    assign in sequence TrackPatchYoyo:MinDistFromPolygonSides = MinDistanceFromPolygonSides
    assign in sequence TrackPatchYoyo:WaitAfterBouncing = WaitTimeAfterBouncing
    assign in sequence TrackPatchYoyo:CntRoundsCrossLegSurfacing = CountRoundsCrossLegSurfacing
    assign in sequence TrackPatchYoyo:NeedCommsTimePatchTracking = NeedCommsTimeInPatchTracking
    assign in sequence TrackPatchYoyo:WpMaxDist = WpMaxDistance
    assign in sequence TrackPatchYoyo:WpTimeout = WpMaxDuration
    assign in sequence TrackPatchYoyo:DetectionTimeout = SignalDetectionTimeout
    assign in sequence TrackPatchYoyo:PatchTrackingYoYoMinDepth = YoYoMinDepthPatchTracking
    assign in sequence TrackPatchYoyo:PatchTrackingYoYoMaxDepth = YoYoMaxDepthPatchTracking
    assign in sequence TrackPatchYoyo:BeginThreshChl = BeginThresholdChl
    assign in sequence TrackPatchYoyo:BeginThreshSalt = BeginThresholdSalt
    assign in sequence TrackPatchYoyo:BeginThreshOil = BeginThresholdOil
    assign in sequence TrackPatchYoyo:BeginThreshPlanktivoreLMavgROI = BeginThresholdPlanktivoreLMavgROI
    assign in sequence TrackPatchYoyo:WpBearing = WpBearingInit
    assign in sequence TrackPatchYoyo:OffPeakFraction = FractionOffPeak
    assign in sequence TrackPatchYoyo:NumOfProfilesSlidingwindow = NumberOfProfilesSlidingwindow
    assign in sequence TrackPatchYoyo:FilterWidthHorizontal = WidthOfFilterHorizontal

    call id="PatchTrackingStartComms" refId="NeedComms"

    assign in sequence NeedComms:DiveInterval = NeedCommsTimeInPatchTracking + NeedCommsTimeMarginPatchTracking

    aggregate Repeat {
      run in sequence repeat=MaxRepeatsPatchTracking

      call id="TrackPatch" refId="TrackPatchYoyo"
      call id="PatchCenterComms" refId="NeedComms"
    }
  }

  call id="SurfacingPriorToSampling" refId="SurfacingBeforeSampling"

  aggregate Sample {
    run in sequence

    assign in sequence SampleAtPeakDepOrTemp:NumSamplers = NumSamplers

    assign in sequence SampleAtPeakDepOrTemp:FlagGoDown = true

    assign in sequence SampleAtPeakDepOrTemp:FlagInitialDiveCompleted = false

    assign in sequence SampleAtPeakDepOrTemp:SampleOptionsSet = false

    assign in sequence SampleAtPeakDepOrTemp:SampleCountIncreased = true

    assign in sequence SampleAtPeakDepOrTemp:SampleCompleted = false

    assign in sequence SampleAtPeakDepOrTemp:FlagPeakDepthSet = false

    assign in sequence SampleAtPeakDepOrTemp:FlagPeakTempSet = false

    assign in sequence SampleAtPeakDepOrTemp:FlagTargetDepthSet = false

    assign in sequence SampleAtPeakDepOrTemp:FlagTempSet = false

    assign in sequence SampleAtPeakDepOrTemp:DepDiffFromPeak = 0 meter

    assign in sequence SampleAtPeakDepOrTemp:WaitDepUndulation1 = WaitDepUndulation[1]

    macro $i = 1..60 {
      aggregate SetCartType$i {
        run in sequence

        assign in sequence SampleAtPeakDepOrTemp:CartridgeType[$i] = CartType[$i]
      }
    }

    call id="Sampling" refId="SampleAtPeakDepOrTemp"
  }
}