Engineering/circle_portuguese_ledge.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission {
  """
  This mission runs a circle around a specified centroid. The tracking
  behavior periodically queries the DAT for range and direction to the
  contact, and the DAT acoustically interrogates the contact.
  """

  arguments {
    # Mission-wide settings

    MissionTimeout = 2.5 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 150 minute
      """
      Elapsed time after previous surface communications when vehicle will
      begin to ascend for additional surface communications
      """

    Depth = 50 meter
      """
      Mission depth.
      """

    AcousticContactTimeout = 15 minute
      """
      If the vehicle does not receive an acoustic signal for more than this
      length of time, it will surface for communications with shore.
      """

    # You probably need to change these.

    ContactLabel = 0 count
      """
      The acoustic address of the asset to be tracked
      """

    ContactDepth = NaN meter
      """
      The acoustic address of the asset to be tracked
      """

    CenterLatitude = 36.696777 degree
      """
      The latitude of the center of the circle.
      """

    CenterLongitude = -121.941224 degree
      """
      The longitude of the center of the circle.
      """

    CenterNorthingsDelta = 0 meter
      """
      Desired change in latitude to achieve, expressed as a distance.
      """

    CenterEastingsDelta = 0 meter
      """
      Desired change in longitude to achieve, expressed as a distance.
      """

    CircleRadius = 218 meter
      """
      Radius of circle around acoustic contact during wait time
      """

    # You probably do not need to change these.

    TrackingUpdatePeriod = 15 second
      """
      How long to wait between acoustic queries
      """

    NumberOfPings = 1 count
      """
      Number of return pings to request with each acoustic query (more than 1
      will activate oneway mode)
      """

    CircleMaxError = 10 meter
      """
      If this distance away from the circle, drive straight towards (or away
      from the center). Otherwise, try to reduce distance from the ideal
      circle.
      """

    CircleTurnToPort = false
      """
      If true, vehicle turns to the left around the center point. If false,
      vehicle turns to the right.
      """

    Speed = 1 meter_per_second
      """
      Vehicle speed.
      """

    SkipComms = true
      """
      Skip communications at start of mission.
      """

    PowerBackseat = true
      """
      Run the backseat computer
      """

    # You are even less likely to need to change these.

    KwpHeading = 0.010 radian_per_meter
      """
      Used to relax waypoint cross-track error constant that is adjusted for
      docking. (You can override this setting by passing an argument.)
      """

    MinAltitude = 7 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 105 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 1.5 kilometer
      """
      Minimum offshore distance for the entire mission.
      """
  }

  # Missions should always start with a timeout.

  timeout duration=MissionTimeout

  # Add tracking directive high in the stack (above NeedComms to enable tracking from surface).

  insert Insert/AbortDrift.tl {
    redefineArg AcousticTimeout = AcousticContactTimeout
  }

  behavior Estimation:Tracking {
    run in parallel

    set contactDepthSetting = ContactDepth
    set contactLabelSetting = ContactLabel
    set numberOfSamplesSetting = NumberOfPings
    set updatePeriodSetting = TrackingUpdatePeriod
  }

  # Most missions have the NeedComms aggregate at high priority.

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime

  # Missions should almost always start with standard safety envelopes; most missions should not expose the parameters of these envelopes.

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  # Power the science payload.

  insert id="Science" Insert/Science.tl

  # Power the Backseat payload and request LCM data broadcast.

  insert Insert/BackseatDriver.tl

  assign in sequence BackseatDriver:EnableBackseat = PowerBackseat

  insert Insert/PowerOnly.tl

  # Check for additional instructions first.

  aggregate StartingMission {
    run in sequence

    break if ( SkipComms )

    # DO NOT REMOVE the syslog entry below. The MissionManager seems to ignore the value of SkipComms, does not evaluate the Break statement properly, and always calls NeedComms. Adding the syslog call somehow fixes it.

    syslog info "Checking for additional instructions before submerging."

    call id="StartingMission" refId="NeedComms"
  }

  # Start mission sequence.

  behavior Guidance:Mass {
    run in parallel

    set position = Control:VerticalControl.massDefault
  }

  behavior Guidance:Buoyancy {
    run in parallel

    set position = Control:VerticalControl.buoyancyNeutral
  }

  behavior Guidance:Pitch {
    run in parallel

    set depth = Depth
  }

  behavior Guidance:SetSpeed {
    run in parallel

    set speed = Speed
  }

  aggregate CircleWrapper {
    run in sequence

    assign in parallel Control:HorizontalControl.kwpHeading = KwpHeading

    behavior Guidance:Circle {
      run in parallel

      set latitude = CenterLatitude
      set longitude = CenterLongitude
      set northingsDelta = CenterNorthingsDelta
      set eastingsDelta = CenterEastingsDelta
      set radius = CircleRadius
      set maxError = CircleMaxError
      set turnToPort = CircleTurnToPort
    }

    behavior Guidance:Wait {
      run in sequence

      set duration = MissionTimeout
    }
  }
}