Insert/SampleAtDepth.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

aggregate SampleAtDepth {
  """
  Take a water sample at a specified depth.
  """

  arguments {
    TargetDepth = 5 meter
      """
      Depth to sample at. Initialized to 5 m.
      """

    SettleTime = 10 second
      """
      Time to wait after reaching target depth before triggering sample.
      Initialized to 10 minutes.
      """

    MaxWaitNotReachingDepth = 3 hour
      """
      Maximum wait time the vehicle cannot reach the targeted depth.
      Initialized to 3 hours.
      """

    RotateOnly = 0 bool

    UseCANONSampler = Science:CANONSampler.loadAtStartup
      """
      Whether to use CANON Sampler to sample.
      """

    UseESP = Science:ESPComponent.loadAtStartup
      """
      Whether to use ESP to sample.
      """

    ESPCartridgeType = NaN count
      """
      Specifies ESP cartridge type code.
      """

    CANONSamplerTriggerTimeout = 3 minute
      """
      How long to wait for a CANON Sampler sample to start.
      """

    CANONSamplerTimeout = Science:CANONSampler.sampleTimeout
      """
      How long to wait for a CANON Sampler sample to complete.
      """
  }

  output {
    # Internal variables that you should not change

    PlanktivoreLMavgROILogged = 0.0 count_per_second

    PlanktivoreHMavgROILogged = 0.0 count_per_second

    PlanktivoreDiatomsLogged = 0 count_per_milliliter

    PlanktivoreDinoflagellatesLogged = 0 count_per_milliliter
  }

  run when ( called )

  aggregate ReportInvalidDepth {
    run in sequence

    break if ( not ( isNaN ( TargetDepth ) ) )

    syslog fault "SampleAtDepth received an invalid target depth. Skipping sample."
  }

  aggregate sample {
    run in sequence

    break if ( isNaN ( TargetDepth ) )

    aggregate ApproachDepth {
      run in sequence

      syslog "Moving to " + TargetDepth~meter

      behavior Guidance:Pitch {
        run in sequence

        timeout duration=MaxWaitNotReachingDepth {
          syslog important "Timed out trying to reach the targeted depth. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        set depth = TargetDepth
      }
    }

    aggregate SampleWrapper {
      run in sequence

      behavior Guidance:Pitch {
        run in parallel

        set depth = TargetDepth
      }

      syslog important "At " + Universal:depth~meter + ", settling for " + SettleTime~minute

      behavior Guidance:Wait {
        run in sequence

        set duration = SettleTime
      }

      aggregate SampleCANONSampler {
        run in sequence

        break if ( not ( UseCANONSampler ) )

        assign in parallel Science:CANONSampler.sampleTimeout = CANONSamplerTimeout

        assign in parallel Science:CANONSampler.rotateOnly = RotateOnly

        readDatum id="TriggerCANONSampler" {
          timeout duration=CANONSamplerTriggerTimeout {
            syslog important "Timed out triggering CANONSampler. Stopping mission."

            behavior Guidance:Execute {
              run in sequence

              set command = "stop"
            }
          }

          Science:CANONSampler.sampling
        }

        assign in sequence PlanktivoreLMavgROILogged = customUri "_.planktivore_LM_AvgRois"

        assign in sequence PlanktivoreHMavgROILogged = customUri "_.planktivore_HM_AvgRois"

        assign in sequence PlanktivoreDiatomsLogged = customUri "_.planktivore_diatoms"

        assign in sequence PlanktivoreDinoflagellatesLogged = customUri "_.planktivore_dinoflagellates"

        syslog important "CANONSampler sampling at " + Universal:depth~meter + " in "
             + Science:PAR_Licor.downwelling_photosynthetic_photon_flux_in_sea_water~micromole_per_second_per_square_meter 
             + " photon flux with "
             + Science:WetLabsBB2FL.bin_mean_mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
             + " chlorophyll fluorescence."

        aggregate SyslogPlanktivoreLMavgROI {
          run in sequence

          break if ( isNaN ( PlanktivoreLMavgROILogged ) )

          syslog important "PlanktivoreLMavgROILogged = "
               + PlanktivoreLMavgROILogged~count_per_second + "."
        }

        aggregate SyslogPlanktivoreHMavgROI {
          run in sequence

          break if ( isNaN ( PlanktivoreHMavgROILogged ) )

          syslog important "PlanktivoreHMavgROILogged = "
               + PlanktivoreHMavgROILogged~count_per_second + "."
        }

        aggregate SyslogPlanktivoreDiatoms {
          run in sequence

          break if ( isNaN ( PlanktivoreDiatomsLogged ) )

          syslog important "PlanktivoreDiatomsLogged = "
               + PlanktivoreDiatomsLogged~count_per_milliliter + "."
        }

        aggregate SyslogPlanktivoreDinoflagellates {
          run in sequence

          break if (
            isNaN ( PlanktivoreDinoflagellatesLogged )
          )

          syslog important "PlanktivoreDinoflagellatesLogged = "
               + PlanktivoreDinoflagellatesLogged~count_per_milliliter + "."
        }

        readDatum {
          timeout duration=CANONSamplerTimeout {
            syslog important "Timed out sampling with CANONSampler. Stopping mission."

            behavior Guidance:Execute {
              run in sequence

              set command = "stop"
            }
          }

          Science:CANONSampler.sample_number
        }
      }

      aggregate SampleESP {
        run in sequence

        break if ( not ( UseESP ) )

        aggregate SelectESPCartridge {
          run in sequence

          break if ( isNaN ( ESPCartridgeType ) )

          behavior Science:ESPCartridgeSelect {
            run in sequence

            timeout duration=P1M

            set cartridgeType = ESPCartridgeType
          }
        }

        readDatum id="TriggerESP" {
          Science:ESPComponent.sampling
        }

        assign in sequence PlanktivoreLMavgROILogged = customUri "_.planktivore_LM_AvgRois"

        assign in sequence PlanktivoreHMavgROILogged = customUri "_.planktivore_HM_AvgRois"

        assign in sequence PlanktivoreDiatomsLogged = customUri "_.planktivore_diatoms"

        assign in sequence PlanktivoreDinoflagellatesLogged = customUri "_.planktivore_dinoflagellates"

        syslog important "ESP sampling at " + Universal:depth~meter + " in "
             + Science:CTD_Seabird.bin_mean_sea_water_temperature~celsius + " water with "
             + Science:WetLabsBB2FL.bin_mean_mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
             + "chlorophyll fluorescence."

        aggregate SyslogPlanktivoreLMavgROI {
          run in sequence

          break if ( isNaN ( PlanktivoreLMavgROILogged ) )

          syslog important "PlanktivoreLMavgROILogged = "
               + PlanktivoreLMavgROILogged~count_per_second + "."
        }

        aggregate SyslogPlanktivoreHMavgROI {
          run in sequence

          break if ( isNaN ( PlanktivoreHMavgROILogged ) )

          syslog important "PlanktivoreHMavgROILogged = "
               + PlanktivoreHMavgROILogged~count_per_second + "."
        }

        aggregate SyslogPlanktivoreDiatoms {
          run in sequence

          break if ( isNaN ( PlanktivoreDiatomsLogged ) )

          syslog important "PlanktivoreDiatomsLogged = "
               + PlanktivoreDiatomsLogged~count_per_milliliter + "."
        }

        aggregate SyslogPlanktivoreDinoflagellates {
          run in sequence

          break if (
            isNaN ( PlanktivoreDinoflagellatesLogged )
          )

          syslog important "PlanktivoreDinoflagellatesLogged = "
               + PlanktivoreDinoflagellatesLogged~count_per_milliliter + "."
        }

        readDatum id="WaitForESP" {
          Science:ESPComponent.sample_number
        }
      }
    }
  }
}