1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194 | # Copyright (c) 2024 MBARI
# MBARI Proprietary Information. Confidential. All Rights Reserved
# Unauthorized copying or distribution of this file via any medium is strictly
# prohibited.
#
# WARNING - This file contains information whose export is restricted by the
# Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
# amended. Violations of these export laws are subject to severe civil and/or
# criminal penalties.
mission transitUnder {
"""
Vehicle transits to desired waypoint and can be commanded to use/hold
mass or buoyancy. Designed for under ice.
"""
arguments {
MissionTimeout = 60 minute
"""
Maximum duration of mission
"""
DetachTimeout = 20 minute
"""
Maximum time to spend getting off the dock
"""
Latitude = NaN degree
"""
Latitude of waypoint to seek. If set to NaN, uses latitude at mission
initialization.
"""
Longitude = NaN degree
"""
Longitude of waypoint to seek. If set to NaN, uses longitude at mission
initialization.
"""
Northings = 0 meter
"""
Northward distance of the waypoint to seek. If combined with Latitude
and/or Longitude, this is an offset from the specified Latitude and/or
Longitude.
"""
Eastings = 0 meter
"""
Eastward distance of the waypoint to seek. If combined with Latitude
and/or Longitude, this is an offset from the specified Latitude and/or
Longitude.
"""
Depth = 10 meter
"""
Depth of flat and level flight during the mission.
"""
Speed = 1 meter_per_second
"""
Speed of vehicle (relative to water) during the mission.
"""
MaxDepth = 20 meter
"""
Maximum depth for the entire mission.
"""
MinOffshore = 1 kilometer
"""
Minimum distance offshore for the entire mission.
"""
MinAltitude = 7 meter
"""
Minimum height above the sea floor for the entire mission.
"""
MassHold = true
"""
Set to True in order to hold mass at default position, False to allow
mass to run on its own.
"""
BuoyancyHold = true
"""
Set to True in order to hold buoyancy at neutral position, False to
allow buoyancy to run on its own.
"""
MicromodemCommsInterval = 2 minute
"""
How often to trigger Umodem communications
"""
TransponderCode = 2 count
"""
Transponder Address.
"""
TrackingUpdatePeriod = 2.5 second
"""
How long to wait between acoustic queries.
"""
NumberOfPings = 1 count
"""
Number of pings requested each time.
"""
}
timeout duration=MissionTimeout
insert Insert/StandardEnvelopes.tl
assign in sequence StandardEnvelopes:MinAltitude = MinAltitude
assign in sequence StandardEnvelopes:MaxDepth = MaxDepth
assign in sequence StandardEnvelopes:MinOffshore = MinOffshore
aggregate Detach {
run in sequence
timeout duration=DetachTimeout {
syslog important "Timed out trying to detach from dock. Stopping mission."
behavior Guidance:Execute {
run in sequence
set command = "stop"
}
}
syslog important "Detaching from dock."
# Turn on tracking so we get some ranges to see how far we are from the dock
behavior Estimation:TrackAcousticContact {
run in parallel
set contactLabelSetting = TransponderCode
set numberOfSamplesSetting = NumberOfPings
set updatePeriodSetting = TrackingUpdatePeriod
}
# Time to leave the dock!
behavior Dock:Undock {
run in sequence
}
}
behavior Guidance:Buoyancy id="BuoyancyHold" {
run while ( BuoyancyHold )
set position = Control:VerticalControl.buoyancyNeutral
}
behavior Guidance:Pitch id="MassHold" {
run while ( MassHold )
set massPosition = Control:VerticalControl.massDefault
}
aggregate Transit {
run in sequence
insert id="MicromodemComms" Insert/MicromodemComms.tl {
redefineArg CommsInterval = MicromodemCommsInterval
}
behavior Guidance:Pitch {
run in parallel
set depth = Depth
}
behavior Guidance:SetSpeed {
run in parallel
set speed = Speed
}
behavior Guidance:Waypoint id="Wpt1" {
run in sequence
set latitude = Latitude
set longitude = Longitude
set northingsDelta = Northings
set eastingsDelta = Eastings
}
}
}
|