Science/smear_waypoint_sampling.tl

#   Copyright (c) 2024 MBARI
#   MBARI Proprietary Information. Confidential. All Rights Reserved
#   Unauthorized copying or distribution of this file via any medium is strictly
#   prohibited.
#
#   WARNING - This file contains information whose export is restricted by the
#   Export Administration Act of 1979 (Title 50, U.S.C., App. 2401 et seq.), as
#   amended. Violations of these export laws are subject to severe civil and/or
#   criminal penalties.

mission smear_waypoint_sampling {
  arguments {
    # Almost every mission should start with an overall timeout and a NeedCommsTime. Drift Missions will have an acoustic timeout instead of a NeedCommsTime.

    # You probably need to change these.

    NumSamplers = 1 count
      """
      Total number of ESP cartridges (Maximum 60) or CANON samplers. Set to 0
      to disable sampling.
      """

    # debug
    #     </Description><Units:count/><Value>3</Value></DefineArg>

    CartridgeType = -6 count
      """
      Cartridge type. Initialized to -6.
      """

    CANONSamplerRotateOnly = 0 bool

    MissionTimeout = 3 hour
      """
      Maximum duration of mission
      """

    WaitDuration = 0 minute
      """
      Wait time before firing a sample.
      """

    NeedCommsTimeInTransit = 60 minute
      """
      In transit, how often to surface for commumications
      """

    MaxWaitNoFiring = 2 hour
      """
      If no firing after more than MaxWaitNoFiring, terminate mission.
      """

    # debug
    #     </Description><Units:hour/><Value>0.05</Value></DefineArg>

    ReachEndWaypoint = true
      """
      Whether to reach the end waypoint after sampling is completed
      (initialized to true).
      """

    # debug
    #     </Description><False/></DefineArg>

    Speed = 1.0 meter_per_second
      """
      Vehicle speed.
      """

    MaxDepth = 50 meter
      """
      Maximum depth for the entire mission.
      """

    SamplingYoYoMinDepth = 10 meter
      """
      Minimum yoyo depth while transiting and sampling.
      """

    SamplingYoYoMaxDepth = 20 meter
      """
      Maximum yoyo depth while transiting and sampling.
      """

    WaypointCaptureRadius = 100 meter
      """
      Waypoint capture radius for transiting to the sampling location.
      """

    SamplingStartLatitude = NaN degree
      """
      The start latitude of sampling. If NaN, start here.
      """

    # debug
    #     </Description><Units:degree/><Value>36.80</Value></DefineArg>

    SamplingStartLongitude = NaN degree
      """
      The start longitude of sampling. If NaN, start here.
      """

    # debug
    #     </Description><Units:degree/><Value>-121.82</Value></DefineArg>

    SamplingEndLatitude = NaN degree
      """
      The end latitude of sampling. Must set.
      """

    # debug
    #     </Description><Units:degree/><Value>36.808</Value></DefineArg>

    SamplingEndLongitude = NaN degree
      """
      The end longitude of sampling. Must set.
      """

    # debug
    #     </Description><Units:degree/><Value>-121.838</Value></DefineArg>

    # Use caution when changing these.

    YoYoMinAltitude = 9 meter
      """
      Minimum altitude while performing the YoYo behavior (for
      bottom-terminated YoYos).
      """

    MinAltitude = 7 meter
      """
      Minimum altitude for the entire mission.
      """

    MinOffshore = 2 kilometer
      """
      Minimum offshore distance for the entire mission.
      """

    # You probably do not need to change these.

    UseCANONSampler = Science:CANONSampler.loadAtStartup
      """
      Whether to use CANON Sampler to sample.
      """

    UseESP = Science:ESPComponent.loadAtStartup
      """
      Whether to use ESP to sample.
      """

    CANONSamplerTriggerTimeout = 1 minute
      """
      How long to wait for a CANON Sampler sample to start.
      """

    CANONSamplerTimeout = Science:CANONSampler.sampleTimeout
      """
      How long to wait for a CANON Sampler sample to complete.
      """

    YoYoUpPitch = 20 degree
      """
      Vehicle up pitch while performing the YoYo behavior.
      """

    YoYoDownPitch = -20 degree
      """
      Vehicle down pitch while performing the YoYo behavior.
      """

    BuoyancyNeutral = Control:VerticalControl.buoyancyNeutral
      """
      Buoyancy bladder position while performing the YoYo behavior. Defaults
      to buoyancyNeutral setting in the Config/Control.cfg file. Set to NaN cc
      for active buoyancy
      """

    MassDefault = Control:VerticalControl.massDefault
      """
      Static setting for mass during the mission. Set to NaN mm for active
      mass position
      """

    # Internal variables that you should not change

    NeedCommsSampling = 3 hour
      """
      How often to surface for commumications during the process of completing
      all samples, in case something goes wrong during sampling.
      """
  }

  output {
    ElapsedSinceStartOrLastSample = 0 hour
      """
      The mission sets this variable to reset the ESP sample timer.
      """

    ElapsedTime = 0 hour
      """
      Only for syslog.
      """

    StoppedForNoFiringForTooLong = false
      """
      Mission stopped because of no firing for too long. Initialized to false.
      """

    DepthLogged = 0.0 meter

    TempLogged = 0.0 celsius

    ChlLogged = 0.0 microgram_per_liter

    MissionStartCommsCompleted = false
      """
      MissionStartComms is completed (initialized to false).
      """

    TransitCompleted = false
      """
      Transit is completed (initialized to False).
      """

    FlagSamplingOngoing = false
      """
      Flag of water sampling in process (initialized to false).
      """

    SampleCompleted = false
      """
      Sampling completed. Initialized to false.
      """

    CntSamples = 1 count
      """
      Count of water samples (initilized to 1).
      """
  }

  # Missions should almost always start with a timeout and a NeedComms aggregate. Drift missions will not use NeedComms.

  timeout duration=MissionTimeout

  insert id="NeedComms" Insert/NeedComms.tl

  assign in sequence NeedComms:DiveInterval = NeedCommsSampling

  # Missions should almost always start with standard safety envelopes

  insert Insert/StandardEnvelopes.tl

  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude

  assign in sequence StandardEnvelopes:MaxDepth = MaxDepth

  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  behavior Sample:AbortSample {
    run in parallel
  }

  # Many missions will keep mass position fixed at the default.

  behavior Guidance:Pitch {
    run in parallel

    set massPosition = MassDefault
  }

  insert Insert/Science.tl

  behavior Guidance:AltitudeEnvelope {
    """
    Another altitude envelope for the YoYo behavior. This envelope
    should fall within the limits of the standard safety envelopes in
    Insert/StandardEnvelopes.tl in order to avoid commanding high pitch
    angles for bottom-terminated YoYos.
    """

    run in parallel

    set minAltitude = YoYoMinAltitude
  }

  aggregate TriggerSampling {
    run when ( called )

    aggregate TriggerESP {
      run in sequence

      break if ( not ( UseESP ) )

      assign in sequence DepthLogged = Universal:depth

      assign in sequence TempLogged = Universal:sea_water_temperature

      assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

      syslog important "Trigger ESP sampling. DepthLogged, TempLogged, ChlLogged = "
           + DepthLogged~meter + ", " + TempLogged~celsius + ", " + ChlLogged~microgram_per_liter + "."

      behavior Science:ESPCartridgeSelect {
        run in sequence

        timeout duration=P1M

        set cartridgeType = CartridgeType
      }

      readDatum {
        Science:ESPComponent.sampling
      }

      syslog important "Wait for ESP sampling to complete."

      readDatum {
        Science:ESPComponent.sample_number
      }
    }

    aggregate TriggerCANON {
      run in sequence

      break if ( not ( UseCANONSampler ) )

      assign in sequence DepthLogged = Universal:depth

      assign in sequence TempLogged = Universal:sea_water_temperature

      assign in sequence ChlLogged = Universal:mass_concentration_of_chlorophyll_in_sea_water

      syslog important "Trigger CANON sampling. DepthLogged, TempLogged, ChlLogged = "
           + DepthLogged~meter + ", " + TempLogged~celsius + ", " + ChlLogged~microgram_per_liter + "."

      assign in parallel Science:CANONSampler.sampleTimeout = CANONSamplerTimeout

      assign in parallel Science:CANONSampler.rotateOnly = CANONSamplerRotateOnly

      readDatum id="TriggerCANONSampler" {
        timeout duration=CANONSamplerTriggerTimeout {
          syslog important "Timed out triggering CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sampling
      }

      readDatum {
        timeout duration=CANONSamplerTimeout {
          syslog important "Timed out sampling with CANONSampler. Stopping mission."

          behavior Guidance:Execute {
            run in sequence

            set command = "stop"
          }
        }

        Science:CANONSampler.sample_number
      }
    }
  }

  aggregate InsertWait {
    run when ( called )

    aggregate IfNot1stSample {
      run in sequence

      break if ( CntSamples == 1 count )

      syslog important "Wait " + WaitDuration~minute + " before firing sample."

      behavior Guidance:Wait {
        run in sequence

        set duration = WaitDuration
      }
    }
  }

  aggregate MissionStart {
    run in sequence

    call id="MissionStartComms" refId="NeedComms"

    assign in sequence MissionStartCommsCompleted = true

    assign in sequence ElapsedSinceStartOrLastSample = 0 hour

    assign in sequence TransitCompleted = true
  }

  aggregate TransitToSamplingLocation {
    run in sequence

    break if (
      isNaN ( SamplingStartLatitude )
      or ( isNaN ( SamplingStartLongitude ) )
    )

    assign in sequence TransitCompleted = false

    assign in sequence NeedComms:DiveInterval = NeedCommsTimeInTransit

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = Speed
    }

    behavior Guidance:DepthEnvelope {
      run in parallel

      set minDepth = SamplingYoYoMinDepth
      set maxDepth = SamplingYoYoMaxDepth
      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:YoYo {
      run in parallel

      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:Buoyancy {
      run in parallel

      set position = BuoyancyNeutral
    }

    behavior Guidance:Waypoint {
      run in sequence

      set latitude = SamplingStartLatitude
      set longitude = SamplingStartLongitude
      set captureRadius = WaypointCaptureRadius
    }

    assign in sequence NeedComms:DiveInterval = NeedCommsSampling

    assign in sequence ElapsedSinceStartOrLastSample = 0 hour

    assign in sequence TransitCompleted = true
  }

  aggregate SamplingToWaypoint {
    run in sequence

    break if (
      isNaN ( SamplingEndLatitude )
      or ( isNaN ( SamplingEndLongitude ) )
      or (
        not ( ReachEndWaypoint )
        and ( CntSamples == ( NumSamplers + 1 count ) )
      )
    )

    behavior Guidance:SetSpeed {
      run in parallel

      set speed = Speed
    }

    behavior Guidance:DepthEnvelope {
      run in parallel

      set minDepth = SamplingYoYoMinDepth
      set maxDepth = SamplingYoYoMaxDepth
      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:YoYo {
      run in parallel

      set downPitch = YoYoDownPitch
      set upPitch = YoYoUpPitch
    }

    behavior Guidance:Buoyancy {
      run in parallel

      set position = BuoyancyNeutral
    }

    behavior Guidance:Waypoint {
      run in sequence

      set latitude = SamplingEndLatitude
      set longitude = SamplingEndLongitude
      set captureRadius = WaypointCaptureRadius
    }

    aggregate TakeSamples {
      run in parallel

      aggregate NoFiringForTooLong {
        run when (
          TransitCompleted
          and ( elapsed ( ElapsedSinceStartOrLastSample ) > MaxWaitNoFiring )
          and ( not ( FlagSamplingOngoing ) )
          and ( not ( CntSamples == ( NumSamplers + 1 count ) ) )
          and ( not ( StoppedForNoFiringForTooLong ) )
        )

        assign in sequence ElapsedTime = elapsed ( ElapsedSinceStartOrLastSample )

        syslog important "No firing for too long. Stopping mission. ElapsedTime, MaxWaitNoFiring = "
             + ElapsedTime~minute + ", " + MaxWaitNoFiring~minute

        behavior Guidance:Execute {
          run in sequence

          set command = "stop"
        }

        assign in sequence StoppedForNoFiringForTooLong = true
      }

      aggregate Firing {
        run when (
          Universal:depth >= SamplingYoYoMinDepth
          and ( Universal:depth <= SamplingYoYoMaxDepth )
          and MissionStartCommsCompleted
          and TransitCompleted
          and ( not ( FlagSamplingOngoing ) )
          and ( CntSamples <= NumSamplers )
          and ( not ( SampleCompleted ) )
        )

        assign in sequence FlagSamplingOngoing = true

        syslog important "Taking sample No." + CntSamples~count + "."

        assign in sequence ElapsedSinceStartOrLastSample = 0 hour

        assign in sequence NeedComms:DiveInterval = NeedCommsSampling

        call id="WaitBeforeFiring" refId="InsertWait"

        call id="Sampling" refId="TriggerSampling"

        syslog important " Sample No." + CntSamples~count + " completed."

        call id="CommsSampling" refId="NeedComms"

        assign in sequence NeedComms:DiveInterval = NeedCommsTimeInTransit

        assign in sequence SampleCompleted = true

        assign in sequence ElapsedSinceStartOrLastSample = 0 hour

        assign in sequence FlagSamplingOngoing = false
      }

      aggregate IncrementSampleCounter {
        run when ( SampleCompleted )

        assign in sequence CntSamples = CntSamples + 1 count

        assign in sequence SampleCompleted = false
      }
    }
  }
}