Skip to content

Maintenance/calibrate_sparton_compass.tl

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
mission calibrate_sparton_compass {
  """
  This mission yoyos in a spiral while calibrating the Sparton AHRS-M2
  Micro AHRS/IMU with AdaptCal.
  """

  # Mission-wide settings

  arguments {
    MissionTimeout = 60 minute
      """
      Maximum duration of mission
      """

    NeedCommsTime = 60 minute
      """
      Elapsed time after previous surface communications when vehicle will
      begin to ascend for additional surface communications
      """

    # You probably need to change these.

    # You probably do not need to change these.

    YoYoMinDepth = 5 meter
      """
      Minimum depth while performing the YoYo behavior.
      """

    YoYoMaxDepth = 40 meter
      """
      Maximum depth while performing the YoYo behavior.
      """

    YoYoMinAltitude = 7 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    YoYoPitch = 20 degree
      """
      Pitch (plus and minus) for yo-yo behavior.
      """

    RudderAngle = 13 degree
      """
      Rudder angle to use while performing the spiral cast.
      """

    Speed = 1 meter_per_second
      """
      Vehicle speed.
      """

    CalibrationInitTimeout = 2 minute
      """
      Elapsed time allowed for calibration to initialize
      """

    # You are even less likely to need to change these.

    MinAltitude = 5 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """
  }

  # Missions should almost always start with a timeout

  timeout duration=MissionTimeout

  insert Insert/Science.tl {
    """
    Most missions will run the science sensors. If you don't place this
    aggregate above NeedComms, science instruments get turned off on the
    last upcast and while floating on the surface.
    """
  }

  # Most missions should use the NeedComms aggregate.

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime
  # Missions should almost always start with standard safety envelopes; most missions should not expose the parameters of these envelopes.

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude
  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth
  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert Insert/BackseatDriver.tl

  # Check for additional instructions first.

  call id="StartingMission" refId="NeedComms"

  # Many missions will keep mass position and buoyancy volume fixed at defaults.

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = Control:VerticalControl.massDefault
  }

  behavior Guidance:Buoyancy {
    run in parallel

    set position = Control:VerticalControl.buoyancyNeutral
  }

  behavior Guidance:DepthEnvelope {
    """
    Another depth envelope for the YoYo behavior. This envelope should
    fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for depth-terminated YoYos.
    """

    run in parallel

    set minDepth = YoYoMinDepth

    set maxDepth = YoYoMaxDepth

    set pitch = YoYoPitch
  }

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude

    set pitch = YoYoPitch
  }

  behavior Guidance:YoYo {
    run in parallel

    set pitch = YoYoPitch
  }

  aggregate AdaptCal {
    run in sequence

    readDatum id="WaitForCalibrationInit" {
      timeout duration=CalibrationInitTimeout {
        syslog important "Failed to initialize calibration within timeout. Stopping mission."

        behavior Guidance:Execute {
          run in sequence

          set command = "stop"
        }
      }

      Sensor:AHRS_M2.number_of_calbration_points
    }

    aggregate AcquireCalibrationPoints {
      run in sequence

      behavior Guidance:Point {
        run in parallel

        set rudderAngle = RudderAngle
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = Speed
      }
    }

    behavior Sensor:CalibrateAHRS_M2 {
      run in parallel
    }
  }
}