Engineering/lab_test_optim.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission lab_test_optim {
  arguments {
    MissionTimeout = 15 minute
      """
      Backseat will stay on for this duration, independent of Optim state
      """

    RecordTime = 1 minute
      """
      How long to record after startup sequence (hopefully) turns on Optim camera
      """

    BackseatWait = 30 second
      """
      How long to wait for the backseat to power up before attempting to power the Optim
      """

    UseMission = true
      """
      If true, tries to go through the application and use components/behaviors for commands.
      Set InitialSampleTime to change delays. If false, backdoors app. Use SleepCycles to change delays.
      Optim must be on C3.
      """

    UseHardcode = false
      """
      If true, backdoors app with a powercycle and a hardcoded sleep 1. Try the two other modes first?
      Optim must be on C3.
      """

    InitialSampleTime = 1 second
      """
      PowerOnly sample time for initial record. Will go back to continuous after startup.
      """

    SleepCycles = 3 count
      """
      How many vehicle computation cycles to wait before commanding the Optim off on initial record
      """

    LightMode = 2 count
      """
      Mode for Multiray lights. 0 is off, 1 is red, 2 is white
      """

    BrightnessWhite = 100 none_int
      """
      White Multiray LED brightness, 0-100
      """

    BrightnessRed = 100 none_int
      """
      Red Multiray LED brightness, 0-100
      """
  }

  output {
    CyclesWaited = 0 count

    RecordingEnabled = false

    LightsEnabled = false
  }

  timeout duration=MissionTimeout

  insert Insert/BackseatDriver.tl
  assign in parallel BackseatDriver:EnableBackseat = true

  readData strategy="MinError" {
    while ( RecordingEnabled )

    Sensor:PowerOnly.sampleLoad1
  }

  readData strategy="MinError" {
    while ( LightsEnabled )

    Sensor:MultiRay.lightModeLog
  }

  aggregate Startup {
    run in sequence

    syslog important "Waiting " + BackseatWait~s + " for backseat to start up..."

    behavior Guidance:Wait {
      run in sequence

      set duration = BackseatWait
    }

    aggregate UseMission {
      run in sequence

      break if (
        not UseMission
        or UseHardcode
      )

      assign in parallel Sensor:PowerOnly.sampleTime1 = InitialSampleTime

      assign in sequence RecordingEnabled = true

      syslog important "Disabling Optim recording after " + InitialSampleTime~s
      assign in sequence RecordingEnabled = false

      behavior Guidance:Wait {
        run in sequence

        set duration = InitialSampleTime
      }

      assign in sequence RecordingEnabled = true
      syslog important "Powering up Optim to try to tide over gap to handoff..."
    }

    aggregate UseBackdoor {
      run in sequence

      break if (
        UseMission
        or UseHardcode
      )

      behavior Guidance:Execute {
        run in sequence

        set command = "! echo 1 > /dev/loadC3"
      }

      syslog important "Optim power on. Spinning for " + SleepCycles~count + " cycles."

      aggregate WaitForStop {
        run in sequence repeat=SleepCycles

        assign in sequence CyclesWaited = CyclesWaited + 1 count
      }

      behavior Guidance:Execute {
        run in sequence

        set command = "! echo 0 > /dev/loadC3"
      }

      syslog important "Optim power off. Spinning again."

      aggregate WaitForStart {
        run in sequence repeat=SleepCycles

        assign in sequence CyclesWaited = CyclesWaited + 1 count
      }

      behavior Guidance:Execute {
        run in sequence

        set command = "! echo 1 > /dev/loadC3"
      }

      syslog important "Optim power on. Handing off to mission."
    }

    aggregate UseHardcode {
      run in sequence

      break if ( not UseHardcode )

      behavior Guidance:Execute {
        run in sequence

        set command = "! echo 1 > /dev/loadC3; sleep 1; echo 0 > /dev/loadC3; sleep 1; echo 1 > dev/loadC3"
      }

      syslog important "Hardcoded Optim command sent. Good luck."
    }
  }

  aggregate Run {
    run in sequence

    syslog important "Trying to run Optim and Multiray forreal"

    assign in sequence RecordingEnabled = true
    assign in sequence LightsEnabled = true
    assign in sequence Sensor:MultiRay.lightModeCommand = LightMode

    aggregate setRed {
      run in sequence

      break if ( LightMode != 1 count )

      assign in sequence Sensor:MultiRay.brightnessRed = BrightnessRed
      syslog info "Setting multiray red brightness to" + BrightnessRed~count
    }

    aggregate setWhite {
      run in sequence

      break if ( LightMode != 2 count )

      assign in sequence Sensor:MultiRay.brightnessWhite = BrightnessWhite
      syslog info "Setting muliray white brightness to" + BrightnessWhite~count
    }

    syslog important "Recording for " + RecordTime~min

    behavior Guidance:Wait {
      run in sequence

      set duration = RecordTime
    }
  }

  behavior Guidance:Wait {
    run in sequence

    set duration = MissionTimeout
  }
}