Science/sample_depth_rate.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission sampleDepthRate {
  """
  This mission drives in a circle while ascending at a given depth rate.
  """

  arguments {
    MissionTimeout = 120 minute
      """
      How long to let the mission run.
      """

    NeedCommsTime = 120 minute
      """
      How often to surface for commumications
      """

    startDepth = 50 meter
      """
      Depth to sample at.
      """

    endDepth = 5 meter
      """
      Depth at which to end.
      """

    UpRate = -0.05555 meter_per_second
      """
      Depth rate (Negative depth rate means going up).
      """

    Speed = 1 meter_per_second
      """
      Vehicle speed. Initialized to zero.
      """

    RudderAngle = 12 degree
      """
      Rudder angle. Initialized to zero.
      """

    MinAltitude = 5 meter
      """
      Minimum height above the sea floor for the entire mission.
      """

    MaxDepth = 205 meter
      """
      Maximum depth for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    # You probably do not need to change these.

    UseCANONSampler = Science:CANONSampler.loadAtStartup
      """
      Whether to use CANON Sampler to sample.
      """

    UseESP = Science:ESPComponent.loadAtStartup
      """
      Whether to use ESP to sample.
      """

    CANONSamplerTriggerTimeout = 1 minute
      """
      How long to wait for a CANON Sampler sample to start.
      """

    CANONSamplerTimeout = Science:CANONSampler.sampleTimeout
      """
      How long to wait for a CANON Sampler sample to complete.
      """
  }

  timeout duration=MissionTimeout

  insert Insert/Science.tl {
    """
    Most missions will run the science sensors. If you don't place this
    aggregate above NeedComms, science instruments get turned off on the
    last upcast and while floating on the surface.
    """
  }

  # Most missions should use the NeedComms aggregate.

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsTime

  assign in sequence NeedComms:SurfaceSpeed = Speed

  # Missions should almost always start with standard safety envelopes; most missions should not expose the parameters of these envelopes.

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = Control:VerticalControl.massDefault
  }

  behavior Guidance:SetSpeed {
    run in parallel

    set speed = Speed
  }

  behavior Guidance:Point {
    run in parallel

    set rudderAngle = RudderAngle
  }

  syslog info "Moving to " + startDepth~meter

  behavior Guidance:Pitch {
    run in sequence

    set depth = startDepth
  }

  aggregate SampleWrapper {
    run in sequence

    aggregate SampleCANONSampler {
      run in sequence

      break if ( not ( UseCANONSampler ) )

      assign in parallel Science:CANONSampler.sampleTimeout = CANONSamplerTimeout

      behavior Guidance:Pitch {
        run in parallel

        set depthRate = UpRate
        set depth = endDepth
      }

      readDatum id="TriggerCANONSampler" {
        timeout duration=CANONSamplerTriggerTimeout {
          syslog important "Timed out triggering CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sampling
      }

      syslog important "CANONSampler sampling at " + Universal:depth~meter + " in "
           + Science:CTD_NeilBrown.bin_mean_sea_water_temperature~celsius + " water with "
           + Science:WetLabsBB2FL.bin_mean_mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
           + " chlorophyll fluorescence."

      readDatum {
        timeout duration=CANONSamplerTimeout {
          syslog important "Timed out sampling with CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sample_number
      }
    }

    aggregate SampleESP {
      run in sequence

      break if ( not ( UseESP ) )

      behavior Guidance:Pitch {
        run in parallel

        set depthRate = UpRate
        set depth = endDepth
      }

      readDatum id="TriggerESP" {
        Science:ESPComponent.sampling
      }

      syslog important "ESP sampling at " + Universal:depth~meter + " in "
           + Science:CTD_NeilBrown.bin_mean_sea_water_temperature~celsius + " water with "
           + Science:WetLabsBB2FL.bin_mean_mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
           + " chlorophyll fluorescence."

      readDatum id="WaitForESP" {
        Science:ESPComponent.sample_number
      }
    }
  }

  call id="MissionComplete" refId="NeedComms"
}