Insert/SampleAtPeakChlDepOrTemp.tl

# -   Copyright (c) 2024 MBARI
# -   MBARI Proprietary Information. Confidential. All Rights Reserved
# -   Unauthorized copying or distribution of this file via any medium is strictly
# -   prohibited.
# -
# -   WARNING - This file contains information whose export is restricted by the
# -   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
# -   amended. Violations of these export laws are subject to severe civil and/or
# -   criminal penalties.
aggregate SampleAtPeakChlDepOrTemp {
  arguments {
    NumSamplers = 0 count
      """
      Total number of ESP cartridges (Maximum 60) or CANON samplers. Set to 0
      to disable sampling.
      """

    MaxWaitNoFiring = 2 hour
      """
      If no firing after more than MaxWaitNoFiring, terminate mission.
      """

    MaxWaitNotAchievingDepth = 0.5 hour
      """
      Maximum wait time the vehicle cannot reach the targeted depth.
      """

    SendSampleStatusAndData = false
      """
      Whether to senddata to acoustic modem.
      """

    SendDataToMultipleModems = false
      """
      Whether to senddata to more than one modem.
      """

    modemId1 = 1 enum
      """
      Modem ID1. Initialized to 1.
      """

    modemId2 = 4 enum
      """
      Modem ID2. Initialized to 4.
      """

    SampleAtPeakChl = false
      """
      Whether to sample at peak-chl
      """

    InitialDiveDuration = 1.0 minute
      """
      On the first dive for looking for the chl max, run at SpeedInitialDive
      for this duration (e.g., 1 m/s spiral to dive fast).
      """

    SpeedInitialDive = 1.0 meter_per_second
      """
      Vehicle speed during initial dive (for looking for the chl max). 0.0 for
      drift mode (prop off); 1.0 for spiral mode (prop on). Initialized to 1
      m/s.
      """

    SpeedSampling = 1.0 meter_per_second
      """
      Vehicle speed during sampling: 0.0 for drift mode (prop off); 1.0 for
      donut mode (prop on). Initialized to 1 m/s.
      """

    RudderAngleInitialDive = 9 degree
      """
      Rudder angle in initial spiral-down to leave surface. Initialized to 9
      degrees.
      """

    RudderAngleDonutSampling = 13 degree
      """
      Rudder angle during donut sampling.
      """

    TriggerThreshChl = 2.5 microgram_per_liter
      """
      If non-NaN, sets threshold for triggering sampling. Chl value of 2.5
      mug/L corresponds to HS2 fluorescence reading of 0.001 on Dorado.
      """

    ShallowbndChl = 3 meter
      """
      Shallow depth bound for chl-peak detection.
      """

    DeepbndChl = 20 meter
      """
      Deep depth bound for chl-peak detection.
      """

    CartridgeCommon = NaN count
      """
      Value common to all samples unless set diffently: cartridge type.
      """

    CartridgeType1 = NaN count
      """
      Sample 1. Cartridge type.
      """

    CartridgeType2 = NaN count
      """
      Sample 2.
      """

    CartridgeType3 = NaN count
      """
      Sample 3.
      """

    CartridgeType4 = NaN count
      """
      Sample 4.
      """

    CartridgeType5 = NaN count
      """
      Sample 5.
      """

    CartridgeType6 = NaN count
      """
      Sample 6.
      """

    CartridgeType7 = NaN count
      """
      Sample 7.
      """

    CartridgeType8 = NaN count
      """
      Sample 8.
      """

    CartridgeType9 = NaN count
      """
      Sample 9.
      """

    CartridgeType10 = NaN count
      """
      Sample 10.
      """

    TempDiffFromPeakChl = NaN kelvin
      """
      Target temperature difference from the peak-chl temperature.
      """

    TempDesignated = NaN celsius
      """
      Pre-designated temperature.
      """

    DepDiffFromPeakChl = NaN meter
      """
      Depth difference (positive: deeper; negative: shallower) from the
      peak-chl depth for taking comparison samples. Initialized to NaN.
      """

    DepDesignated = NaN meter
      """
      Pre-designated depth.
      """

    WaitDepUndulationCommon = 5.0 minute
      """
      Value common to all samples unless set differently: Wait duration for
      the depth undulation to damp down.
      """

    WaitDepUndulation1 = 10.0 minute
      """
      For the 1st sample: wait duration for the depth undulation to damp down.
      """

    UpRate = -0.05 meter_per_second
      """
      Go-up depth rate (Negative depth rate means going up).
      """

    DownRate = 0.2 meter_per_second
      """
      Go-down depth rate (Positive depth rate means going down).
      """

    UseESP = Science:ESPComponent.loadAtStartup
      """
      Whether to use ESP to sample.
      """

    UseCANONSampler = Science:CANONSampler.loadAtStartup
      """
      Whether to use CANON Sampler to sample.
      """

    CANONSamplerRotateOnly = 0 bool

    CANONSamplerTriggerTimeout = 3 minute
      """
      How long to wait for a CANON Sampler sample to start.
      """

    CANONSamplerTimeout = Science:CANONSampler.sampleTimeout
      """
      How long to wait for a CANON Sampler sample to complete.
      """

    RiseFromTurningDep = 5 meter
      """
      The peak chl detected on the initial dive is reported when the vehicle
      has turned from the deepest depth (i.e., the turning depth) onto the
      ascending profile at a depth that is RiseFromDeepTurningPoint shallower
      than the turning depth. For robustness, RiseFromTurningDep =
      DepChangeThreshAttitudeFlip + 2 meters.
      """

    DepChangeThreshAttitudeFlip = 3 meter
      """
      Depth change threshold for determining vehicle attitude flip.
      """

    LPWindowLength = 20 count
      """
      Low-pass window length (based on depth sensor sampling interval 0.4
      second) for low-pass filtering.
      """

    MedianFilterLength = 5 count
      """
      Median filter length (only for chlorophyll fluorescence which tends to
      have spikes). The median-filtered signal enters the succeeding low-pass
      filter. If set to 1, then no median filtering, i.e., the raw
      fluorescence signal directly enters the low-pass filter.
      """

    GainProportional = 1 none
      """
      Proportional gain for temperature holding control loop.
      """

    GainIntegral = 0 none
      """
      Integral gain for temperature holding control loop.
      """

    GainDerivative = 0 none
      """
      Derivative gain for temperature holding control loop.
      """

    VariationPerMeter = 0.2 reciprocal_meter
      """
      Expected temperature change per meter.
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """
  }

  output {
    # Internal variables that you should not change

    FlagGoDown = true
      """
      Go-down flag (set to true when going down. Initialized to true).
      """

    EnableElapsedSinceStartOrLastSample = false
      """
      Enable clock checking of ElapsedSinceStartOrLastSample (Initialized to false).
      """

    ElapsedSinceStartOrLastSample = 0 hour
      """
      The mission sets this variable to reset the sample timer.
      """

    ElapsedTime = 0 hour
      """
      Only for syslog.
      """

    CartridgeType = -6 count
      """
      Cartridge type. Initialized to -6.
      """

    CartridgeTypeIndividual = -6 count
      """
      Initialized to -6.
      """

    TempSet = NaN kelvin
      """
      Temperature for sampling. Initialized to NaN.
      """

    DepthSet = 10.0 meter
      """
      Depth for sampling. Initialized to 10 m.
      """

    WaitDepthUndulation = 10.0 minute
      """
      Wait duration for the depth undulation to damp down. Initialized to 10
      minutes.
      """

    SampleCountIncreased = true
      """
      Sample count is increased.
      """

    SampleOptionsSet = false
      """
      Sample options (DepDiffFromPeakChl etc.) already set. Initialized to
      false.
      """

    SampleCompleted = false
      """
      Sampling completed. Initialized to false.
      """

    StoppedForNoFiringForTooLong = false
      """
      Mission stopped because of no firing for too long. Initialized to false.
      """

    DepthLogged = 0.0 meter

    TempLogged = 0.0 celsius

    ChlLogged = 0.0 microgram_per_liter

    FlagTempSet = false
      """
      Flag of target temperature having been set. Initialized to false.
      """

    FlagTargetDepthSet = false
      """
      Flag of target depth having been set. Initialized to false.
      """

    FlagGoUp = false
      """
      Go-up flag (set to true when going up. Initialized to false).
      """

    FlagInitialDiveCompleted = false
      """
      Flag of initial dive completed. Initialized to false.
      """

    FlagPeakChlDepthSet = false
      """
      Flag of peak-chl depth having been set (set to true when the chl-peak
      depth has been set. Initialized to false).
      """

    FlagPeakChlTempSet = false
      """
      Flag of peak-chl temperature having been set (set to true when the
      chl-peak temperature has been set. Initialized to false).
      """

    FlagSamplingOngoing = false
      """
      Flag of water sampling in process (initialized to false).
      """

    PeakChlDepthSet = 10.0 meter
      """
      Peak-chl depth detected on a dive. Initialized to 10 meters.
      """

    PeakChlTemperatureSet = NaN kelvin
      """
      Peak-chl temperature detected on a dive, and set for chl-peak holding.
      Initialized to NaN.
      """

    PeakChlSet = 0.0 microgram_per_liter
      """
      Peak-chl value detected on a dive.
      """

    SyslogGoUp = false
      """
      Flag of logging "GoUp" in syslog (initialized to false).
      """

    SyslogGoDown = false
      """
      Flag of logging "GoDown" in syslog (initialized to false).
      """

    CntSamples = 1 count
      """
      Count of water samples (initilized to 1).
      """

    SendDataCntSamplesCompleted = false
      """
      Initialized to false.
      """

    SendDataESPSampleNumberCompleted = false
      """
      Initialized to false.
      """

    SendDataESPCartridgeTypeCompleted = false
      """
      Initialized to false.
      """

    SendDataESPSampleVolumeCompleted = false
      """
      Initialized to false.
      """

    SendDataSampleDepCompleted = false
      """
      Initialized to false.
      """

    SendDataSampleTempCompleted = false
      """
      Initialized to false.
      """

    SendDataSampleChlCompleted = false
      """
      Initialized to false.
      """

    SendDataAllCompleted = false
      """
      Initialized to false.
      """

    CallSendData = true
      """
      Initialized to true.
      """

    ModemID = 1 enum
      """
      Modem ID. Set to modemId1 or modemId2. Initialized to 1.
      """
  }

  run in sequence

  insert Insert/Science.tl {
    redefineArg PeakDetectChlActive = SampleAtPeakChl
    redefineArg LowPassWindowLength = LPWindowLength
    redefineArg MedianFilterLen = MedianFilterLength
    redefineArg PeakShallowBound = ShallowbndChl
    redefineArg PeakDeepBound = DeepbndChl
    redefineArg DepChangeThreshForAttitudeFlip = DepChangeThreshAttitudeFlip
  }

  insert Insert/SampleAtDepth.tl {
    redefineArg MaxWaitNotReachingDepth = MaxWaitNotAchievingDepth
  }

  assign in sequence ElapsedSinceStartOrLastSample = 0 hour

  aggregate TriggerSampling {
    run when ( called )

    aggregate TriggerESP {
      run in sequence

      break if ( not ( UseESP ) )

      assign in sequence DepthLogged = Universal:depth

      assign in sequence TempLogged = Universal:sea_water_temperature

      assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

      syslog important "Trigger sampling. DepthLogged, TempLogged, ChlLogged = " + DepthLogged~meter
           + ", " + TempLogged~celsius + ", " + ChlLogged~microgram_per_liter + "."

      behavior Science:ESPCartridgeSelect {
        run in sequence

        timeout duration=P1M

        set cartridgeType = CartridgeType
      }

      readDatum {
        Science:ESPComponent.sampling
      }

      syslog important "Wait for ESP sampling to complete."

      readDatum {
        Science:ESPComponent.sample_number
      }
    }

    aggregate TriggerCANON {
      run in sequence

      break if ( not ( UseCANONSampler ) )

      assign in sequence DepthLogged = Universal:depth

      assign in sequence TempLogged = Universal:sea_water_temperature

      assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

      syslog important "Trigger sampling. DepthLogged, TempLogged, ChlLogged = " + DepthLogged~meter
           + ", " + TempLogged~celsius + ", " + ChlLogged~microgram_per_liter + "."

      assign in parallel Science:CANONSampler.sampleTimeout = CANONSamplerTimeout

      assign in parallel Science:CANONSampler.rotateOnly = CANONSamplerRotateOnly

      readDatum id="TriggerCANONSampler" {
        timeout duration=CANONSamplerTriggerTimeout {
          syslog important "Timed out triggering CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sampling
      }

      readDatum {
        timeout duration=CANONSamplerTimeout {
          syslog important "Timed out sampling with CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sample_number
      }
    }
  }

  aggregate DampDown {
    run when ( called )

    syslog important "Wait " + WaitDepthUndulation~minute
         + " for the depth undulation to damp down."

    behavior Guidance:Wait {
      run in sequence

      set duration = WaitDepthUndulation
    }
  }

  aggregate DoSendDirect {
    run when ( called )

    syslog important "ModemID = " + ModemID~enum

    behavior Sensor:SendDirect {
      run in sequence

      set destType = "modem"
      set destId = ModemID
      set destName = "_.LRAUVcntSamples"
      set value = CntSamples
      set unit = "count"
    }

    syslog important "CntSamples = " + CntSamples~count

    aggregate SendDirectESP {
      run in sequence

      break if ( not ( UseESP ) )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemID
        set destName = "_.ESPsampleNumber"
        set value = Science:ESPComponent.sample_number
        set unit = "count"
      }

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemID
        set destName = "_.ESPcartridgeType"
        set value = Science:ESPComponent.cartridge
        set unit = "count"
      }

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemID
        set destName = "_.ESPsampleVolume"
        set value = Science:ESPComponent.sampleVolume
        set unit = "milliliter"
      }

      syslog important "Science:ESPComponent.sample_number = "
           + Science:ESPComponent.sample_number~count

      syslog important "Science:ESPComponent.cartridge = " + Science:ESPComponent.cartridge~count

      syslog important "Science:ESPComponent.sampleVolume = "
           + Science:ESPComponent.sampleVolume~milliliter
    }

    aggregate SendDirectCANON {
      run in sequence

      break if ( not ( UseCANONSampler ) )

      behavior Sensor:SendDirect {
        run in sequence

        set destType = "modem"
        set destId = ModemID
        set destName = "_.CANONsampleNumber"
        set value = Science:CANONSampler.sample_number
        set unit = "count"
      }

      syslog important "Science:CANONSampler.sample_number = "
           + Science:CANONSampler.sample_number~count
    }

    behavior Sensor:SendDirect {
      run in sequence

      set destType = "modem"
      set destId = ModemID
      set destName = "_.sampleDepth"
      set value = Universal:depth
      set unit = "meter"
    }

    behavior Sensor:SendDirect {
      run in sequence

      set destType = "modem"
      set destId = ModemID
      set destName = "_.sampleTemperature"
      set value = Universal:sea_water_temperature
      set unit = "celsius"
    }

    behavior Sensor:SendDirect {
      run in sequence

      set destType = "modem"
      set destId = ModemID
      set destName = "_.sampleChlorophyll"
      set value = Universal:mass_concentration_of_chlorophyll_in_sea_water
      set unit = "microgram_per_liter"
    }

    syslog important "Universal:depth = " + Universal:depth~meter

    syslog important "Universal:sea_water_temperature = " + Universal:sea_water_temperature~celsius

    syslog important "Universal:mass_concentration_of_chlorophyll_in_sea_water = "
         + Universal:mass_concentration_of_chlorophyll_in_sea_water~microgram_per_liter
  }

  aggregate SendData {
    run when ( called )

    aggregate SendTo1Modem {
      run in sequence

      break if ( SendDataToMultipleModems )

      assign in sequence ModemID = modemId1

      syslog important "Set ModemID to " + ModemID~enum + "."

      call refId="DoSendDirect"
    }

    aggregate SendTo2Modems {
      run in sequence

      break if ( not ( SendDataToMultipleModems ) )

      assign in sequence ModemID = modemId1

      syslog important "Set ModemID to " + ModemID~enum + "."

      call refId="DoSendDirect"

      assign in sequence ModemID = modemId2

      syslog important "Set ModemID to " + ModemID~enum + "."

      call refId="DoSendDirect"
    }

    assign in sequence SendDataAllCompleted = true
  }

  aggregate SetSampleOptions {
    run when ( called )

    syslog important "CntSamples = " + CntSamples~count

    aggregate SettingCartridgeTypeIndividual {
      run in sequence

      break if (
        isNaN ( CartridgeTypeIndividual )
        or ( not ( UseESP ) )
      )

      assign in sequence CartridgeType = CartridgeTypeIndividual
    }

    aggregate SettingCartridgeCommon {
      run in sequence

      break if (
        not ( isNaN ( CartridgeTypeIndividual ) )
        or ( not ( UseESP ) )
      )

      assign in sequence CartridgeType = CartridgeCommon
    }

    aggregate SettingWait1 {
      run in sequence

      break if ( CntSamples >= 2 count )

      assign in sequence WaitDepthUndulation = WaitDepUndulation1
    }

    aggregate SettingWaitCommon {
      run in sequence

      break if ( CntSamples == 1 count )

      assign in sequence WaitDepthUndulation = WaitDepUndulationCommon
    }

    syslog important "CntSamples = " + CntSamples~count
         + ". Set CartridgeType (if ESP), TempDiffFromPeakChl, DepDiffFromPeakChl, TempDesignated, DepDesignated, WaitDepthUndulation to "
         + CartridgeType~count + ", " + TempDiffFromPeakChl~kelvin + ", " + DepDiffFromPeakChl~meter
         + ", " + TempDesignated~celsius + ", " + DepDesignated~meter + ", " + WaitDepthUndulation~minute
         + "."
  }

  aggregate SetSpeedRudderAngleInitialDive {
    run when (
      not ( FlagInitialDiveCompleted )
      and ( CntSamples == 1 count )
    )

    break if ( not ( SampleAtPeakChl ) )

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = SpeedInitialDive
    }

    behavior Guidance:Point {
      run in parallel

      set rudderAngle = RudderAngleInitialDive
    }

    behavior Guidance:Wait {
      run in sequence

      set duration = InitialDiveDuration
    }

    assign in sequence FlagInitialDiveCompleted = true
  }

  aggregate FindPeakChlVertical {
    run in sequence

    break if ( CntSamples > NumSamplers )

    aggregate FindPeak {
      run while ( SampleAtPeakChl )

      aggregate FindPeakSpiralMode {
        run while ( SpeedSampling > 0.0 meter_per_second )

        behavior Guidance:SetSpeed {
          run in parallel

          set speed = SpeedSampling
        }

        behavior Guidance:Point {
          run in parallel

          set rudderAngle = RudderAngleDonutSampling
        }

        behavior Guidance:Buoyancy {
          run in parallel

          set position = BuoyancyNeutral
        }
      }

      aggregate FindPeakDriftMode {
        run while (
          not ( SpeedSampling > 0.0 meter_per_second )
        )

        behavior Guidance:SetSpeed {
          run in parallel

          set speed = 0.0 meter_per_second
        }

        behavior Guidance:Point {
          run in parallel

          set rudderAngle = 0.0 degree
        }
      }

      aggregate SetDepthRateGoDown {
        run while ( FlagGoDown )

        behavior Guidance:Pitch {
          run in parallel

          set depthRate = DownRate
        }
      }

      aggregate SetDepthRateGoUp {
        run while ( FlagGoUp )

        behavior Guidance:Pitch {
          run in parallel

          set depthRate = UpRate
        }
      }

      aggregate LogGoDown {
        run when (
          FlagGoDown
          and ( not ( SyslogGoDown ) )
        )

        assign in sequence DepthLogged = Universal:depth

        syslog important "Go down from " + DepthLogged~meter

        assign in sequence SyslogGoDown = true
      }

      aggregate SetFlagGoUp {
        run when (
          SampleAtPeakChl
          and ( isNaN ( DepDesignated ) )
          and ( isNaN ( TempDesignated ) )
          and ( Universal:depth > DeepbndChl )
          and ( not ( FlagGoUp ) )
        )

        assign in sequence FlagGoUp = true

        assign in sequence FlagGoDown = false

        assign in sequence SyslogGoDown = false
      }

      aggregate LogGoUp {
        run when (
          FlagGoUp
          and ( not ( SyslogGoUp ) )
        )

        assign in sequence DepthLogged = Universal:depth

        syslog important "Go up from " + DepthLogged~meter

        assign in sequence SyslogGoUp = true
      }

      aggregate SetChlPeakTempDepth {
        run when (
          SampleAtPeakChl
          and ( not ( FlagPeakChlDepthSet ) )
          and FlagGoUp
          and ( Universal:depth < ( DeepbndChl - RiseFromTurningDep ) )
          and ( Science:PeakChlDepth > ShallowbndChl )
        )

        assign in sequence PeakChlDepthSet = Science:PeakChlDepth

        assign in sequence PeakChlTemperatureSet = Science:PeakChlTemperature

        assign in sequence PeakChlSet = Science:PeakChl

        assign in sequence FlagPeakChlDepthSet = true

        assign in sequence DepthLogged = Universal:depth

        assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

        assign in sequence FlagGoUp = false

        assign in sequence FlagGoDown = false

        assign in sequence SyslogGoUp = false

        assign in sequence SyslogGoDown = false

        syslog important "Set peak-chl depth and temp. DepthLogged, ChlLogged, PeakChlDepthSet, PeakChlTemperatureSet, PeakChlSet = "
             + DepthLogged~meter + ", " + ChlLogged~microgram_per_liter + ", " + PeakChlDepthSet~meter + ", "
             + PeakChlTemperatureSet~celsius + ", " + PeakChlSet~microgram_per_liter

        assign in sequence FlagPeakChlTempSet = true
      }
    }
  }

  aggregate IsothermOrDepthHolding {
    run in parallel

    break if ( CntSamples > NumSamplers )

    aggregate HoldTempInDonutMode {
      run while (
        FlagTempSet
        and ( not ( FlagGoUp ) )
        and ( not ( FlagGoDown ) )
        and ( SpeedSampling > 0.0 meter_per_second )
      )

      behavior Guidance:DepthServo {
        run in parallel

        set input = Universal:sea_water_temperature
        set holdValue = TempSet
        set proportionalGain = GainProportional
        set integralGain = GainIntegral
        set derivativeGain = GainDerivative
        set changePerMeter = VariationPerMeter
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = SpeedSampling
      }

      behavior Guidance:Point {
        run in parallel

        set rudderAngle = RudderAngleDonutSampling
      }

      behavior Guidance:Buoyancy {
        run in parallel

        set position = BuoyancyNeutral
      }
    }

    aggregate HoldTempInDriftMode {
      run while (
        FlagTempSet
        and ( not ( FlagGoUp ) )
        and ( not ( FlagGoDown ) )
        and ( not ( SpeedSampling > 0.0 meter_per_second ) )
      )

      behavior Guidance:DepthServo {
        run in parallel

        set input = Universal:sea_water_temperature
        set holdValue = TempSet
        set proportionalGain = GainProportional
        set integralGain = GainIntegral
        set derivativeGain = GainDerivative
        set changePerMeter = VariationPerMeter
      }

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = 0.0 meter_per_second
      }

      behavior Guidance:Point {
        run in parallel

        set rudderAngle = 0.0 degree
      }
    }

    aggregate HoldDepthInDonutMode {
      run while (
        FlagTargetDepthSet
        and ( not ( FlagGoUp ) )
        and ( not ( FlagGoDown ) )
        and ( SpeedSampling > 0.0 meter_per_second )
      )

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = SpeedSampling
      }

      behavior Guidance:Point {
        run in parallel

        set rudderAngle = RudderAngleDonutSampling
      }

      behavior Guidance:Buoyancy {
        run in parallel

        set position = BuoyancyNeutral
      }
    }

    aggregate HoldDepthInDriftMode {
      run while (
        FlagTargetDepthSet
        and ( not ( FlagGoUp ) )
        and ( not ( FlagGoDown ) )
        and ( not ( SpeedSampling > 0.0 meter_per_second ) )
      )

      behavior Guidance:SetSpeed {
        run in parallel

        set speed = 0.0 meter_per_second
      }

      behavior Guidance:Point {
        run in parallel

        set rudderAngle = 0.0 degree
      }
    }
  }

  aggregate TakeSamples {
    run in parallel

    break if (
      CntSamples > NumSamplers
      or (
        SampleAtPeakChl
        and ( not ( FlagInitialDiveCompleted ) )
      )
    )

    aggregate NoFiringForTooLong {
      run when (
        EnableElapsedSinceStartOrLastSample
        and ( elapsed ( ElapsedSinceStartOrLastSample ) > MaxWaitNoFiring )
        and ( not ( FlagSamplingOngoing ) )
        and ( not ( StoppedForNoFiringForTooLong ) )
      )

      assign in sequence ElapsedTime = elapsed ( ElapsedSinceStartOrLastSample )

      syslog important "No firing for too long. Stopping mission. ElapsedTime, MaxWaitNoFiring = "
           + ElapsedTime~minute + ", " + MaxWaitNoFiring~minute

      behavior Guidance:Execute {
        run in sequence

        set command = "stop"
      }

      assign in sequence StoppedForNoFiringForTooLong = true
    }

    aggregate SetOptionsOfSample1 {
      run when (
        CntSamples == 1 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType1

      call id="SetOptionsForSample1" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample2 {
      run when (
        CntSamples == 2 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType2

      call id="SetOptionsForSample2" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample3 {
      run when (
        CntSamples == 3 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType3

      call id="SetOptionsForSample3" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample4 {
      run when (
        CntSamples == 4 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType4

      call id="SetOptionsForSample4" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample5 {
      run when (
        CntSamples == 5 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType5

      call id="SetOptionsForSample5" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample6 {
      run when (
        CntSamples == 6 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType6

      call id="SetOptionsForSample6" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample7 {
      run when (
        CntSamples == 7 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType7

      call id="SetOptionsForSample7" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample8 {
      run when (
        CntSamples == 8 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType8

      call id="SetOptionsForSample8" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample9 {
      run when (
        CntSamples == 9 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType9

      call id="SetOptionsForSample9" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetOptionsOfSample10 {
      run when (
        CntSamples == 10 count
        and ( not ( SampleOptionsSet ) )
        and SampleCountIncreased
      )

      assign in sequence CartridgeTypeIndividual = CartridgeType10

      call id="SetOptionsForSample10" refId="SetSampleOptions"

      assign in sequence SampleOptionsSet = true
    }

    aggregate SetFiringTempRelativeToChlPeak {
      run when (
        SampleOptionsSet
        and ( not ( isNaN ( TempDiffFromPeakChl ) ) )
        and FlagPeakChlTempSet
        and ( not ( FlagTempSet ) )
      )

      assign in sequence TempSet = PeakChlTemperatureSet + TempDiffFromPeakChl

      assign in sequence FlagTempSet = true
    }

    aggregate SetFiringTempAbsolute {
      run when (
        SampleOptionsSet
        and (
          TempDesignated >= 0 celsius
          or ( TempDesignated < 0 celsius )
        )
        and ( not ( FlagTempSet ) )
      )

      assign in sequence TempSet = TempDesignated

      assign in sequence FlagTempSet = true

      assign in sequence FlagGoDown = false
    }

    aggregate SetFiringDepthRelativeToChlPeakNormal {
      run when (
        SampleOptionsSet
        and FlagPeakChlDepthSet
        and ( not ( isNaN ( DepDiffFromPeakChl ) ) )
        and ( not ( FlagTargetDepthSet ) )
        and ( PeakChlDepthSet + DepDiffFromPeakChl >= ShallowbndChl )
        and ( PeakChlDepthSet + DepDiffFromPeakChl <= DeepbndChl )
      )

      assign in sequence DepthSet = PeakChlDepthSet + DepDiffFromPeakChl

      assign in sequence FlagTargetDepthSet = true
    }

    aggregate SetFiringDepthRelativeToChlPeakClampedToShallowest {
      run when (
        SampleOptionsSet
        and FlagPeakChlDepthSet
        and ( not ( isNaN ( DepDiffFromPeakChl ) ) )
        and ( not ( FlagTargetDepthSet ) )
        and ( PeakChlDepthSet + DepDiffFromPeakChl < ShallowbndChl )
      )

      assign in sequence DepthSet = ShallowbndChl

      assign in sequence FlagTargetDepthSet = true
    }

    aggregate SetFiringDepthRelativeToChlPeakClampedToDeepest {
      run when (
        SampleOptionsSet
        and FlagPeakChlDepthSet
        and ( not ( isNaN ( DepDiffFromPeakChl ) ) )
        and ( not ( FlagTargetDepthSet ) )
        and ( PeakChlDepthSet + DepDiffFromPeakChl > DeepbndChl )
      )

      assign in sequence DepthSet = DeepbndChl

      assign in sequence FlagTargetDepthSet = true
    }

    aggregate SetFiringDepthAbsolute {
      run when (
        SampleOptionsSet
        and ( not ( isNaN ( DepDesignated ) ) )
        and ( not ( FlagTargetDepthSet ) )
      )

      assign in sequence DepthSet = DepDesignated

      assign in sequence FlagTargetDepthSet = true

      assign in sequence FlagGoDown = false
    }

    aggregate FiringOnTemp {
      run when (
        FlagTempSet
        and ( not ( FlagSamplingOngoing ) )
        and ( CntSamples <= NumSamplers )
        and SampleOptionsSet
        and ( not ( SampleCompleted ) )
      )

      assign in sequence FlagSamplingOngoing = true

      assign in sequence SampleCountIncreased = false

      syslog important "Taking sample No." + CntSamples~count + ". Target temp = " + TempSet~celsius
           + "."

      syslog important "If ESP, requesting ESP cartridge type:" + CartridgeType~count

      assign in sequence ElapsedSinceStartOrLastSample = 0 hour

      aggregate TriggerOnTemp {
        run in sequence

        break if (
          UseESP
          and ( isNaN ( CartridgeType ) )
          or (
            SampleAtPeakChl
            and ( PeakChlSet < TriggerThreshChl )
          )
        )

        call id="WaitForDepthDampingDown" refId="DampDown"

        call id="Sampling" refId="TriggerSampling"

        syslog important "Sample No." + CntSamples~count + " completed."

        assign in sequence ElapsedSinceStartOrLastSample = 0 hour

        assign in sequence FlagSamplingOngoing = false

        assign in sequence SampleCompleted = true

        # Don't move the following line

        assign in sequence SampleOptionsSet = false

        assign in sequence FlagTempSet = false
      }

      aggregate SkipOnTemp {
        run in sequence

        break if (
          not (
            UseESP
            and ( isNaN ( CartridgeType ) )
            or (
              SampleAtPeakChl
              and ( PeakChlSet < TriggerThreshChl )
            )
          )
        )

        syslog important "Sampling is skipped because (1) the Chl level is lower than the scientist-specified threshold or (2) ESP sampling but cartridge type is NaN."

        assign in sequence CntSamples = NumSamplers

        assign in sequence FlagSamplingOngoing = false

        assign in sequence SampleCompleted = true

        # Don't move the following line

        assign in sequence SampleOptionsSet = false

        assign in sequence FlagTempSet = false

        assign in sequence SendDataAllCompleted = true
      }

      aggregate FireOnTempSendData {
        run when (
          not ( isNaN ( CartridgeType ) )
          and SampleCompleted
          and SendSampleStatusAndData
          and CallSendData
        )

        call id="SendDataFireOnTemp" refId="SendData"

        assign in sequence CallSendData = false
      }
    }

    aggregate FiringOnDepth {
      run when (
        FlagTargetDepthSet
        and ( not ( FlagGoUp ) )
        and ( not ( FlagGoDown ) )
        and ( not ( FlagSamplingOngoing ) )
        and ( CntSamples <= NumSamplers )
        and SampleOptionsSet
        and ( not ( SampleCompleted ) )
      )

      assign in sequence SampleAtDepth:TargetDepth = DepthSet

      assign in sequence SampleAtDepth:SettleTime = WaitDepthUndulation

      assign in sequence FlagSamplingOngoing = true

      assign in sequence SampleCountIncreased = false

      syslog important "Taking sample No." + CntSamples~count + ". Target depth = " + DepthSet~meter
           + "."

      syslog important "If ESP, requesting ESP cartridge type:" + CartridgeType~count

      assign in sequence ElapsedSinceStartOrLastSample = 0 hour

      aggregate TriggerOnDepth {
        run in sequence

        break if (
          UseESP
          and ( isNaN ( CartridgeType ) )
          or (
            SampleAtPeakChl
            and ( PeakChlSet < TriggerThreshChl )
          )
        )

        assign in sequence SampleAtDepth:ESPCartridgeType = CartridgeType

        call id="Sampling" refId="SampleAtDepth"

        syslog important "Sample No." + CntSamples~count + " completed."

        assign in sequence ElapsedSinceStartOrLastSample = 0 hour

        assign in sequence FlagSamplingOngoing = false

        assign in sequence SampleCompleted = true

        # Don't move the following line

        assign in sequence SampleOptionsSet = false

        assign in sequence FlagTargetDepthSet = false
      }

      aggregate SkipOnDepth {
        run in sequence

        break if (
          not (
            UseESP
            and ( isNaN ( CartridgeType ) )
            or (
              SampleAtPeakChl
              and ( PeakChlSet < TriggerThreshChl )
            )
          )
        )

        syslog important "Sampling is skipped because (1) the Chl level is lower than the scientist-specified threshold or (2) ESP sampling but cartridge type is NaN."

        assign in sequence CntSamples = NumSamplers

        assign in sequence FlagSamplingOngoing = false

        assign in sequence SampleCompleted = true

        # Don't move the following line

        assign in sequence SampleOptionsSet = false

        assign in sequence FlagTargetDepthSet = false

        assign in sequence SendDataAllCompleted = true
      }

      aggregate FireOnDepSendData {
        run when (
          not ( isNaN ( CartridgeType ) )
          and SampleCompleted
          and SendSampleStatusAndData
          and CallSendData
        )

        call id="SendDataFireOnDep" refId="SendData"

        assign in sequence CallSendData = false
      }
    }

    aggregate IncreaseSampleCount {
      run when (
        SampleCompleted
        and ( not ( SendSampleStatusAndData ) )
        or (
          SampleCompleted
          and SendSampleStatusAndData
          and SendDataAllCompleted
        )
      )

      assign in sequence CntSamples = CntSamples + 1 count

      assign in sequence SendDataCntSamplesCompleted = false

      assign in sequence SendDataESPSampleNumberCompleted = false

      assign in sequence SendDataESPCartridgeTypeCompleted = false

      assign in sequence SendDataESPSampleVolumeCompleted = false

      assign in sequence SendDataSampleDepCompleted = false

      assign in sequence SendDataSampleTempCompleted = false

      assign in sequence SendDataSampleChlCompleted = false

      assign in sequence SendDataAllCompleted = false

      assign in sequence CallSendData = true

      assign in sequence SampleCompleted = false

      assign in sequence SampleOptionsSet = false

      assign in sequence SampleCountIncreased = true
    }
  }
}