Engineering/tritoncam_circle_hotspot.tl

mission circle_hotspot {
  """
  Circle-Hotspot mission for Triton LRAUV 
  """

  arguments {
    MissionTimeout = 500 hour
      """
      Maximum duration of mission
      """

    NeedCommsTime = 100 hour
      """
      How often to surface for communications
      """

    # Parameters updated by the backseat via customUri (the '_.' slate namespace)
    MinDepth = 10 meter
      """
      Minimum depth of the yoyo envelope. Updated by backseat via _.YoYoMinDepth.
      """

    MaxDepth = 60 meter
      """
      Maximum depth of the yoyo envelope. Updated by backseat via _.YoYoMaxDepth.
      """

    Speed = 1 meter_per_second
      """
      Vehicle speed. Updated by backseat via _.speed_command.
      """

    YoYoDownPitch = -15 degree
      """
      Vehicle pitch while diving (negative = nose down).
      """

    YoYoUpPitch = 15 degree
      """
      Vehicle pitch while climbing (positive = nose up).
      """

    RudderAngleYoyoCircle = 5 degree
      """
      Rudder angle applied while circling a hotspot.
      """

    CircleCheckInterval = 30 second
      """
      How often, while circling, to re-check whether the backseat still wants
      to circle (_.InYoyoCircle). The circle aggregate breaks out as soon as
      the backseat drops back to transit.
      """

    StateUpdateDelay = 1 second
      """
      Minimum time delay between state updates to avoid rapid changes.
      """

    MinAltitude = 5 meter
    MaxSafeDepth = 100 meter
    MinOffshore = 1.5 kilometer

    Repeat = 10 count
      """
      Number of times to cycle through the waypoint list.
      """

    Lat[1..7] = NaN degree
      """
      Latitude of waypoint {$}. NaN entries are skipped. The vehicle yo-yos
      while transiting to each waypoint, so at least one is required.
      """

    Lon[1..7] = NaN degree
      """
      Longitude of waypoint {$}. NaN entries are skipped.
      """

    MassHold = true
      """
      Set to True to hold mass at default position.
      """
  }

  # --- Mission Start ---
  timeout duration=MissionTimeout

  insert id="NeedComms" Insert/NeedComms.tl
  assign in sequence NeedComms:DiveInterval = NeedCommsTime

  insert Insert/StandardEnvelopes.tl
  assign in sequence StandardEnvelopes:MinAltitude = MinAltitude
  assign in sequence StandardEnvelopes:MaxDepth = MaxSafeDepth
  assign in sequence StandardEnvelopes:MinOffshore = MinOffshore

  # --- Backseat Parameter Updates ---
  aggregate UpdateYoYoMin {
    run when (
      elapsed ( customUri "_.YoYoMinDepth" ) < ( elapsed ( MinDepth ) )
      and ( elapsed ( MinDepth ) > StateUpdateDelay )
    )
    assign in sequence MinDepth = customUri "_.YoYoMinDepth"
    syslog info "Backseat updated YoYo MinDepth: " + MinDepth~meter
  }

  aggregate UpdateYoYoMax {
    run when (
      elapsed ( customUri "_.YoYoMaxDepth" ) < ( elapsed ( MaxDepth ) )
      and ( elapsed ( MaxDepth ) > StateUpdateDelay )
    )
    assign in sequence MaxDepth = customUri "_.YoYoMaxDepth"
    syslog info "Backseat updated YoYo MaxDepth: " + MaxDepth~meter
  }

  aggregate UpdateSpeed {
    run when (
      elapsed ( customUri "_.speed_command" ) < ( elapsed ( Speed ) )
      and (elapsed ( Speed ) > StateUpdateDelay)
    )
    assign in sequence Speed = customUri "_.speed_command"
  }

  # --- Science & Backseat Payload ---
  insert id="Science" Insert/Science.tl

  insert Insert/BackseatDriver.tl
  assign in sequence BackseatDriver:EnableBackseat = true

  insert Insert/PowerOnly.tl

  behavior Guidance:BackseatDriver {
    run in parallel
  }

  # --- Check for comms before diving ---
  call id="StartingMission" priorityHere=false refId="NeedComms"

  # --- Vehicle Control (mirrors sci2_peak_layer_yoyo / adaptive_yoyo) ---
  behavior Guidance:Buoyancy {
    run in parallel
    set position = Control:VerticalControl.buoyancyNeutral
  }

  behavior Guidance:Pitch {
    run while ( MassHold )
    set massPosition = Control:VerticalControl.massDefault
  }

  behavior Guidance:SetSpeed {
    run in parallel
    set speed = Speed
  }

  behavior Guidance:DepthEnvelope {
    run in parallel
    set minDepth = MinDepth
    set maxDepth = MaxDepth
    set downPitch = YoYoDownPitch
    set upPitch = YoYoUpPitch
  }

  behavior Guidance:AltitudeEnvelope {
    run in parallel
    set minAltitude = MinAltitude
  }

  behavior Guidance:YoYo {
    run in parallel
    set downPitch = YoYoDownPitch
    set upPitch = YoYoUpPitch
  }

  # --- Test waypoints: short triangle near the deploy site ---
  # assign in sequence Lat[1] = 36.812 degree
  # assign in sequence Lon[1] = -121.808 degree
  # assign in sequence Lat[2] = 36.807 degree
  # assign in sequence Lon[2] = -121.814 degree
  # assign in sequence Lat[3] = 36.802 degree
  # assign in sequence Lon[3] = -121.808 degree

  # --- Transit the waypoint list and  circle a hotspot when the backseat asks ---

  aggregate Lap {
    run in sequence repeat = Repeat

    macro $i = 1..7 {
      aggregate Wpt$i {
        run in sequence
        break if ( customUri "_.InYoyoCircle" >= 1 count )

        behavior Guidance:Waypoint {
          run in sequence
          set latitude = Lat[$i]
          set longitude = Lon[$i]
        }
      }
    }

    aggregate YoyoCircleHotspot {
      run in sequence
      break if ( customUri "_.InYoyoCircle" < 1 count )


      behavior Guidance:Point {
        run in parallel
        set rudderAngle = RudderAngleYoyoCircle
      }

      behavior Guidance:Wait {
        run in sequence
        set duration = CircleCheckInterval
      }
    }
  }
}