Engineering/tow_passive.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission tow_passive {
  """
  Vehicle gets towed underwater at a fairly consistent depth and released
  without the vehicle knowing. Depth limits trigger the end of the
  mission.
  """

  arguments {
    MissionTimeout = 30 minute
      """
      Maximum duration of mission
      """

    NeedCommsTime = 30 minute
      """
      How often to surface for commumications
      """

    TowBoundUp = 2 meter
      """
      Once the vehicle reaches this depth for the timeout, it's no longer
      considered in tow.
      """

    TowBoundDown = 8 meter
      """
      Once the vehicle reaches this depth for the timeout, it's no longer
      considered in tow.
      """

    MaxDepth = 15 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 1 kilometer
      """
      Minimum distance offshore for the entire mission.
      """

    MinAltitude = 7 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during. Defaults to massDefault setting.
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position. Defaults to buoyancyNeutral setting.
      """

    UnderTow = false
      """
      Sets true when we've been under long enough that we think we're under
      tow.
      """

    UnderTowTimerArmed = false
      """
      Sets true when we hit the top depth and want to arm the clock.
      """

    TowTimeout = 3 minute
      """
      How long to wait until we're probably not being towed anymore
      """

    ArmingInterval = 60 second
      """
      Used to measure elapsed time
      """

    TowTimer = NaN minute
      """
      Elapsed time tow.
      """
  }

  timeout duration=MissionTimeout

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:WaitForPitchUp = 0 minute

  aggregate SurfaceComms {
    run when (
      called
      or ( elapsed ( Universal:time_fix ) > NeedCommsTime )
    )

    call refId="NeedComms"
  }

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  behavior Guidance:Buoyancy {
    run in parallel

    set position = BuoyancyNeutral
  }

  behavior Guidance:SetSpeed {
    run in parallel

    set speed = 0 meter_per_second
  }

  syslog important "Lights, Camera on!"

  readData strategy="MinError" {
    Sensor:PowerOnly.samplePowerOnly
  }

  aggregate Towing {
    run in sequence

    aggregate WaitingForTow {
      run while (
        not ( UnderTow )
        and ( not ( UnderTowTimerArmed ) )
        and ( Universal:depth < TowBoundUp )
      )

      syslog important "Ready To Launch"
    }

    aggregate StartingTow {
      run when (
        not ( UnderTow )
        and ( not ( UnderTowTimerArmed ) )
        and ( Universal:depth > TowBoundUp )
      )

      assign in sequence UnderTowTimerArmed = true

      assign in sequence TowTimer = Universal:time

      syslog important "Tow Launched"
    }

    aggregate ArmingTow {
      run when (
        not ( UnderTow )
        and UnderTowTimerArmed
        and ( Universal:depth > TowBoundUp )
        and ( Universal:time - TowTimer > ArmingInterval )
      )

      assign in sequence UnderTow = true

      assign in sequence UnderTowTimerArmed = false
    }

    aggregate InTow {
      run when (
        UnderTow
        and ( not ( UnderTowTimerArmed ) )
        and ( Universal:depth > TowBoundUp )
        and ( Universal:depth < TowBoundDown )
      )

      syslog info "Under Tow"

      assign in sequence TowTimer = Universal:time
    }

    aggregate OutOfTow {
      run when (
        ( Universal:depth < TowBoundUp
          or Universal:depth > TowBoundDown
        )
        and UnderTow
        and ( Universal:time - TowTimer > TowTimeout )
      )

      syslog important "Off Tow. Stopping Mission"

      behavior Guidance:Execute {
        run in sequence

        set command = "stop"
      }
    }
  }
}