Science/esp_sample_at_depth.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission esp_sample_at_depth {
  """
  This mission takes ESP samples at the designated depth.
  """

  arguments {
    MissionTimeout = 4 hour
      """
      Maximum duration of mission.
      """

    TargetDepth = 3 meter
      """
      Depth to sample at. Initialized to 3 m.
      """

    ESPCartridgeType_1 = -4 count
      """
      Specifies ESP cartridge type code for sample# 1. Set to NaN to skip this
      sample.
      """

    ESPCartridgeType_2 = -15 count
      """
      Specifies ESP cartridge type code for sample# 2. Set to NaN to skip this
      sample.
      """

    ESPCartridgeType_3 = NaN count
      """
      Specifies ESP cartridge type code for sample# 3. Set to NaN to skip this
      sample.
      """

    ESPCartridgeType_4 = NaN count
      """
      Specifies ESP cartridge type code for sample# 4. Set to NaN to skip this
      sample.
      """

    SettleTime = 3 minute
      """
      How long to wait between samples. This starts *before* the first sample.
      """

    Speed = 0 meter_per_second
      """
      Vehicle speed while sampling. Set to zero to maintain depth using VBS
      (drift).
      """

    ApproachDepth = 1.5 meter
      """
      Depth for initial descent form the surface. Initialized to 3 m.
      """

    ApproachSpeed = 0.9 meter_per_second
      """
      Vehicle speed for initial descent form the surface to target depth. Set
      to zero to disable the thruster and descend using VBS (drift).
      """

    ApproachDepthRate = 0.05 meter_per_second
      """
      Descent depth rate (Positive depth rate means going down).
      """

    ApproachPitchLimit = 10 degree
      """
      Max vehicle pitch (+/-) when decending from the surface.
      """

    ApproachSettleTimePreDive = 1.5 minute
      """
      Time duration for the vehicle to pump down the VBS *BEFORE* leaving the
      surface.
      """

    ApproachSettleTimePostDive = 1 minute
      """
      Time duration for the vehicle to settle *AFTER* reaching the target
      depth.
      """

    ApproachDepthTimeout = 15 minute
      """
      Maximum time duration for the vehicle to reach the target depth.
      """

    kpDepth = 0.07 radian_per_meter
      """
      Dive loop proportional gain (applied only while the vehicle is
      descending to target depth).
      """

    DepthDeadband = 0.01 meter
      """
      How much vertical drift from the specified depth is allowed while
      sampling.
      """

    MinAltitude = 2 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 5 meter
      """
      Maximum allowable depth during the mission.
      """

    MinOffshore = 1 kilometer
      """
      Minimum distance from the shoreline to maintain.
      """
  }

  output {
    ESPCartridgeType = NaN count
      """
      Mission parameter (don't change). Specifies ESP cartridge type code.
      """
  }

  # Mission timeout

  timeout duration=MissionTimeout

  # Safety nets and surfacing behaviors

  behavior Sample:AbortSample {
    run in parallel
  }

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = MissionTimeout

  assign in sequence NeedComms:WaitForPitchUp = 0 minute

  assign in parallel Control:VerticalControl.depthDeadband = DepthDeadband

  # Callable aggregate

  aggregate SampleESP {
    run when ( called )

    aggregate sample {
      run in sequence

      syslog important "At " + Universal:depth~meter + ", settling for " + SettleTime~minute

      behavior Guidance:Wait {
        run in sequence

        set duration = SettleTime
      }

      syslog important "Requesting ESP cartridge type:" + ESPCartridgeType~count

      behavior Science:ESPCartridgeSelect {
        run in sequence

        timeout duration=P1M

        set cartridgeType = ESPCartridgeType
      }

      readDatum id="TriggerESP" {
        Science:ESPComponent.sampling
      }

      syslog important "ESP sampling at " + Universal:depth~meter + " in "
           + Science:CTD_Seabird.bin_mean_sea_water_temperature~celsius + " water with "
           + Science:WetLabsBB2FL.bin_mean_mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
           + "chlorophyll fluorescence."

      readDatum id="WaitForESP" {
        Science:ESPComponent.sample_number
      }
    }
  }

  # Start mission sequence

  call id="StartingMission" refId="NeedComms"

  insert Insert/Science.tl

  aggregate InitialDive {
    """
    Descend from the surface to approach depth at ApproachSpeed, limit
    pitch, depth-rate, and hold the rudder.
    """

    run in sequence

    break if ( ApproachSpeed == 0.0 meter_per_second )

    assign in parallel Control:VerticalControl.pitchLimit = ApproachPitchLimit

    assign in parallel Control:VerticalControl.kpDepth = kpDepth

    behavior Guidance:Pitch {
      run in parallel

      set massPosition = Control:VerticalControl.massDefault
    }

    behavior Guidance:Point {
      run in parallel

      set rudderAngle = 9 degree
    }

    behavior Guidance:Buoyancy {
      run in parallel

      set position = Control:VerticalControl.buoyancyNeutral
    }

    syslog info "Waiting for " + ApproachSettleTimePreDive~minute + "while pumping down to neutral."

    behavior Guidance:Wait {
      """
      Take a few moments to ensure the VBS reaches neutral.
      """

      run in sequence

      set duration = ApproachSettleTimePreDive
    }

    syslog "Moving to " + ApproachDepth~meter

    aggregate ApproachDepth {
      run in sequence

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = ApproachSpeed
      }

      behavior Guidance:Pitch {
        run in sequence

        timeout duration=ApproachDepthTimeout {
          syslog important "Timed out while trying to reach target depth at current depth of "
               + Universal:depth~meter + "."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        set depth = ApproachDepth
        set depthRate = ApproachDepthRate
      }
    }
  }

  aggregate SettleAtDepth {
    """
    Take a few more moments here to ensure the vechile is settled at the
    target depth.
    """

    run in sequence

    behavior Guidance:Pitch {
      run in progression

      set depth = TargetDepth
    }

    syslog info "Reached " + Universal:depth~meter + ", settling for "
         + ApproachSettleTimePostDive~minute

    behavior Guidance:Wait {
      run in sequence

      set duration = ApproachSettleTimePostDive
    }
  }

  aggregate SampleAtTargetDepth {
    """
    Maintain target depth and acquire ESP samples.
    """

    run in sequence

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = Speed
    }

    behavior Guidance:Pitch {
      run in parallel

      set depth = TargetDepth
    }

    aggregate Spinout {
      """
      A speed has been specified, spin in circels while sampling.
      """

      run while ( Speed > 0.0 meter_per_second )

      behavior Guidance:Pitch id="HoldMassPosition" {
        run in parallel

        set massPosition = Control:VerticalControl.massDefault
      }

      behavior Guidance:Buoyancy id="HoldBuoyancyPosition" {
        run in parallel

        set position = Control:VerticalControl.buoyancyNeutral
      }

      behavior Guidance:Point id="HoldRudderAngle" {
        run in parallel

        set rudderAngle = 9 degree
      }
    }

    aggregate GrabSamples {
      run in sequence

      aggregate Sample1 {
        run in sequence

        break if ( isNaN ( ESPCartridgeType_1 ) )

        assign in sequence ESPCartridgeType = ESPCartridgeType_1

        call refId="SampleESP"
      }

      aggregate Sample2 {
        run in sequence

        break if ( isNaN ( ESPCartridgeType_2 ) )

        assign in sequence ESPCartridgeType = ESPCartridgeType_2

        call refId="SampleESP"
      }

      aggregate Sample3 {
        run in sequence

        break if ( isNaN ( ESPCartridgeType_3 ) )

        assign in sequence ESPCartridgeType = ESPCartridgeType_3

        call refId="SampleESP"
      }

      aggregate Sample4 {
        run in sequence

        break if ( isNaN ( ESPCartridgeType_4 ) )

        assign in sequence ESPCartridgeType = ESPCartridgeType_4

        call refId="SampleESP"
      }
    }
  }
}